Using textRead2Func

[Jewtus]

I'm using this function to loop through a file and run a script: 

expandcollapse popup

;==================================================================
;---> FUNCTION: textRead2Func($strFileName, $strFuncName)
;==================================================================
;DESCRIPTION:
;    This function reads a text file line by line and for each line the parsed function name will be called and the read line will be parsed into the called function.

;PARAMETERS:
;    $strFileName = The filename of an existing text file
;    $strFuncName = The name of function to process the read line, the function name should be parsed as a string.

;RETURN VALUES:
;     1 = The function completed successfully.
;    -1 = The file does not exist.
;    -2 = The file couldnt be opened, may be locked or no permissions.
;    -3 = The text file was empty.
;------------------------------------------------------------------
#cs
;######################### EXAMPLE CODE ##########################
textRead2Func(@ScriptDir & "\questions.txt", "debugOut")
Func debugOut($strToWrite)
    ConsoleWrite("-->" & $strToWrite & @CRLF)
EndFunc
;#################################################################
#ce
Func textRead2Func($strFileName, $strFuncName)
    Local $objTextFile, $strLine

    ;Make sure the file exists, if not, return an error code.
    If Not FileExists($strFileName) = 1 Then
        SetError(-1)
        Return -1
    EndIf

    ;Open the text file for reading.
    $objTextFile = FileOpen($strFileName, 0)

    ;Make sure the text file was opened successfully, otherwise return an error code.
    If $objTextFile = -1 Then
        SetError(-2)
        Return -2
    EndIf

    ;Read the first line to check whether the file is empty or not, if it is, return an error code.
    $strLine = FileReadLine($objTextFile)
    If @error Then
        SetError(-3)
        Return -3
    EndIf

    ;Call the parsed function name and parse the read line.
    Call($strFuncName, $strLine)

    ;Now, continue to read the rest of the file, line by line.
    While 1
        $strLine = FileReadLine($objTextFile)
        If @error Then ExitLoop

        ;Call the parsed function name and parse the read line.
        Call($strFuncName, $strLine)
    WEnd

    ;Release the opened text file object from memory.
    FileClose($objTextFile)

    ;Return a success code.
    Return 1
EndFunc

The file I'm using is a 5 column CSV with a | delimiter.

This is the code I'm executing:

textRead2Func(@ScriptDir & "\db\log\merged.csv", "splitsearch")
Func splitsearch($strToWrite)
    Local $aSearchstring = StringSplit($strToWrite,"|")
    For $z = 1 To $aSearchstring[0]
        MsgBox($MB_SYSTEMMODAL, "", "$aSearchstring[" & $z & "] - " & $aSearchstring[$z])
    Next
EndFunc

The issue I'm running into is that when the message box shows up, it shows up with

 

$aSearchstring[1] - ID

When I hit OK, it loops to 

 

$aSearchstring[1] - Name

How would I make it only do the ID and skip the other columns?

Edited May 2, 2014 by Jewtus

[guinness]

Why not FileReadToArray()?

[Jewtus]

When I try:
 

$aFulldat=FileReadToArray(@ScriptDir & '\db\log\merged.csv')
_ArrayDisplay($aFulldat)

Nothing shows up

EDIT: I also tried this:

#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Read the current script file into an array using the filepath.
    Local $aArray = FileReadToArray(@ScriptDir & '\db\log\merged.csv')
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "", "There was an error reading the file. @error: " & @error) ; An error occurred reading the current script file.
    Else
        For $i = 0 To UBound($aArray) - 1 ; Loop through the array.
            MsgBox($MB_SYSTEMMODAL, "", $aArray[$i]) ; Display the contents of the array.
        Next
    EndIf
EndFunc   ;==>Example

and got an @error1

 

Ideally, I'd like to just write the first column to an array and then loop through the array.

I was figuring I would do something like this with the above script:

extRead2Func(@ScriptDir & "\db\log\merged.csv", "splitsearch")
Func splitsearch($strToWrite)
    Local $aSearchstring = StringSplit($strToWrite,"|")
    For $z = 1 To $aSearchstring[0]
       ; MsgBox($MB_SYSTEMMODAL, "", "$aSearchstring[" & $z & "] - " & $aSearchstring[$z])
        _IENavigate($oIE, "http://www.google.com/search?q=" & $z)
    Next
EndFunc

I haven't figured out the next steps, but I'm going to log the outputs to a file. If I can do this with a loop through an array, that would be significantly simpler.

Edited May 2, 2014 by Jewtus

[Jewtus]

I ended up going with the CSV.au3 from this thread. Seems to work perfectly.

'?do=embed' frameborder='0' data-embedContent>>

[Melba23]

Jewtus,

Running this script (on the latest Beta 3.3.11.5):

#include <File.au3>
#include <Array.au3>

Global $aArray

_FileReadToArray("CSV.txt", $aArray, $FRTA_COUNT, "|")

_ArrayDisplay($aArray, "", Default, 8)

works perfectly for me when used on this 5-column "|"-delimited file:

Row 1 Col 1|Row 1 Col2|Row 1 Col 3|Row 1 Col 4|Row 1 Col 5
Row 2 Col 1|Row 2 Col2|Row 2 Col 3|Row 2 Col 4|Row 2 Col 5
Row 3 Col 1|Row 3 Col2|Row 3 Col 3|Row 3 Col 4|Row 3 Col 5
Row 4 Col 1|Row 4 Col2|Row 4 Col 3|Row 4 Col 4|Row 4 Col 5
Row 5 Col 1|Row 5 Col2|Row 5 Col 3|Row 5 Col 4|Row 5 Col 5

Does it work for you?

M23