String Extraction/Manipulation

[Reddragon]

Product Name: Windows 7 Ultimate
 Version: 6.1  Service Pack 1


 Product Name: Microsoft Office Professional Edition 2003
 Version: 11.0.5614.0

How to extract the above texts so that i get the values of product name and version through a loop

[BrewManNH]

Here's one way to do it, it takes the text and puts it into a 2D array, the first column is the product name, the second column is the version information.

#include <Array.au3>
$sString = "Product Name: Windows 7 Ultimate" & @CRLF & _
        "Version: 6.1  Service Pack 1" & @CRLF & _
        "Product Name: Microsoft Office Professional Edition 2003" & @CRLF & _
        "Version: 11.0.5614.0" & @CRLF
Global $aText[10][2]
$aString = StringRegExp($sString, "Product Name: (.+)", 3)
For $I = 0 To UBound($aString) - 1
    $aText[$I][0] = $aString[$I]
Next
$aString = StringRegExp($sString, "Version: (.+)", 3)
For $I = 0 To UBound($aString) - 1
    $aText[$I][1] = $aString[$I]
Next
ReDim $aText[UBound($aString)][2]
_ArrayDisplay($aText)

Probably not the most elegant way of doing it, and I'm sure one of the RegEx gurus will come up with a better way of doing it, but it can at least give you some ideas.

[Melba23]

Reddragon,

I am not sure what you mean by "through a loop" - but this code will extract the required information:

#include <MsgBoxConstants.au3>
#include <String.au3>

$sString = "Product Name: Windows 7 Ultimate" & @CRLF & _
    "Version: 6.1  Service Pack 1" & @CRLF & _
    "" & @CRLF & _
    "" & @CRLF & _
    "Product Name: Microsoft Office Professional Edition 2003" & @CRLF & _
    "Version: 11.0.5614.0"

$aProductName = _StringBetween($sString, "Product Name:", @CRLF)
$aVersion     = _StringBetween($sString, "Version:", @CRLF)

MsgBox($MB_SYSTEMMODAL, "Return", $aProductName[0] & @CRLF & $aVersion[0])

M23

[mikell]

Without regex

#include <Array.au3>
$sString = "Product Name: Windows 7 Ultimate" & @CRLF & _
        "Version: 6.1  Service Pack 1" & @CRLF & _
        "Product Name: Microsoft Office Professional Edition 2003" & @CRLF & _
        "Version: 11.0.5614.0"

Local $aArray1 = StringSplit($sString, @crlf, 1), $aArray2, $aResult[$aArray1[0]][1]
For $i = 1 To $aArray1[0]
    $aArray2 = StringSplit($aArray1[$i], ": ", 1)
    If $aArray2[0] > UBound($aResult, 2) Then ReDim $aResult[$aArray1[0]][$aArray2[0]]
    For $i2 = 1 To $aArray2[0]
       $aResult[$i-1][$i2-1] = $aArray2[$i2]
    Next
Next
_ArrayDisplay($aResult)

Edited October 19, 2014 by mikell