Assign 'varname' - Cannot be an array element ?

[mLipok]

Here is description form beta HelpFile for Assign for parameters "varname" :

 

The name of the variable you wish to assign. Cannot be an array element and must only contain letters, digits and underscore characters (as per normal variable naming conventions).

 

and here is my test snippet:

#AutoIt3Wrapper_Run_Tidy=y
#include <array.au3>

Example()

Func Example()
    MsgBox(0, 'Test Assign', _
            Assign("aTest", FileReadToArray(@ScriptFullPath)))
    #forcedef $aTest
    _ArrayDisplay($aTest, '$aTest')

    Local $sFile = @ScriptDir & '\TestAssign.txt'
    FileDelete($sFile)
    FileWrite($sFile, @CRLF & @CRLF & @CRLF)

    MsgBox(0, 'TEST ReAssign', _
            Assign("aTest", FileReadToArray($sFile)))

    Local $aEvalString = Eval("aTest")
    _ArrayDisplay($aEvalString, '$aEvalString')

EndFunc   ;==>Example

So my question: is this statement: "Cannot be an array element" is still valid ?

or something I do not understand ?

mLipok

 

edit: snippet changed - now is better

Edited September 19, 2014 by mLipok

[Jos]

This is an array element: $test[0]

Does that also work?

Jos

Edited September 19, 2014 by Jos

[mLipok]

You mean this :

#AutoIt3Wrapper_Run_Tidy=y
#include <array.au3>

Example()

Func Example()
    Local $aTest[3] = [1, 2, 3]
    _ArrayDisplay($aTest, 'First check: $aTest')

    MsgBox(0, 'Test Assign', _
            Assign("aTest", FileReadToArray(@ScriptFullPath)))
    #forcedef $aTest
    _ArrayDisplay($aTest, '$aTest')

    Local $sFile = @ScriptDir & '\TestAssign.txt'
    FileDelete($sFile)
    FileWrite($sFile, @CRLF & @CRLF & @CRLF)

    MsgBox(0, 'TEST ReAssign', _
            Assign("aTest", FileReadToArray($sFile)))

    Local $aEvalString = Eval("aTest")
    _ArrayDisplay($aEvalString, '$aEvalString')

EndFunc   ;==>Example

Yes it works .

[jguinch]

For me, Cannot be an array means that the varname cannot be an array element, like this : Assign("test[0]", 1)

[Jos]

For me, Cannot be an array means that the varname cannot be an array element, like this : Assign("test[0]", 1)

correct

[mLipok]

For me, Cannot be an array means that the varname cannot be an array element, like this : Assign("test[0]", 1)

"The name of the variable you wish to assign"

clearly excludes the example that you point, so

"Cannot be an array element"

is not related to your meaning.

or something I do not understand ?

[mLipok]

now I see

"cannot be an array element,"

but is it true ?

Look here:

#AutoIt3Wrapper_Run_Tidy=y
#include <array.au3>

Example()

Func Example()
    Local $aTest2[3] = [1, 'aTest', 3]
    _ArrayDisplay($aTest2, 'First check: $aTest')

    ; now I'am using Array element $aTest2[1]
    MsgBox(0, 'Test Assign', _
            Assign($aTest2[1], FileReadToArray(@ScriptFullPath)))
    #forcedef $aTest
    _ArrayDisplay($aTest, '$aTest')

    Local $sFile = @ScriptDir & '\TestAssign.txt'
    FileDelete($sFile)
    FileWrite($sFile, @CRLF & @CRLF & @CRLF)

    MsgBox(0, 'TEST ReAssign', _
            Assign("aTest", FileReadToArray($sFile)))

    Local $aEvalString = Eval("aTest")
    _ArrayDisplay($aEvalString, '$aEvalString')

EndFunc   ;==>Example

EDIT Script: added comment ; now I'am using Array element $aTest2[1]

Edited September 19, 2014 by mLipok

[Jos]

Mmm so now you are not using an literal string as first parameter but the actual element.

So tell me what happened when using it as a litteral string, which is the common use?

Jos

Edited September 19, 2014 by Jos

[mLipok]

Assign("test[0]", 1)

it is not Array Element but normal string.

and looking in description

must only contain letters, digits and underscore characters (as per normal 
variable naming conventions)

so this one is invalid

?

EDIT: I must go out for minimum 2 hours.

Edited September 19, 2014 by mLipok

[mLipok]

Mmm so now you are not using an literal string as first parameter but the actual element.

So tell me what happened when using it as a litteral string, which is the common use?

Jos

 

You mean.

Local $aTest2[3] = [1, 'aTest', 3]
    MsgBox(0, 'Test Assign', _
            Assign('aTest2[1]', FileReadToArray(@ScriptFullPath)))

Assign Return Value = 0  .

There is no assigement.

Now all is clear - I mean I understand what exactly HelpFile say. But it was not so clear before.

I think this below snippet would be a good refreshed example to HelpFile:

#include <array.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Assign the variable string sString with data.
    Assign("sString", "This is a string which is declared using the function Assign")

    ; Find the value of the variable string sString and assign to the variable $sEvalString.
    Local $sEvalString = Eval("sString")

    ; Display the value of $sEvalString. This should be the same value as $sString.
    MsgBox($MB_SYSTEMMODAL, "", $sEvalString)

    ; example how you can not try to assign
    Local $aTest[3] = [1, 2, 3]
    MsgBox($MB_SYSTEMMODAL, "Assign", 'Return Value = ' & Assign("aTest[2]", "TEST STRING"))

    _ArrayDisplay($aTest,'Testing $aTest[2]')

EndFunc   ;==>Example

EDIT: removed duplicated word

Edited September 19, 2014 by mLipok

[Melba23]

mLipok,

 

But it was not so clear before

I am afraid I completely disagree. The Help file comment is perfectly clear - the problem was your misunderstanding of what was meant by "an array element".

M23

[mLipok]

I am afraid I completely disagree. The Help file comment is perfectly clear - the problem was your misunderstanding of what was meant by "an array element".

 

on reflection ... good point

Thanks to all the participants in this thread.

mLipok