_INetSmtpMailCom Compile Error on new Windows 7 PC

[FrozenTeeth]

My old windows 7 PC compiles just fine. My new windows 7 machine gets an error. Not sure if it's a configuration or I'm missing something

i'm using the _INetSmtpMailCom to send email and it compiles and runs and works fine on my other machine but when I try to compile it on the new machine I get:

"G:JayAutoIT_ScriptsMyCoolProgram.au3"(859,12) : error: missing separator character before keyword.

$objEmail.To

~~~~~~~~~~^

G:JayAutoIT_ScriptsMyCoolProgram.au3 - 1 error(s), 0 warning(s)

!>11:09:01 AU3Check ended. Press F4 to jump to next error.rc:2

 

 

This is the code i'm using for email:

 

 

expandcollapse popup

Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                $i_Error_desciption = $i_Error_desciption & @LF & 'File not found to attach: ' & $S_Files2Attach[$x]
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
EndFunc   ;==>_INetSmtpMailCom

 

[JLogan3o13]

Is there a space between the period and the word To?

[BrewManNH]

It's a bug in AU3Check see this track ticket for a solution

https://www.autoitscript.com/trac/autoit/ticket/2731

[FrozenTeeth]

Odd. Still happens if I use the compile with Beta

.. I also retyped the line many times

Edited August 15, 2014 by FrozenTeeth

[BrewManNH]

Turn off Au3Check in the tools menu under Compile (CTRL + F7), it's not AutoIt that's complaining it's Au3Check.

[FrozenTeeth]

Turn off Au3Check in the tools menu under Compile (CTRL + F7), it's not AutoIt that's complaining it's Au3Check.

 

Bingo! Thanks!