list control

[face]

i have a list control that needs to show images selected from a list control items through a gui. how can i make it show images for each item selected on the list control

#include <GuiConstantsEx.au3>

; GUI
GUICreate("Sample GUI", 400, 400)

; PIC
GUICtrlCreatePic("logo4.gif", 0, 0, 169, 68)
GUICtrlCreateLabel("Image 1", 75, 1, 53, 15)
GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetColor(-1, 0xFFFFFF)

; LIST
GUICtrlCreateList("", 5, 190, 100, 90)
GUICtrlSetData(-1, "Image 1|Image 2|Image 3|Image 4", "Image 1")


; GUI MESSAGE LOOP
GUISetState(@SW_SHOW)
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Edited June 27, 2014 by face

[Melba23]

face,

This should give you the idea:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListBox.au3>
#include <Array.au3>

; Create an array with the image titles and paths
Global $aData[5][2] = [["Image 0", "Path_To_Image_0"], _
                       ["Image 1", "Path_To_Image_1"], _
                       ["Image 2", "Path_To_Image_2"], _
                       ["Image 3", "Path_To_Image_3"], _
                       ["Image 4", "Path_To_Image_4"]]

$sList = ""
For $i = 0 To UBound($aData) - 1
    $sList &= "|" & $aData[$i][0]
Next

$hGUI = GUICreate("Test", 500, 500)

$cList = GUICtrlCreateList("", 10, 10, 200, 200)
GUICtrlSetData($cList, $sList)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cList
            $sSel = GUICtrlRead($cList)
            $iIndex = _ArraySearch($aData, $sSel)
            $sImagePath = $aData[$iIndex][1]
            ; Here we display the path - use GUICtrlSetImage to display it in a Pic control
            MsgBox($MB_SYSTEMMODAL, "Set image", "Path: " & $sImagePath)
    EndSwitch

WEnd

Please ask if you have any questions.

M23

[face]

how can i make it so it shows an image when an item on the list is selected

[Melba23]

face,

As I said in the example code:

use GUICtrlSetImage to display it in a Pic control

You have a path and a Pic control, so you have all you need to use that function to set the image into the control.

M23

[face]

i cant seem to fix it, please help

[Melba23]

face,

Would Sir like fries with that?

#include <GUIConstantsEx.au3>
#include <Array.au3>

; Create an array with the image titles and paths - change the values to match the images you want to display <<<<<<<<<<<<<<<<<<<<<<
Global $aData[5][2] = [["Image 0", "Path_To_Image_0"], _
                       ["Image 1", "Path_To_Image_1"], _
                       ["Image 2", "Path_To_Image_2"], _
                       ["Image 3", "Path_To_Image_3"], _
                       ["Image 4", "Path_To_Image_4"]]

$sList = ""
For $i = 0 To UBound($aData) - 1
    $sList &= "|" & $aData[$i][0]
Next

$hGUI = GUICreate("Test", 500, 500)

$cList = GUICtrlCreateList("", 10, 10, 200, 200)
GUICtrlSetData($cList, $sList)

$cPic = GUICtrlCreatePic("", 250, 10, 100, 100) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cList
            $sSel = GUICtrlRead($cList)
            $iIndex = _ArraySearch($aData, $sSel)
            $sImagePath = $aData[$iIndex][1]
            GUICtrlSetImage($cPic, $sImagePath) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    EndSwitch
WEnd

M23