second optional var in my udf

[undefinedspace]

HotKeySet("!a", "funca")

func funca($a=20,$b=100000)

$b=$b-1

Error! when hotkeyed, var used without being declared!

func funca($a=20,$b=100000)

local $b

Error! when f5 go, already declared as a parameter

var and func names changed

Edited May 30, 2014 by undefinedspace

[Danp2]

You can't pass parameters to a function using HotKeySet.

[BrewManNH]

You can't use a function with parameters with HotKeys (or OnEvent, or Adlib for that matter), the parameter variables aren't accessible so they cause an undeclared error message.

[Melba23]

undefinedspace,

First, welcome to the AutoIt forums.

From the Help file page for HotKeySet:

 

The called function can not be given parameters. They will be ignored.

So it is hardly surprising you get those errors.

M23

[jdelaney]

Initiate global variables as your default at the start of your script...you can then subtract from them, or whatever (not passed as a param to the function)

$var=1234

hotkeyset...

func yourfunction()

$var -=1
...

endfunc

[undefinedspace]

Hi.

But $a causes no errors and both parameters are optional.

Using globals would require 2 vars. I could call the real function from a different one that sets the parameters.

[BrewManNH]

 

Using globals would require 2 vars. I could call the real function from a different one that sets the parameters.

That would be the ONLY way to use the parameters in the function. As stated previously, a function with parameters won't be able to use the parameters if you use HotKeySet, or AdlibRegister, or OnEvent mode.

[undefinedspace]

But $a causes no errors and both parameters are optional.

[Melba23]

undefinedspace,

 

$a causes no errors

That is because you do not try to access $a in the script. Add a line which does and you will see that the error happens on that line:

HotKeySet("!a", "funca")

While 1
    Sleep(10)
WEnd

Func funca($a = 20, $b = 100000)
    $a += 1
    $b = $b - 1
EndFunc   ;==>funca

M23

[jguinch]

What about using @NumParams ?

Func funca($a=20,$b=100000)
    If @NumParams = 0 Then Local $a=20, $b=100000
    $b = $b-1
    ConsoleWrite($b & @CRLF)
EndFunc

I will try it before posting, next time...

Edited June 1, 2014 by jguinch

[guinness]

@jguinch,

Those parameters are already defined, no need for Local there.

[jguinch]

Edited... sorry.

Guinness, why IsDeclared("a") returns 0, while $a is seen as declared ?

Edited June 1, 2014 by jguinch

[BrewManNH]

As stated previously, the parameters in a function that is called by a hotkey, or other methods already explained, will not be accessible, but AutoIt will see them as already defined and throw an error.

EDIT: here's an example to show you what I mean.

#AutoIt3Wrapper_Run_AU3Check=n
HotKeySet("a", "Funca")
HotKeySet("{esc}", "_Exit")
Funca()
While 1
    sleep(10)
WEnd

Func _Exit()
    Exit
EndFunc   ;==>_Exit

Func funca($a = 20, $b = 100000)
    If @NumParams = 0 Then Local $a = 10, $b = 1000
    $b = $b - 1
    ConsoleWrite($b & @CRLF)
EndFunc   ;==>funca

If you remove the Funca() line after the hotkeysets, the function works perfectly. When you call the function directly though, you get an error about redeclaring a declared parameter. So, don't use any functions with parameters with a function that can't use them, such as HotKeySet.

Edited June 1, 2014 by BrewManNH

[MHz]

You could use Assign() to get around the error check though I would not recommend using functions with parameters like that as it can get quite complicated, depending on the function and whether it is called by onevent or a direct call from the code.

Example using Assign() based from BrewManNHs last code.

HotKeySet("a", "Funca")
HotKeySet("{esc}", "_Exit")
Funca()
While 1
    sleep(10)
WEnd

Func _Exit()
    Exit
EndFunc

Func funca($a = 20, $b = 100000)
    If @NumParams = 0 Then
        If Not Assign('a', 20, 1) Then Return 0
        If Not Assign('b', 100000, 1) Then Return 0
    EndIf
    $b = $b - 1
    ConsoleWrite($b & @CRLF)
EndFunc

Sure it works, for a simple function, but it is being fixed by a work around. Functions that accept parameters as arrays, objects etc will probably be unworkable.

.

Another way is to use a function as a event handler for all HotKeySet events.

Example with _Event_HotKeySet() handling all hotkeys and thus able to call conditionally functions with parameters or what ever desired. It is a flexible concept.

HotKeySet("a",     "_Event_HotKeySet")
HotKeySet("b",     "_Event_HotKeySet")
HotKeySet("{ESC}", "_Event_HotKeySet")

While 1
    Sleep(10)
WEnd

Exit

Func _Event_HotKeySet()
    ; manage all hotkey events
    ConsoleWrite(@HotKeyPressed & @CRLF)
    Switch @HotKeyPressed
        Case 'a'
            _FuncA()
        Case 'b'
            _FuncB('title')
        Case '{ESC}'
            Exit
        Case Else
            MsgBox(0x40000, '_Event_HotKeySet()', 'No assigned for this event' & @CRLF & @HotKeyPressed)
    EndSwitch
EndFunc

Func _FuncA($a = 20, $b = 100000)
    $b = $b - 1
    MsgBox(0x40000, $a, $b)
EndFunc

Func _FuncB($a = '')
    MsgBox(0x40000, $a, 'You pressed the hotkey ' & @HotKeyPressed)
EndFunc

It adds a little more complication of more functions in the script but it is more manageable and does no work around to get past the checks of Au3Check or AutoIt.

[jguinch]

Or you can call the function ifself :

HotKeySet("a", "funca")
HotKeySet("{ESC}", "_Quit")

While 1
    Sleep(10)
WEnd


Func funca($a = 20, $b = 100000)
    If NOT IsDeclared("a") OR NOT IsDeclared("b") Then Return funca()

    $b -= 1
    ConsoleWrite($b & @CRLF)
EndFunc


Func _Quit()
    Exit
EndFunc