Control windows by using ProcessList turning the PID into a Handle?

[Hyflex]

Hey Everyone,

I can't quite get this working, basically I have 20 "Program.exe" processes, I want to cycle through each process and do things to it for example I've done WinActivate and WinSetState... 

I thought that I would have to get the handle in order to do this but for some reason the handle fails on most of the processes...
 

Func Wins()
    $aProcessList = ProcessList("Program.exe")
    $vProcessorCount = 0
    For $x = 1 To $aProcessList[0][0]
        $hWnd = WinGetHandle($aProcessList[$x][1])
        WinActivate($hWnd) ; Just an example
        WinSetState($hWnd, "", @SW_MINIMIZE) ; Just an example
    Next
EndFunc

If I print all of the handles I get the following:

0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000E80 ; Why do only this one and the one below have handles...
0x00000DE8
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000
0x00000000

Any ideas what im doing wrong?

 

[UEZ]

Maybe _WinAPI_EnumProcessWindows() will help you to get the windows handle from the pid.

 

Br,

UEZ

[Hyflex]

Ran into an error with handling arrays :/
 

If $hWnd[0][0] >= 2 Then
    While $hWnd[1][2] = "SplashWnd"
        Sleep(1000)
    WEnd
EndIf

Error = Array variable has incorrect number of subscripts or subscript dimension range exceeded.

I've tried using if @error but can't seem to get round it...

[MikahS]

 

Ran into an error with handling arrays :/

 

If $hWnd[0][0] >= 2 Then
    While $hWnd[1][2] = "SplashWnd"
        Sleep(1000)
    WEnd
EndIf

Error = Array variable has incorrect number of subscripts or subscript dimension range exceeded.

I've tried using if @error but can't seem to get round it...

 

Success:    The 2D array of the handles to the window and class for the specified process.
[0][0] - Number of rows in array (n)
[0][1] - Unused
[n][0] - Window handle
[n][1] - Window class name

$hWnd[1][2] is not a valid array value.

you would do $hWnd[1][0] for the handle and $hWnd[1][1] for the class.

Edited November 3, 2014 by MikahS

[funkey]

Maybe this is helpful:

#include <Array.au3>

Global $aProcessList = ProcessList("program.exe")
_ArrayDisplay($aProcessList, "Processes", -1, 0, "", "|", "index|process names|process ids")

Global $aWinTitlesAndHandles

For $i = 1 To $aProcessList[0][0]
    $aWinTitlesAndHandles = _PID2WinTitleAndHandle($aProcessList[$i][1])
    _ArrayDisplay($aWinTitlesAndHandles, "Titles and handles", -1, 0, "", "|", "index|window titles|window handles")
Next


Func _PID2WinTitleAndHandle($PID)
    ;funkey 1st Nov 2008
    Local $aWinTitle[1][2] = [[0]], $aList = WinList()
    For $i = 1 To $aList[0][0]
        If $PID = WinGetProcess($aList[$i][0]) Then
            ReDim $aWinTitle[$aWinTitle[0][0] + 2][2]
            $aWinTitle[0][0] += 1
            $aWinTitle[$aWinTitle[0][0]][0] = $aList[$i][0] ;$List[$i][0] for titles, $List[$i][1] for handles ;)
            $aWinTitle[$aWinTitle[0][0]][1] = $aList[$i][1] ;$List[$i][0] for titles, $List[$i][1] for handles ;)
        EndIf
    Next
    Return $aWinTitle
EndFunc   ;==>_PID2WinTitleAndHandle

[guinness]

Maybe _WinAPI_EnumProcessWindows() will help you to get the windows handle from the pid.

 

Br,

UEZ

Would have been my recommendation too.

[Hyflex]

Success:    The 2D array of the handles to the window and class for the specified process.
[0][0] - Number of rows in array (n)
[0][1] - Unused
[n][0] - Window handle
[n][1] - Window class name

$hWnd[1][2] is not a valid array value.

you would do $hWnd[1][0] for the handle and $hWnd[1][1] for the class.

Not true, the array can become 4 long because in some of my windows $hWnd[1][2] gives me SplashWnd

[MikahS]

Not true, the array can become 4 long because in some of my windows $hWnd[1][2] gives me SplashWnd

 

True but if there is nothing in [1][2] it will error out and say Array variable has incorrect number of subscripts or subscript dimension range exceeded.

Edited November 4, 2014 by MikahS