How to reactivate a RichEdit control?

[qwert]

It's a common situation for a user to select a portion of text in a RichEdit control and then click away to another control to perform some other action.  Following that other action, how can I automatically return focus to the RichEdit field without disturbing any prior text selection?   I’ve tried various combinations of GUISetState and GUICtrlSetState, plus WinAPI_SetFocus, but nothing has worked. Here’s another view of the problem:

 

GUICtrlSetState($i_RichEdit, $GUI_FOCUS)      ; set focus with all text selected

 

ControlClick($hGui, "", $i_RichEdit)                     ; set focus with no text selected

 

______<unknown command>_________            ; set focus with previous text still selected

 

The user can accomplish the third method by simply clicking in the field. That activates the field and any prior selection is still active. But short of trying to figure out a proper cursor position and exactly duplicate the user’s click, isn’t there a specific and direct way?

 

Thanks in advance for any help.

[mLipok]

Try this:

[mLipok]

Working example:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $hRichEdit, $aSelection
Example()

Func Example()
    Local $hGui, $iMsg
    $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is more text")
    Local $idButton = GUICtrlCreateButton('test',10,240,300,20)
    GUIRegisterMsg($WM_COMMAND, "MY_WM_COMMAND")
    GUISetState(@SW_SHOW)

    While True
        $iMsg = GUIGetMsg()
        Select
            Case $iMsg = $GUI_EVENT_CLOSE
                _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                ; GUIDelete()   ; is OK too
                Exit
        EndSelect
    WEnd
EndFunc   ;==>Example

Func MY_WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    Local $nNotifyCode = BitShift($wParam, 16)
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $hCtrl = $lParam
    Switch $hCtrl
        Case $hRichEdit
            Switch $nNotifyCode
                Case $EN_KILLFOCUS
                    $aSelection = _GUICtrlRichEdit_GetSel($hRichEdit)
                Case $EN_SETFOCUS
                    _GUICtrlRichEdit_SetSel($hRichEdit,$aSelection[0],$aSelection[1])
            EndSwitch
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc ;==>MY_WM_COMMAND

[qwert]

Thanks for the suggestion.  It so happens that I found the solution in the response to a post I made for a similar problem back in June.  Danp2 had suggested _WinAPI_SwitchToThisWindow

Indeed, it works perfectly to get the user back to exactly where they were.

To summarize, here are three alternatives:

GUICtrlSetState($i_RichEdit, $GUI_FOCUS)      ; set focus with all text selected

 ControlClick($hGui, "", $i_RichEdit)                     ; set focus with no text selected

 _WinAPI_SwitchToThisWindow($hGUI_Child)    ; set focus with previous text still selected

 ... where $hGUI_Child is the window containing the RichEdit control (... which may also work in place of $hGUI, above ... but I didn't test that).

Edited January 8, 2017 by qwert
corrected spacing

[mLipok]

But what happend when you just just {TAB} on the same GUI ?

[qwert]

I had tried {Tab} and nothing happened.  I couldn't determine if any window received it or not.