Array combinations

[guinness]

Anyone know if a function already exists for an output like this? _ArrayCombinations()  doesn't quite do this. Thanks.

Local $aArray = ['A', 'B', 'C']
#cs
    A
    B
    C
    AA
    AB
    AC
    BA
    BB
    BC
    CA
    CB
    CC
    AAA
    AAB
    AAC
    ABA
    ABB
    ABC
    ACA
    ACB
    ACC
    ...
#ce

[PainTain]

_ArrayPermute

maybe?

[guinness]

Nope. But thanks anyway.

[jguinch]

It's not a existing function, but I made one for myself (not posted).

Maybe it can be usefull :

expandcollapse popup

#include <Array.au3> ; just for _ArrayDiplay

Local $aData[6] = ['a', 'b', 'c', 'd', 'e', 'f']
Local $aCombi = _DataCombinations($aData, 6)
_ArrayDisplay($aCombi)



; #FUNCTION# ====================================================================================================================
; Name ..........: _DataCombinations
; Description ...: Returns an array of all possible combinations of a string or array
; Syntax ........: _DataCombinations($vData, $iLen)
; Parameters ....: $vData               - Data to use for combinations (can be a string or a 1D array)
;                  $iLen                - Length of the combination.
; Return values .: An array of the whole combinations
; Author ........: JGUINCH
; ===============================================================================================================================
Func _DataCombinations($vData, $iLen)
    Local $aData = $vData, $k, $iIndex, $iTemp

    If IsString($vData) Then $aData = StringRegExp($vData, ".", 3)

    Local $iSize = UBound($aData) ^ $iLen
    Local $aResult[$iSize]

    For $x = $iLen To 1 Step -1
        $iIndex = 0
        $iTemp = 0
        $n = Ubound($aData) ^ ( $x - 1)

        For $i = 1 To $iSize
            If $iTemp = $n Then
                $iTemp = 0
                If $iIndex = UBound($aData) - 1 Then
                    $iIndex = 0
                Else
                    $Iindex += 1
                EndIf
            EndIf

            $aResult[$i - 1] &= $aData[$iIndex]
            $iTemp += 1
        Next
    Next

    Return $aResult

EndFunc

You can make a loop from 1 to UBound($aData) - 1 to get all combinations

Edited August 23, 2014 by jguinch

[guinness]

Thanks.

I won't mark it as solved just yet.

[jchd]

I'm afraid your only way is to code that by yourself. There aren't enough combinatorics primitives built-in UDFs right now. BTW this isn't a common operation on sets.

[guinness]

I'm afraid your only way is to code that by yourself. There aren't enough combinatorics primitives built-in UDFs right now. BTW this isn't a common operation on sets.

OK. The reason I am asking is I am looking at adding variable renaming to PreExpand and wishing to use the lowest possible combination first and then work from there.

[jchd]

Number them in hex?

[guinness]

Number them in hex?

Ah...nice idea.

[Gianni]

another attempt

(of course the input array can have different number of elements)

Local $aInput[3] = ["A", "B", "C"]

_MultiLoop($aInput)
;
; ---------------------------------------------------------------
; simulates nested for next loops with variable levels of nesting
; ---------------------------------------------------------------
Func _MultiLoop(ByRef $Array)
    ; prepare simulated "For Next" loops
    $Elements = UBound($Array)
    Local $aLoops[$Elements][4]
    For $i = 0 To $Elements - 1
        $aLoops[$i][0] = 0 ;               starting of loop
        $aLoops[$i][1] = $Elements - 1 ;   end of loop
        $aLoops[$i][2] = 1 ;               step
        $aLoops[$i][3] = $aLoops[$i][0] ;  internal use (same as [$i][0] at starting)
    Next
    Do
        ; --- Output results to console just for example -
        For $zz = $Elements - 1 To 0 Step -1
            ConsoleWrite($Array[$aLoops[$zz][3]])
        Next
        ConsoleWrite(@CRLF)
        ; ------------------------------------------------
        ;
        $x = UBound($aLoops) - 1
        $aLoops[$x][3] += $aLoops[$x][2]
        While ($aLoops[$x][3] < $aLoops[$x][$aLoops[$x][0] >= $aLoops[$x][1]]) Or ($aLoops[$x][3] > $aLoops[$x][$aLoops[$x][0] < $aLoops[$x][1]])
            $aLoops[$x][3] = $aLoops[$x][0] ; reset counter
            $x -= 1
            If $x < 0 Then ExitLoop
            $aLoops[$x][3] += $aLoops[$x][2]
        WEnd
    Until $x < 0
