GUICtrlRead couldn't use string combination as ControlID?

[Tenka]

Why I could not use $RoundStatus="$Round" & $Roundloops & "V"

as $Round1V for GUICtrlRead?

 

$Round1V = GUICtrlCreateCombo("", 464, 65, 67, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))

GUICtrlSetData(-1, "RUN|NA")
GUICtrlSetFont(-1, 10, 800, 0, "Calibri")

.

.

.

.  

For  $Roundloops=1 to 11

$RoundStatus="$Round" & $Roundloops & "V"
$RoundSeq="$Round" & $Roundloops

  

If GUICtrlRead($RoundStatus)="RUN" Then

   

   $Filename=GUICtrlRead($RoundSeq) & ".exe"
   ShellExecute($Filename)

Endif

Next

[Melba23]

Tenka,

Welcome to the AutoIt forums.

You can do what you want by using Eval to get the value associated with the concatenated control name - but it is not the recommended way to do this. Here is a short script showing how to use Eval - but also how you might use an array, which is a better solution:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $aInput[6]

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Incorrect method", 10, 10, 200, 20)
$cInput_1_V = GUICtrlCreateInput("Incorrect 1", 10, 50, 200, 20)
$cInput_2_V = GUICtrlCreateInput("Incorrect 2", 10, 80, 200, 20)
$cInput_3_V = GUICtrlCreateInput("Incorrect 3", 10, 110, 200, 20)
$cInput_4_V = GUICtrlCreateInput("Incorrect 4", 10, 140, 200, 20)
$cInput_5_V = GUICtrlCreateInput("Incorrect 5", 10, 170, 200, 20)

$cEval_Read = GUICtrlCreateButton("Read", 10, 250, 80, 30)

GUICtrlCreateLabel("Correct method", 250, 10, 200, 20)
For $i = 1 To 5
    $aInput[$i] = GUICtrlCreateInput("Correct " & $i, 250, 20 + (30 * $i), 200, 20)
Next

$cArray_Read = GUICtrlCreateButton("Read", 250, 250, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cEval_Read
            $sData = ""
            For $i = 1 To 5
                $cID = Eval("cInput_" & $i & "_V")
                $sData &= GUICtrlRead($cID) & @CRLF
            Next
            MsgBox($MB_SYSTEMMODAL, "Incorrect", $sData)
        Case $cArray_Read
            $sData = ""
            For $i = 1 To 5
                $cID = $aInput[$i]
                $sData &= GUICtrlRead($cID) & @CRLF
            Next
            MsgBox($MB_SYSTEMMODAL, "Array", $sData)
    EndSwitch

WEnd

Please ask if you have any questions.

M23

[Tenka]

Thank you very much. I've solved my question by your comments.