Why does this for statement only check the first variable

[Maelstrom]

Hey guys,

This is an interesting problem that I have come across.  For some reason, this for...next loop only ever checks the first variable in the array.

Global $rules[3] = ["MozillaWindowClass|VEIW_MOZILLA>1>KLOG", "CabinetWClass|VEIW_FILES>2>KLOG", "SunAwtFrame|VEIW_JITSI>3>KLOG"]

while 1
     ConsoleWrite(rulecheck())
wend

Func rulecheck()
   $active = _WinAPI_GetClassName(WinGetHandle("[ACTIVE]"))
   For $i In $rules
      $si = _StringExplode($i, "|")
      If WinActive("[CLASS:" & $si[0] & "]") Then
            Return $si[1]
         Else
            Return "NULLVAL"
      EndIf
   Next
EndFunc

So my question is how can I prevent it from doing that?

[guinness]

Because you have return on failure if WinActive() returns false.

[jdelaney]

Move the Return on the negative case outside of the loop.

Func rulecheck()
    $active = _WinAPI_GetClassName(WinGetHandle("[ACTIVE]"))
    For $i In $rules
        $si = _StringExplode($i, "|")
        If WinActive("[CLASS:" & $si[0] & "]") Then
            Return $si[1]
        EndIf
    Next
    Return "NULLVAL"
EndFunc

[guinness]

Here, ponder over this code.

#include <String.au3>

Global $g_aRules = ["MozillaWindowClass|VEIW_MOZILLA>1>KLOG", "CabinetWClass|VEIW_FILES>2>KLOG", "SunAwtFrame|VEIW_JITSI>3>KLOG"]

Local $sWindowClass = ""
While 1
    $sWindowClass = RuleCheck()
    If Not @error Then
        ConsoleWrite($sWindowClass & @CRLF)
    Else
        ConsoleWrite("No window was found to be active." & @CRLF)
    EndIf
    Sleep(100) ; Pause the loop for 100 ms.
WEnd

Func RuleCheck()
    Local $aExplode = 0
    For $i = 0 To UBound($g_aRules) - 1
        $aExplode = _StringExplode($g_aRules[$i], "|")
        If WinActive("[CLASS:" & $aExplode[0] & "]") Then
            Return $aExplode[1]
        EndIf
    Next
    Return SetError(1, 0, "") ; Return an blank string and set @error to 1.
EndFunc   ;==>RuleCheck

You could also use a multidimensional array and do away with _StringExplode().