String Split

[AutID]

How can I turn this string

Local $sString = "221+3=6-*43/4:7"

into an array like this:

$sString[0]= "221"
$sString[1] = "+"
$sString[2] = "3"
$sString[3] = "="
$sString[4] = "6"
$sString[5] = "-"
$sString[6] = "*"
$sString[7] = "43"
...

So basically I am splitting the string into numbers and math signs.

Any ideas gurus?

 

[guinness]

StringSplit(DATA, '+-*/', $STR_NOCOUNT)

[Melba23]

AutID,

This seems to work:

#include <Array.au3>

Local $sString = "221+3=6-*43/4:7"

$aRet = StringRegExp($sString, "(\d+|\D)", 3)

_ArrayDisplay($aRet, "", Default, 8)

M23

[AutID]

StringSplit(DATA, '+-*/', $STR_NOCOUNT)

That won't work properly

AutID,

This seems to work:

#include <Array.au3>

Local $sString = "221+3=6-*43/4:7"

$aRet = StringRegExp($sString, "(\d+|\D)", 3)

_ArrayDisplay($aRet, "", Default, 8)

M23

 

I came up with a pattern like this "(?i)([d+-/*:=])" but yours defeats mine. It is exactly how it should be working

Cheers

[guinness]

Ah, you wanted to retain the operators. I missed that point.

[tommytx]

You can use this when you only understand basic code and dont' know all this fancy stuff these pros use..

And with minor adjustements it can work no matter how complex yo decide to make the string... just add or subtract symbols as needed...

#include <Array.au3>

Local $str = "221+3=6-*43/4:7"

Local $sString[8] = ["", "+", "", "=", "", "-", "*", ""]

$dog = StringSplit($str, '+=-*/', $STR_NOCOUNT)
$sString[0]=  $dog[0]
$sString[2] = $dog[1]
$sString[4] = $dog[2]
$sString[7] = $dog[4]

for $i = 0 to 7
   ConsoleWrite($sString[$i] & @CRLF)
Next

Edited November 1, 2014 by tommytx

[Melba23]

tommytx,

If you want to avoid using "fancy stuff" such as a RegEx, you could do something like this which only uses "basic code":

expandcollapse popup

#include <Array.au3>

Local $sString = "221+3=6-*43/4:7"

; Length of string
Local $iLen = StringLen($sString)
; Array to hold result - can cope with as many characters as are in the string
Local $aRet[$iLen]
; Index of array to fill
Local $iIndex = 0
; Type of first character
Local $bDigit = False
Local $sChar = StringLeft($sString, 1)
Switch $sChar
    Case "0" To "9"
        $bDigit = True
EndSwitch

; Enter first character
$aRet[0] = $sChar
; Now loop through the rest
For $i = 2 To $iLen
    ; Next character in string
    $sChar = StringMid($sString, $i, 1)
    ; If we were dealing with digits before
    If $bDigit Then
        ; What is this character
        Switch $sChar
            Case "0" To "9"
                ; Do nothing
            Case Else
                ; Not a digit
                $bDigit = False
                ; Move to next array element
                $iIndex += 1
        EndSwitch
    ; If we were not dealing with digits before
    Else
        ; What is this character
        Switch $sChar
            ; ; It is a digit
            Case "0" To "9"
                $bDigit = True
        EndSwitch
        ; In any case move to next element
        $iIndex += 1
    EndIf
    ; Add the char to the correct element
    $aRet[$iIndex] &= $sChar
Next

; Remove any empty elements
ReDim $aRet[$iIndex + 1]

; And show the result
_ArrayDisplay($aRet, "Final", Default, 8)

But overall I think I prefer my earlier version.

M23