Is that Tray Message possible?

[kelevr]

Are there any UDFs which can do this or something like this:

[mLipok]

Look for Melba23 project called: Notify

[UEZ]

Just wrote one (it's not perfect but a good starting point):

expandcollapse popup

;Proof of concept version
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

;example
_GDIPlus_Startup()

Global $hGUI = GUICreate("Test", 300, 200), $aGUIGetMsg

GUISetState()
Global $hGUI_TrayMessage = CreateTrayMessage("Text Message" & @CRLF & @CRLF & "Coded by UEZ 2014 using GDI+   ;-)", 350, 100)

Sleep(500)
ShowTrayMessage($hGUI_TrayMessage)

Do
    $aGUIGetMsg = GUIGetMsg(1)
    Switch $aGUIGetMsg[1]
        Case $hGUI
            Switch $aGUIGetMsg[0]
                Case $GUI_EVENT_CLOSE
                    _GDIPlus_Shutdown()
                    GUIDelete()
                    Exit
            EndSwitch
        Case $hGUI_TrayMessage
            Switch $aGUIGetMsg[0]
                Case $GUI_EVENT_PRIMARYDOWN
                    HideTrayMessage($hGUI_TrayMessage)
            EndSwitch
    EndSwitch
Until False


Func CreateTrayMessage($sText, $iW, $iH)
    Local Const $hGUI_TrayMessage = GUICreate("", $iW, $iH, @DesktopWidth, @DesktopHeight, $WS_POPUP, BitOR($WS_EX_LAYERED, $WS_EX_TOPMOST, $WS_EX_TOOLWINDOW))
    Local Const $hBmp_TP = _GDIPlus_BitmapCreateTrayMessage($sText, $iW, $iH)
    _WinAPI_BitmapSetTransparent($hGUI_TrayMessage, $hBmp_TP)
    GUISetState(@SW_HIDE, $hGUI_TrayMessage)
    _GDIPlus_ImageDispose($hBmp_TP)
    Return $hGUI_TrayMessage
EndFunc   ;==>CreateTrayMessage

Func ShowTrayMessage($__hGUI_TrayMessage)
    Local $aSize = WinGetPos($__hGUI_TrayMessage, "")
    Local $iW = $aSize[2], $iH = $aSize[3]
    Local $aPos = _Toast_Locate($iW, $iH)
    WinMove($__hGUI_TrayMessage, "", $aPos[0], @DesktopHeight, $iW, $iH)
    GUISetState(@SW_SHOWNA, $__hGUI_TrayMessage)
    WinMove($__hGUI_TrayMessage, "", $aPos[0], $aPos[1], $iW, $iH, 4)
    Return 1
EndFunc   ;==>ShowTrayMessage

Func HideTrayMessage($__hGUI_TrayMessage)
    GUISetState(@SW_SHOWNA, $__hGUI_TrayMessage)
    Local $aSize = WinGetPos($__hGUI_TrayMessage, "")
    Local $iW = $aSize[2], $iH = $aSize[3]
    Local $aPos = _Toast_Locate($iW, $iH)
    WinMove($__hGUI_TrayMessage, "", $aPos[0], @DesktopHeight, $iW, $iH + 4, 5)
    GUISetState(@SW_HIDE, $__hGUI_TrayMessage)
    Return 1
EndFunc   ;==>HideTrayMessage

; #FUNCTION# ====================================================================================================================
; Name ..........: _GDIPlus_BitmapCreateTrayMessage
; Description ...: Creates a tooltip like window using GDI+
; Syntax ........: _GDIPlus_BitmapCreateTrayMessage($sText[, $iW = 70[, $iH = 50[, $sFont = "Arial"[, $fFontSize = 12[,
;                  $iBGColor = 0xD0101010[, $iFontColor = 0xFF000000[, $iRadius = 8[, $hImage = 0[, $iImgPosX = 8[,
;                  $iImgPosY = 4[, $iImgW = 16[, $iImgH = 16[, $bGDIBmp = 1]]]]]]]]]]]]])
; Parameters ....: $sText               - A string value.
;                  $iW                  - [optional] An integer value. Default is 70.
;                  $iH                  - [optional] An integer value. Default is 50.
;                  $sFont               - [optional] A string value. Default is "Arial".
;                  $fFontSize           - [optional] A boolean value. Default is 12.
;                  $iBGColor            - [optional] An integer value. Default is 0xD0101010.
;                  $iFontColor          - [optional] An integer value. Default is 0xFF000000.
;                  $iRadius             - [optional] An integer value. Default is 8.
;                  $hImage              - [optional] A handle value. Default is 0.
;                  $iImgPosX            - [optional] An integer value. Default is 8.
;                  $iImgPosY            - [optional] An integer value. Default is 4.
;                  $iImgW               - [optional] An integer value. Default is 16.
;                  $iImgH               - [optional] An integer value. Default is 16.
;                  $bGDIBmp             - [optional] A binary value. Default is 1.
; Return values .: bitmap handle (GDI+ format bitmap)
; Version .......: 0.90 build 2014-10-07
; Author ........: UEZ
; Modified ......:
; Remarks .......: AutoIt version 3.3.9.18+ and Win7+ is needed. Don't forget to dispose returned bitmap handle!
; Related .......:
; Link ..........:
; Example .......: No
; ===============================================================================================================================
Func _GDIPlus_BitmapCreateTrayMessage($sText, $iW = 70, $iH = 40, $sFont = "Arial", $fFontSize = 12, $iBGColor = 0xD0101010, $iFontColor = 0xFFFFFFFF, $iRadius = 8, $hImage = 0, $iImgPosX = 8, $iImgPosY = 4, $iImgW = 16, $iImgH = 16, $bGDIBmp = 0)
    Local $iPenSize = 1, $iSize = 12, $iSize2 = $iSize / 2, $iDX = $iW / 2
    Local $iWidth = $iW - $iPenSize - $iSize, $iHeight = $iH - $iPenSize - $iSize
    Local $hBitmap = _GDIPlus_BitmapCreateFromScan0($iW, $iH)
    Local $hCtxt = _GDIPlus_ImageGetGraphicsContext($hBitmap)
    _GDIPlus_GraphicsSetSmoothingMode($hCtxt, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsSetTextRenderingHint($hCtxt, $GDIP_TEXTRENDERINGHINT_ANTIALIASGRIDFIT)
    Local $hPath = _GDIPlus_PathCreate(), $hMatrix = _GDIPlus_MatrixCreate()
    Local $iX = 0, $iY = 0
    _GDIPlus_PathAddArc($hPath, $iWidth - ($iRadius * 2), 0, $iRadius * 2, $iRadius * 2, 270, 90)
    _GDIPlus_PathAddArc($hPath, $iWidth - ($iRadius * 2), $iHeight - ($iRadius * 2), $iRadius * 2, $iRadius * 2, 0, 90)
    _GDIPlus_PathAddLine($hPath, $iWidth - ($iRadius * 2), $iHeight, $iDX + $iSize2, $iHeight)
    _GDIPlus_PathAddArc($hPath, 0, $iHeight - ($iRadius * 2), $iRadius * 2, $iRadius * 2, 90, 90)
    _GDIPlus_PathAddArc($hPath, 0, 0, $iRadius * 2, $iRadius * 2, 180, 90)
    _GDIPlus_PathCloseFigure($hPath)

    _GDIPlus_MatrixTranslate($hMatrix, $iSize / 2, $iSize / 2)
    _GDIPlus_GraphicsSetTransform($hCtxt, $hMatrix)

    Local $hBrush_Shadow = _GDIPlus_PathBrushCreateFromPath($hPath)
    _GDIPlus_PathBrushSetCenterColor($hBrush_Shadow, 0x00FFFFFF)
    _GDIPlus_PathBrushSetSurroundColor($hBrush_Shadow, 0x80000000)
    _GDIPlus_PathBrushSetGammaCorrection($hBrush_Shadow, True)
    _GDIPlus_GraphicsFillPath($hCtxt, $hPath, $hBrush_Shadow)

    Local $hEffect = _GDIPlus_EffectCreateBlur(4.5, 1)
    _GDIPlus_BitmapApplyEffect($hBitmap, $hEffect)

    _GDIPlus_MatrixTranslate($hMatrix, -$iSize / 2, -$iSize / 2)
    _GDIPlus_GraphicsSetTransform($hCtxt, $hMatrix)

    Local $hBrush = _GDIPlus_BrushCreateSolid($iBGColor)
    _GDIPlus_GraphicsFillPath($hCtxt, $hPath, $hBrush)
    Local $hPen = _GDIPlus_PenCreate(0xFF000000, $iPenSize)
    _GDIPlus_GraphicsDrawPath($hCtxt, $hPath, $hPen)

    _GDIPlus_PathReset($hPath)
    Local $hFamily = _GDIPlus_FontFamilyCreate($sFont)
    Local $hFormat = _GDIPlus_StringFormatCreate()
    Local $tLayout = _GDIPlus_RectFCreate($iRadius, $iRadius, $iWidth, $iHeight)
    _GDIPlus_StringFormatSetAlign($hFormat, 0)
    _GDIPlus_StringFormatSetLineAlign($hFormat, 0)

    _GDIPlus_BrushSetSolidColor($hBrush, $iFontColor)
    _GDIPlus_PathAddString($hPath, $sText, $tLayout, $hFamily, 0, $fFontSize * 1.3, 0)
    _GDIPlus_GraphicsFillPath($hCtxt, $hPath, $hBrush)

    If $hImage Then
        _GDIPlus_GraphicsSetInterpolationMode($hCtxt, $GDIP_INTERPOLATIONMODE_HIGHQUALITYBICUBIC)
        _GDIPlus_GraphicsDrawImageRectRect($hCtxt, $hImage, 0, 0, _GDIPlus_ImageGetWidth($hImage), _GDIPlus_ImageGetHeight($hImage), $iImgPosX, $iImgPosY, $iImgW, $iImgH)
    EndIf

    _GDIPlus_EffectDispose($hEffect)
    _GDIPlus_MatrixDispose($hMatrix)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_BrushDispose($hBrush_Shadow)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hCtxt)
    If $bGDIBmp Then
        Local $hGDIBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
        _GDIPlus_BitmapDispose($hBitmap)
        Return $hGDIBmp
    EndIf
    Return $hBitmap
EndFunc   ;==>_GDIPlus_BitmapCreateTrayMessage

Func _WinAPI_BitmapSetTransparent($hGUI, $hImage, $iOpacity = 0xFF)
    Local $hScrDC, $hMemDC, $hBitmap, $hOld, $pSize, $tSize, $pSource, $tSource, $pBlend, $tBlend
    $hScrDC = _WinAPI_GetDC(0)
    $hMemDC = _WinAPI_CreateCompatibleDC($hScrDC)
    $hBitmap = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)
    $hOld = _WinAPI_SelectObject($hMemDC, $hBitmap)
    $tSize = DllStructCreate($tagSIZE)
    $pSize = DllStructGetPtr($tSize)
    $tSize.X = _GDIPlus_ImageGetWidth($hImage)
    $tSize.Y = _GDIPlus_ImageGetHeight($hImage)
    $tSource = DllStructCreate($tagPOINT)
    $pSource = DllStructGetPtr($tSource)
    $tBlend = DllStructCreate($tagBLENDFUNCTION)
    $pBlend = DllStructGetPtr($tBlend)
    $tBlend.Alpha = $iOpacity
    $tBlend.Format = 1
    _WinAPI_UpdateLayeredWindow($hGUI, $hMemDC, 0, $pSize, $hMemDC, $pSource, 0, $pBlend, $ULW_ALPHA)
    _WinAPI_ReleaseDC(0, $hScrDC)
    _WinAPI_SelectObject($hMemDC, $hOld)
    _WinAPI_DeleteObject($hBitmap)
    _WinAPI_DeleteDC($hMemDC)
