strange behavior with return values

[gcue]

hello world!

when more than 1 pc is selected, i am trying to prompt the user again to avoid inadvertent selections.  

 

if i enter the correct value the first time the function returns TRUE around it works great

however

if i enter the wrong value the first time, then the correct value the second time - the return value is 0 and not TRUE so the script does not continue

 

im sure it has to do with re-running the _Authorize function - but i dont see how to fix it - what am i missing????

thanks in advance!

expandcollapse popup

#include <array.au3>
$msg_normal = 0


Test()


Func Test()


$selection_text = "Test"


$pcs_selected = 2;UBound($selected_checkboxes) - 1


If $pcs_selected > 1 Then
$message = "You have selected to " & $pcs_selected & " PCs." & @CRLF & @CRLF & "Please type the number '" & $pcs_selected & "' without quotes to continue."


$authorize = _Authorize($selection_text, $message, $pcs_selected)


Debug($authorize)


If $authorize = False Then
Debug("NOT updating")
Return
EndIf
EndIf


Debug("updating")


EndFunc   ;==>Test


Func _Authorize($selection_text, $message, $requirement)


$authorize = False


$input = InputBox($selection_text, $message, "", " M", 320, 160)


If @error Then
Return $authorize
EndIf


Debug()


If $input = $requirement Then
Debug("passed", $input, $requirement)
$authorize = True
Return $authorize
Else
Debug("failed", $input, $requirement)
_Authorize($selection_text, $message, $requirement)
EndIf


EndFunc   ;==>_Authorize


Func Debug($variable1 = "", $variable2 = "", $variable3 = "")


;~  #include <array.au3>
;~  $msg_normal = 0


If IsArray($variable1) Then
_ArrayDisplay($variable1)
Else
If $variable2 <> "" Then
$variable1 &= @CRLF & $variable2
EndIf


If $variable3 <> "" Then
$variable1 &= @CRLF & $variable3
EndIf


ClipPut($variable1)
MsgBox($msg_normal, "Debug", $variable1)
EndIf


EndFunc   ;==>Debug

 

[BrewManNH]

Try it this way instead, this way you're only calling _Authorize once and still able to keep calling up an InputBox until the entry is correct or cancelled.

expandcollapse popup

#Tidy_Parameters=/rel
#include <array.au3>
$msg_normal = 0
Test()
Func Test()
    $selection_text = "Test"
    $pcs_selected = 2;UBound($selected_checkboxes) - 1
    If $pcs_selected > 1 Then
        $message = "You have selected to " & $pcs_selected & " PCs." & @CRLF & @CRLF & "Please type the number '" & $pcs_selected & "' without quotes to continue."
        $authorize = _Authorize($selection_text, $message, $pcs_selected)
        ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $authorize = ' & $authorize & @CRLF & '>Error code: ' & @error & @CRLF) ;### Debug Console
        Debug($authorize)
        If $authorize = False Then
            Debug("NOT updating")
            Return
        EndIf
    EndIf
    Debug("updating")
EndFunc   ;==>Test
Func _Authorize($selection_text, $message, $requirement)
    $authorize = False
    $input = InputBox($selection_text, $message, "", " M", 320, 160)
    If @error Then
        Return $authorize
    EndIf
    While $input <> $requirement
        $input = InputBox($selection_text, $message, "", " M", 320, 160)
        If @error Then
            Return $authorize
        EndIf
    WEnd
    Debug("passed", $input, $requirement)
    $authorize = True
    Return $authorize
EndFunc   ;==>_Authorize
Func Debug($variable1 = "", $variable2 = "", $variable3 = "")
    If IsArray($variable1) Then
        _ArrayDisplay($variable1)
    Else
        If $variable2 <> "" Then
            $variable1 &= @CRLF & $variable2
        EndIf
        If $variable3 <> "" Then
            $variable1 &= @CRLF & $variable3
        EndIf
        ClipPut($variable1)
        MsgBox($msg_normal, "Debug", $variable1)
    EndIf
EndFunc   ;==>Debug

[gcue]

works great!!

curious - any reason you could see why the other one didnt work - just for my info since i spent so much trying to figure it out !

thank you very much!

Edited May 12, 2014 by gcue

[BrewManNH]

When you called _Authorize the second time here:

Else
        Debug("failed", $input, $requirement)
        _Authorize($selection_text, $message, $requirement)
    EndIf

The return from the successful result is returned and the If/Endif ends, and because you called it twice and only returned once (so far) it doesn't return anything when it hits the EndFunc line except 0, which is translated as False.

[gcue]

ahhhhhh makes sense!

thank you again =)