Work if executed as .au3 but not as compiled .exe?

[firestrife23]

I'm having werid issue that I cannot figure out... It work great if I execute the script within SciTE editor... however it doesn't work if I tried to run it from compiled exe file...

This script is meant to run at the root of external HDD to backup important files.

expandcollapse popup

#include <ProgressConstants.au3>

Opt("TrayIconHide", 1)

; This script must be excute at the root of external drive for this to work.
Global $SourceDir = @UserProfileDir, $DestinationDir = @ScriptDir & "Backup\", $OS

Processing()
OSVersion()
If $OS = "Modern" Then
   Backup("AppData")
   Backup("Contacts")
   Backup("Desktop")
   Backup("Documents")
   Backup("Downloads")
   Backup("Favorites")
   Backup("Links")
   Backup("Music")
   Backup("Pictures")
   Backup("Saved Games")
   Backup("Videos")
ElseIf $OS = "Legacy" Then
   Backup("Application Data")
   Backup("Desktop")
   Backup("My Documents")
EndIf
Processed()
Exit

Func Backup($folder)
   If Not FileExists($DestinationDir & @Username) Then
      DirCreate($DestinationDir & @Username)
   EndIf
   _CopyFolder($SourceDir & "\" & $folder, $DestinationDir & @UserName & "\" & $folder, $folder)
EndFunc

Func _CopyFolder($sSourceFolder,$sDestFolder, $foldername)
   DirRemove($sDestFolder,1)
   Local $iSourceSize = DirGetSize($sSourceFolder), $iDestSize
   Local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')
   Do
      $iDestSize = dirgetsize($sDestFolder)
      Local $ipct = int(($iDestSize/$iSourceSize)*100)
      ProgressSet($ipct,$ipct & '% - Backing up ' & $foldername & "...")
      Sleep(20)
   Until Not ProcessExists($pid)
EndFunc

Func Processing()
   ProgressOn("Copying Progress", "Please Wait...")
EndFunc

Func Processed()
   ProgressOff()
EndFunc

Func OSVersion()
   if @OSVersion = "WIN_XP" Then
      $OS = "Legacy"
   ElseIf @OSVersion = "WIN_XPe" Then
      $OS = "Legacy"
   ElseIf @OSVersion  = "WIN_VISTA" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_7" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_8" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_81" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_2003" Then
      $OS = "Legacy"
   ElseIf @OSVersion = "WIN_2008" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_2008R2" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_2012" Then
      $OS = "Modern"
   ElseIf @OSVersion = "WIN_2012R2" Then
      $OS = "Modern"
   EndIf
   Return $OS
 EndFunc

[BrewManNH]

Where does the problem occur in your script? If it works in SciTE, I'd assume it's probably permissions.

[firestrife23]

Well I even added #RequireAdmin but the issue persisted. If I run it from SciTE target folders do get copied to destination folder, but as .exe file nothing get copied. So I think it may have something to do with this line:

Local $pid = Run(@AutoItExe & ' /AutoIt3ExecuteLine "DirCopy(''' & $sSourceFolder & ''', ''' & $sDestFolder & ''')"')

[BrewManNH]

First off, you need to use the pragma directive #pragma compile(AutoItExecuteAllowed, true) if you're going to use that line.

Secondly, why are you using that line at all? You should execute the DirCopy command IN your script, not as a secondary process. Unless you need to have a dozen or so processes running at the same time of course.

[firestrife23]

Thank you for quick respond, I'm using that line to create $pid for Do...Until process no longer exist