Yet another StringRegExp question

[mjolnirmarkiv]

Hi there!

I have two strings in two possible formats as seen below that I need to process and get a date.

I understand that it could be done with two patterns, but ideally I want to process it within single StringRegExp. As of now it returns following array of matches:

["August", "02", "2014"] for $s1, which is not exactly what I want

and

["2014", "08", "27"] for $s2, which is exactly what I want

I need to redo the pattern so it will return array of matches in following format ["YYYY", "MM", "DD"] for both strings.

#include <Array.au3>

$s1 = "Deadline Saturday, August 02, 2014 6:17 AM"
$s2 = "Deadline:    [2014-08-27 16:00:00 [Central European Time]]"
$pattern = "(?i)Deadline.*?(?:,\s|\[)(.*?)(?:\s|-)(.*?)(?:,\s|-)(.*?)\s"

_ArrayDisplay (StringRegExp ($s1, $pattern, 1))
_ArrayDisplay (StringRegExp ($s2, $pattern, 1))

Thank in advance for help!

 

P.S.: converting name of the month into a double-digit code is a problem for another time, shouldn't be too hard.

[Melba23]

mjolnirmarkiv,

No doubt one of the RegEx gurus will be along at some point to show you how it can be done in one pass, but I would do it like this (and you get the month converted to numeric form as well ):

#include <Array.au3>
#include <StringConstants.au3>
#include <DTC.au3>

$s1 = "Deadline Saturday, August 02, 2014 6:17 AM"
$s2 = "Deadline:    [2014-08-27 16:00:00 [Central European Time]]"

$aRet = _ReadDate($s1)
_ArrayDisplay($aRet, "", Default, 8)

$aRet = _ReadDate($s2)
_ArrayDisplay($aRet, "", Default, 8)

Func _ReadDate($sString)

    ; Check which type of string is passed
    If StringRegExp($sString, "\d{4}-\d{2}-\d{2}") Then
        ; Extract date elements
        $sDate = StringRegExpReplace($sString, ".*\[(\d{4})-(\d{2})-(\d{2}).*", "$1 $2 $3")
    Else
        ; Extract date elements
        $sDate = StringRegExpReplace($sString, ".*,\s(\w+)\s(\d{2}),\s(\d{4}).*", "$2 $1 $3")
        ; Convert to numeric month
        $sDate = _Date_Time_Convert($sDate, "dd MMMM yyyy", "yyyy MM dd")
    EndIf
    ; Split string into array
    Return StringSplit($sDate, " ", $STR_NOCOUNT)

EndFunc

You can find the link to my DateTimeConvert UDF in my sig.

M23

[jchd]

No better idea here. "When NOT to use XYZ" is the point.

[jguinch]

There is certainly easier, but here is a way :

#include <Array.au3>

$s1 = "Deadline Saturday, August 02, 2014 6:17 AM"
$s2 = "Deadline:    [2014-08-27 16:00:00 [Central European Time]]"

$pattern = "(?xmi)^Deadline[:\h]+(?|  (?=(?:\[(\d{4})-(\d{2})-(\d{2}))) |  (?:(?=[a-z]+,\h+.*?(\d{4})) (?=.*?,\h+(\w+))  (?=.*?(\d{2}))  ) )"

_ArrayDisplay( StringRegExp($s1, $pattern, 3) )
_ArrayDisplay( StringRegExp($s2, $pattern, 3) )

http://regex101.com/r/pN3hG2/3

Edited September 17, 2014 by jguinch

[mjolnirmarkiv]

@Melba23

Well aware of that UDF, thanks!

@jguinch

Much appreciated, I knew look ahead is the key here, but didn't think of using capturing groups inside it