Combobox Change Value

[MacScript]

Is there a way to dynamically change a value in a drop down box.

For instance the drop down box has the following options to select

• Setup
• Mode-Dual
• Copy
• Filter

When the person selects the Option -> Mode-Dual <- Event handle does a few things but also changes the list to look like ->

• Setup
• Mode-Single
• Copy
• Filter

Then if the person would choose Mode-Single it would then change back to Mode-Dual.

I have looked over the forums and internet and have not found anything that helps me accomplish this.

Any pointers would be appreciated (Don't really want to do a control destroy and create it again if I can avoid that).

Thanks

[JohnOne]

GuiCtrlSetData

[MacScript]

Thanks Johnone

That is only a part of it.

Need to take the entire contents of the dropdown box.

Do a string replace

Then Empty the contents of the control

Then add the data back into the control

Sample code below:

_GUICtrlComboBox_ResetContent($cmbMainOpt)
$tmpMainMenuOpt = StringReplace($tmpMainMenuOpt, "Mode-Dual", "Mode-Single")
GUICtrlSetData($cmbMainOpt, $tmpMainMenuOpt)

[Melba23]

MacScript,

You are overcomplicating things - using GUICtrlSetData with a leading "|" will replace the data automatically:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$sData_Dual = "|Setup|Mode-Dual|Copy|Filter"     ; Note leading "|"
$sData_Single = "|Setup|Mode-Single|Copy|Filter"

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData($cCombo, $sData_Dual)
$fDual = True ; Set a flag

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo
            Switch GUICtrlRead($cCombo)
                Case "Setup"
                    MsgBox($MB_SYSTEMMODAL, "Selected", "Setup")
                Case "Copy"
                    MsgBox($MB_SYSTEMMODAL, "Selected", "Copy")
                Case "Filter"
                    MsgBox($MB_SYSTEMMODAL, "Selected", "Filter")
                Case Else
                    $fDual = Not $fDual ; Toggle the flag
                    If $fDual Then
                        GUICtrlSetData($cCombo, $sData_Dual)
                    Else
                        GUICtrlSetData($cCombo, $sData_Single)
                    EndIf
            EndSwitch
    EndSwitch

WEnd

M23

[MacScript]

Thanks for the information about using the "|". However I still will do the string replace cause I suspect this dropdown in the future will have other options to swap in and out. Thanks again