Restrict Edit UDF and HH:MM AM/PM

[ijourneaux]

I am not very knowledge with RegEx expressions so I am having difficulty using the Restric Edit UDF to control limit the user to a HH:MM am/pm formatted entry.

Is there a source of examples? that I would be able to model after?

For the purposes of REstrict Edit what would the correct regex string be?

Ian

[JohnOne]

You should post a link to that UDF, I've never heard of it.

[mLipok]

I think OP mean RestrictEdit_SRE (UDF) by PhoenixXL.

[ijourneaux]

Thanks WIll post to that thread directly

[kylomas]

ijoureaux,

The author of that thread has not been on in awhile.  Here's an example of how it might be done. 

expandcollapse popup

#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <WindowsConstants.au3>
#include <winapi.au3>

GUICreate('MyGUI', 300, 200)
guictrlcreatelabel('Enter Time in HH:MM AM|PM format',10,10,200,20)
$edit = GUICtrlCreateInput('', 10, 30, 120, 30)
guictrlsetfont(-1,16)
$warn = guictrlcreatelabel('',10,160,180,30)
guictrlsetcolor(-1,0xaa0000)
GUIRegisterMsg($WM_COMMAND, 'WM_COMMAND')
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    Switch BitAND($wParam, 0xFFFF)
        Case $edit
            Switch BitShift($wParam, 16)
                Case $EN_update
                    guictrlsetdata($warn,'')
                    switch stringlen(guictrlread($edit))
                        case 1,2
                            if not stringisdigit(guictrlread($edit)) then
                                guictrlsetdata($edit,'')
                                guictrlsetdata($warn,'Chars 1 and 2 must be numeric')
                            EndIf
                        case 3
                            if not stringregexp(guictrlread($edit),'\d\d\:') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'3RD char must be a :')
                            EndIf
                        case 4
                            if not stringregexp(guictrlread($edit),'\d\d\:\d') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'4TH char must be a numeric')
                            EndIf
                        case 5
                            if not stringregexp(guictrlread($edit),'\d\d\:\d\d') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'5TH char must be a numeric')
                            EndIf
                        case 6
                            if not stringregexp(guictrlread($edit),'\d\d\:\d\d ') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'6TH char must be a space')
                            EndIf
                        case 7
                            if not stringregexp(guictrlread($edit),'(?i)\d\d\:\d\d a|p') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'7TH char must be an "a" or "p"')
                            endif
                        case 8
                            if not stringregexp(guictrlread($edit),'(?i)\d\d\:\d\d (a|p)m') then
                                guictrlsetdata($edit,stringtrimright(guictrlread($edit),1))
                                guictrlsetdata($warn,'8TH char must be an "m"')
                            endif
                    endswitch
            EndSwitch
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

There might be a way to edit the input using one SRE but I don't speak Klignon that well.

Another possibility is to use a date control.

kylomas

Edited August 13, 2014 by kylomas

[mikell]

Another possibility is to use a date control.

 

Or use 2 combos to enter hour and min 

@kylomas

This one will accept 24h format without am/pm, but will force to add am/pm if 12h format

$txt = "05:18 pm"  ; "5:18 am"  ; "00:15" ; "23:48"  ; "13:35" ; "12:45"  ; valid
;$txt = "05:18"  ; "13:15 am"  ; "12:35 pm" ; "00:15 am"  ; "22:35 pm"    ; invalid   

$res = StringRegExp($txt, '(?ix)^\h*(((((0?[1-9])|(1[01])):([0-5]\d))(\h*[ap]m))|(((0?0?)|(1[2-9])|(2[0-3])):[0-5]\d))\h*$' )

Msgbox(0,"", $res)

Edit : rectif

Edited August 13, 2014 by mikell

[kylomas]

@mikell - Thanks.  I believe that PhoenixXL's code is based on either subclassing the control or operating on EN_UPDATE.  Since the OP referred to that code I assumed that he wanted a character by character edit.

@ijouneaux - If you do NOT want character by character editing then mikell's SRE can be applied to the whole pattern in the message loop.

Edited August 13, 2014 by kylomas

[mikell]

Honestly, a simpler way (using combos) is better by far, the digits checking is tricky 

[kylomas]

Agreed, but that is not the road the OP started down.

[mikell]

PhoenixXL's UDF needs to define patterns to be used for char by char checking and this will be tricky if a time format (12 or 24h) is not forced

[kylomas]

Again agreed...

Directly from the Help file for date contorl...

#include <DateTimeConstants.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    GUICreate("My GUI get time", 200, 200, 800, 200)
    Local $idDate = GUICtrlCreateDate("", 20, 20, 100, 20, $DTS_TIMEFORMAT)
    GUISetState(@SW_SHOW)

    ; Loop until the user exits.
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd

    MsgBox($MB_SYSTEMMODAL, "Time", GUICtrlRead($idDate))
    GUIDelete()
EndFunc   ;==>Example

If the user does NOT need char by char editing then I believe this is the simplest way  (the second can be striped off if needed)

[mikell]

As the OP mentioned "limit the user to a HH:MM am/pm formatted entry"  this GuiCtrlCreateDate way is - IMHO - the best one