EndFunc   ;==>_MultiLoop

[guinness]

Thanks Chimp. Though up until now no one has really presented the output I posted above. I am going with jchd's recommendation.

[Gianni]

new attempt

(previous listing slightly modified)
it just sends output to console, but can be easily modified to return an array

Local $aInput[3] = ["A", "B", "C"]
_MultiLoop($aInput)


; combinatory of elements
; -----------------------
Func _MultiLoop(ByRef $Array)
    Local $Elements = UBound($Array)
    For $items = 0 To $Elements - 1
        ; each time icrease elements of $Array involved in permutation
        Local $aLoops[$items + 1][4]
        For $i = 0 To $items
            $aLoops[$i][0] = 0 ;               starting of loop
            $aLoops[$i][1] = $Elements - 1 ;   end of loop
            $aLoops[$i][2] = 1 ;               step
            $aLoops[$i][3] = $aLoops[$i][0] ;  internal use (same as [$i][0] at starting)
        Next
        Do
            ; --- Output results to console just for example -
            For $zz = 0 To UBound($aLoops) - 1
                ConsoleWrite($Array[$aLoops[$zz][3]])
            Next
            ConsoleWrite(@CRLF)
            ; ------------------------------------------------
            ;
            $x = UBound($aLoops) - 1
            $aLoops[$x][3] += $aLoops[$x][2]
            While ($aLoops[$x][3] < $aLoops[$x][$aLoops[$x][0] >= $aLoops[$x][1]]) Or ($aLoops[$x][3] > $aLoops[$x][$aLoops[$x][0] < $aLoops[$x][1]])
                $aLoops[$x][3] = $aLoops[$x][0] ; reset counter
                $x -= 1
                If $x < 0 Then ExitLoop
                $aLoops[$x][3] += $aLoops[$x][2]
            WEnd
        Until $x < 0
    Next
EndFunc   ;==>_MultiLoop

[jguinch]

expandcollapse popup

#include <Array.au3> ; just for _ArrayDiplay

Local $aData[6] = ['a', 'b', 'c', 'd', 'e', 'f']
Local $aCombi = _DataCombinations($aData)
_ArrayDisplay($aCombi)


; #FUNCTION# ====================================================================================================================
; Name ..........: _DataCombinations
; Description ...: Returns an array of all possible combinations of an array
; Syntax ........: _DataCombinations($aData)
; Parameters ....: $aData               - Data to use for combinations (must be a 1D array)
; Return values .: An array of the whole combinations
; Author ........: JGUINCH
; ===============================================================================================================================
Func _DataCombinations($aData)
    Local $iIndex, $iTemp, $iSize = 0, $iPos = 0
    If NOT IsArray($aData) Then Return SetError(1, 0, 0)

    For $i = 1 To UBound($aData)
        $iSize += UBound($aData) ^ $i
    Next
    Local $aResult[$iSize]
    
    For $iLen = 1 To UBound($aData)
        $iSize = UBound($aData) ^ $iLen

        For $x = $iLen To 1 Step -1
            $iIndex = 0
            $iTemp = 0
            $n = Ubound($aData) ^ ( $x - 1)

            For $i = 1 To $iSize
                If $iTemp = $n Then
                    $iTemp = 0
                    If $iIndex = UBound($aData) - 1 Then
                        $iIndex = 0
                    Else
                        $Iindex += 1
                    EndIf
                EndIf

                $aResult[$iPos + $i - 1] &= $aData[$iIndex]
                $iTemp += 1
            Next
        Next
        $iPos += ( UBound($aData) ^ ($iLen) )
    Next

    Return $aResult
EndFunc ; ===> _DataCombinations

Edited August 24, 2014 by jguinch

[guinness]

Thanks all. Your time and effort is much appreciated.

Edited August 24, 2014 by guinness

[jguinch]

The excercise you've proposed is interesting...

[guinness]

The excercise you've proposed is interesting...

Excellent.

[kylomas]

The excercise you've proposed is interesting...

 

@jguinch - Yes, I've been thinking about this on and off since guinness asked the question and got no where near your elegant solution...excellent (as guinness said)

[jguinch]

So, this function could be in the next beta...

[guinness]

So, this function could be in the next beta...

No, because it's specific to only one user's needs and not the community in general.

[jguinch]

I know Guinness, I joke

But, not only for one user : http://www.autoitscript.fr/forum/viewtopic.php?f=20&t=12172#p84486