EndFunc   ;==>_WinAPI_BitmapSetTransparent

; #INTERNAL_USE_ONLY#============================================================================================================
; Name...........: _Toast_Locate
; Description ...: Find Systray and determine Toast start position and movement direction
; Syntax ........: _Toast_Locate($iToast_Width, $iToast_Height)
; Parameters ....: $iToast_Width  - required width of slice
;                  $iToast_Height - required height of slice
; Author ........: Melba23 - using some code from guinness and MilesAhead
; Modified.......:
; Remarks .......: This function is used internally by _Toast_Show
; ===============================================================================================================================
Func _Toast_Locate($iToast_Width, $iToast_Height)

    Local $tWorkArea

    ; Define return array
    Local $aToast_Data[3]
    ; Determine which struct syntax to use to use
    If @AutoItVersion < "3.3.8.0" Then
        $tWorkArea = DllStructCreate("long Left;long Top;long Right;long Bottom")
    Else
        $tWorkArea = DllStructCreate("struct;long Left;long Top;long Right;long Bottom;endstruct")
    EndIf

    ; Check if Taskbar is hidden
    Local $aRet = DllCall("shell32.dll", "uint", "SHAppBarMessage", "dword", 0x00000004, "ptr*", 0) ; $ABM_GETSTATE
    If BitAND($aRet[0], 0x01) Then

        ; Find hidden taskbar
        Local $iPrevMode = Opt("WinTitleMatchMode", 4)
        Local $aTray_Pos = WinGetPos("[CLASS:Shell_TrayWnd]")
        Opt("WinTitleMatchMode", $iPrevMode)
        ; If error in finding systray
        If Not IsArray($aTray_Pos) Then Return SetError(2, 0, -1)

        ; Determine direction of Toast motion and starting position
        If $aTray_Pos[1] > 0 Then
            $iToast_Move = 0x00050004 ; $AW_SLIDE_OUT_BOTTOM
            $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
            $aToast_Data[1] = $aTray_Pos[1] - $iToast_Height - 2
            $aToast_Data[2] = 0x00040008 ; $AW_SLIDE_IN_BOTTOM
        ElseIf $aTray_Pos[0] > 0 Then
            $iToast_Move = 0x00050001 ; $AW_SLIDE_OUT_RIGHT
            $aToast_Data[0] = $aTray_Pos[0] - $iToast_Width - 2
            $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
            $aToast_Data[2] = 0x00040002 ; $AW_SLIDE_IN_RIGHT
        ElseIf $aTray_Pos[2] > @DesktopWidth - 70 Then
            $iToast_Move = 0x00050008 ; $AW_SLIDE_OUT_TOP
            $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
            $aToast_Data[1] = $aTray_Pos[1] + $aTray_Pos[3]
            $aToast_Data[2] = 0x00040004 ; $AW_SLIDE_IN_TOP
        ElseIf $aTray_Pos[3] >= @DesktopHeight Then
            $iToast_Move = 0x00050002 ; $AW_SLIDE_OUT_LEFT
            $aToast_Data[0] = $aTray_Pos[0] + $aTray_Pos[2]
            $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
            $aToast_Data[2] = 0x00040001 ; $AW_SLIDE_IN_LEFT
        EndIf

    Else

        ; Determine available work area ; $SPI_GETWORKAREA = 48
        DllCall("user32.dll", "bool", "SystemParametersInfoW", "uint", 48, "uint", 0, "ptr", DllStructGetPtr($tWorkArea), "uint", 0)
        If @error Then Return SetError(2, 0, -1)
        Local $aWorkArea[4] = [DllStructGetData($tWorkArea, "Left"), DllStructGetData($tWorkArea, "Top"), _
                DllStructGetData($tWorkArea, "Right"), DllStructGetData($tWorkArea, "Bottom")]

        ; Determine direction of Toast motion and starting position
        If $aWorkArea[3] <> @DesktopHeight Then
            $iToast_Move = 0x00050004 ; $AW_SLIDE_OUT_BOTTOM
            $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
            $aToast_Data[1] = $aWorkArea[3] - $iToast_Height - 2
            $aToast_Data[2] = 0x00040008 ; $AW_SLIDE_IN_BOTTOM
        ElseIf $aWorkArea[2] <> @DesktopWidth Then
            $iToast_Move = 0x00050001 ; $AW_SLIDE_OUT_RIGHT
            $aToast_Data[0] = $aWorkArea[2] - $iToast_Width - 2
            $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
            $aToast_Data[2] = 0x00040002 ; $AW_SLIDE_IN_RIGHT
        ElseIf $aWorkArea[1] <> 0 Then
            $iToast_Move = 0x00050008 ; $AW_SLIDE_OUT_TOP
            $aToast_Data[0] = @DesktopWidth - $iToast_Width - 10
            $aToast_Data[1] = $aWorkArea[1]
            $aToast_Data[2] = 0x00040004 ; $AW_SLIDE_IN_TOP
        ElseIf $aWorkArea[0] <> 0 Then
            $iToast_Move = 0x00050002 ; $AW_SLIDE_OUT_LEFT
            $aToast_Data[0] = $aWorkArea[0]
            $aToast_Data[1] = @DesktopHeight - $iToast_Height - 10
            $aToast_Data[2] = 0x00040001 ; $AW_SLIDE_IN_LEFT
        EndIf

    EndIf

    Return $aToast_Data

EndFunc   ;==>_Toast_Locate

Thx to Melba23 for the _Toast_Locate function.

 

Works only for Win7+ operating systems.

 

Br,

UEZ

Edited July 10, 2014 by UEZ

[mLipok]

Very nice UEZ.

Question:

Can I wait for WM_MESSAGE (I mean click) from $hGUI_ToolTip instead Sleep(3000) ?

[UEZ]

@mLipok: I updated the code from post#3.

It doesn't check whether the taskbar is not at the bottom to adjust the tray message's position appropriately.

Br,

UEZ

[mLipok]

Awesome.

Thanks.

mLipok

[mLipok]

but I think you forgot about something

Global $hGUI_TrayMessage = CreateTrayMessage("Text Message" & @CRLF & @CRLF & "Test1" & @CRLF & @CRLF & "Test2" & @CRLF & @CRLF & "Test3", 350, 200)

not working

[UEZ]

Forgot to remove the hard coded text.

Fixed now.

Thanks for your feedback.

Br,

UEZ