Clear way to show lines in RichEdit for code (Like Scite)

[GordonFreeman]

Theres a clear way to put lines in a richedit control and color the bar like scite?

Like:

1 ABCD

2 EEEE

3 AAAA

but, with a background color.

I think in create LABELS or an Listbox in side of richedit control but is not a clear way.

I find this way with list but list consider 10 < 9 then in list appear

1

10

2

3

....

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

 #include <GuiRichEdit.au3>


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 438, 192, 124)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

_GUICtrlRichEdit_Create($Form1,"",100,100,150,150)
GuiCtrlCreateList("",85,100,15,150)
GUICtrlSetBkColor(-1,0x00FF00)
For $i = 1 to 8
GUICtrlSetData(-1,$i)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Edited April 30, 2014 by GordonFreeman

[mLipok]

maybe something like this:

expandcollapse popup

;~ http://www.autoitscript.com/forum/topic/161043-clear-way-to-show-lines-in-richedit-for-code-like-scite/

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include <GuiRichEdit.au3>


#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 438, 192, 124)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$sText = _
        "ABCD" & @CRLF & _
        "EEEE" & @CRLF & _
        "AAAA" & @CRLF & _
        ""

$hRichEdit = _GUICtrlRichEdit_Create($Form1, "", 100, 100, 150, 150)
_Magic($hRichEdit, $sText)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func _Magic(ByRef $hRichEdit, $sText)
    Local $aTextTemp = StringSplit($sText, @CRLF, 1)

    For $i = 1 To $aTextTemp[0]
        _GUICtrlRichEdit_SetSel($hRichEdit,-1,-1)
        Sleep(100) ; this can be removed
        _GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec("00FF00"))
        Sleep(100); this can be removed
        _GUICtrlRichEdit_InsertText($hRichEdit, $i)
        Sleep(100); this can be removed
        _GUICtrlRichEdit_SetSel($hRichEdit,-1,-1)
        Sleep(100); this can be removed
        _GUICtrlRichEdit_SetCharBkColor($hRichEdit, Dec("FFFFFF"))
        Sleep(100); this can be removed
        _GUICtrlRichEdit_InsertText($hRichEdit, " " & $aTextTemp[$i] & @CRLF)
        Sleep(100); this can be removed
    Next

EndFunc   ;==>_Magic

but I think there is an issue in _GUICtrlRichEdit_SetCharBkColor()

because doc saying:

 

Sets the background color of selected text or, if none selected, sets the background color of text inserted at the insertion point

 

but in UDF there is:

 

If $ai[0] = $ai[1] Then
  Return _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_ALL, $tCharFormat, 0, "wparam", "struct*") <> 0
Else
  Return _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_SELECTION, $tCharFormat, 0, "wparam", "struct*") <> 0
EndIf

[mLipok]

here is a solution to the UDF:

If $ai[0] = $ai[1] Then
;~      Return _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_ALL, $tCharFormat, 0, "wparam", "struct*") <> 0
        Return _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_SELECTION, $tCharFormat, 0, "wparam", "struct*") <> 0
    Else
        Return _SendMessage($hWnd, $EM_SETCHARFORMAT, $SCF_SELECTION, $tCharFormat, 0, "wparam", "struct*") <> 0
    EndIf

DOC:
http://msdn.microsoft.com/en-us/library/windows/desktop/bb774230(v=vs.85).aspx
 

SCF_SELECTION
Applies the formatting to the current selection. If the selection is empty, the character formatting is applied to the insertion point, and the new character format is in effect only until the insertion point changes.

 

EDIT:

Ticket #2700

Edited April 30, 2014 by mLipok

[mLipok]

I see @jpm set my Track Ticket as fixed

so temporaly you can change this UDF in your system or wait for new beta, or wait litle longer......

Cheers

mLipok