Merging pdfs

[kaotkbliss]

I've been playing with the following code trying to merge pdfs (we'll be getting hundreds-thousands of pdfs that I'll have to merge into 1 before doing other stuff to it in another program.)

The pdfs merge great the problem is, if a pdf is an odd number of pages I want to add an additional blank pdf to make it an even number but that doesn't seem to want to be merging in

expandcollapse popup

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=H:\Client\BRVO\Daily\Print\TESTING FOLDER\PDF Merger.exe
#AutoIt3Wrapper_UseUpx=n
#AutoIt3Wrapper_Add_Constants=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <Math.au3>
Dim $filelist[1]

If Not FileExists(@ScriptDir & "\PDFmerge.ini") Then
    IniWrite(@ScriptDir & "\PDFmerge.ini","LastFolder",1,"")
EndIf



$sourcepath = IniRead(@ScriptDir & "\PDFmerge.ini","LastFolder",1,"")

; example  merging files
$var= FileSelectFolder("Select folder", "","",$sourcepath) & "\"
if @error Then
    Exit
EndIf
IniWrite(@ScriptDir & "\PDFmerge.ini","LastFolder",1,$var)
$var2 = FileSaveDialog( "Select Filename", $var, "PDF Files (*.pdf)", 2)
If @error Then
    Exit
EndIf
MergeFiles($var,$var2)
; example end



func GetRotation($Targetpath)
;----------------------------------------------------
; Get the Rotation of a Page (eg. page 1)
; Ex.: msgbox(0,"Rotation",GetRotation("c:\pdft\test.pdf" ))
;----------------------------------------------------

    if not FileExists($Targetpath) then
        return -1
    endif

    $SourcePDF = ObjCreate("AcroExch.PDDoc")

    if not IsObj($SourcePDF) then
        return -2
    endif

    $b = $SourcePDF.Open($Targetpath)
    $rotation = $sourcePDF.AcquirePage(0).GetRotate
    $SourcePDF.close
    $sourcePDF=""
    return $rotation                                ; in Degree
EndFunc



func MergeFiles($SourcePath , $DestinationPath)

    if StringRight($DestinationPath,4) <> ".pdf" Then
        $DestinationPath = $DestinationPath&".pdf"
    EndIf

    if fileexists($DestinationPath) then
        FileDelete($DestinationPath)
    endif


    getfiles($sourcepath, "*.pdf")                                      ; Search Files in Dir
    if $filelist[0] < 2 then
        Msgbox(32,"Info", "Ther are less than two files in folder")
        exit
    endif

    ProgressOn("PDF Merge","Processing ...")

    $SourcePDF = ObjCreate("AcroExch.PDDoc")
    if IsObj($SourcePDF) then
        $b = $SourcePDF.Open($sourcepath & $filelist[1])

    $TargetPDF = ObjCreate("AcroExch.PDDoc")
    $b = $TargetPDF.Open($sourcepath & $filelist[1])

    $intSourcePgs = $SourcePDF.GetNumPages
    $intInsertPgs = $TargetPDF.GetNumPages

    $SourcePDF.InsertPages($intSourcePgs-1, $TargetPDF, 0, $intInsertPgs, False)
    if _MathCheckDiv($intInsertPgs/2) <> 2 Then
        $TargetPDF2 = ObjCreate("AcroExch.PDDoc")
        $b2 = $TargetPDF2.Open("H:\Client\BRVO\Daily\Print\Blank.pdf")

        $intInsertPgs2 = $TargetPDF2.GetNumPages
        if not $SourcePDF.InsertPages($intSourcePgs + $intInsertPgs -1, $TargetPDF2, 0, $intInsertPgs2, False) = -1  then
            $TargetPDF2.Close
            $TargetPDF2=""
            $intInsertPgs += 1
        EndIf
    EndIf
    $b = $SourcePDF.Save(1, $DestinationPath)
    $SourcePDF.Close
    $SourcePDF=""

    $SourcePDF = ObjCreate("AcroExch.PDDoc")
    if not IsObj($SourcePDF) then
        return -2
    endif

    $b = $SourcePDF.Open($DestinationPath)
    $intSourcePgs = $SourcePDF.GetNumPages

    for $n=2 to UBound($filelist)-1

        ProgressSet((($n-1)/$filelist[0]) * 100, $filelist[$n-1])

        $TargetPDF = ObjCreate("AcroExch.PDDoc")
        $b = $TargetPDF.Open($sourcepath & $filelist[$n])


        $intInsertPgs = $TargetPDF.GetNumPages

        if not $SourcePDF.InsertPages($intSourcePgs-1, $TargetPDF, 0, $intInsertPgs, False) = -1  then
            if _MathCheckDiv($intInsertPgs/2) <> 2 Then
                $TargetPDF2 = ObjCreate("AcroExch.PDDoc")
                $b2 = $TargetPDF2.Open("H:\Client\BRVO\Daily\Print\Blank.pdf")


                $intInsertPgs2 = $TargetPDF2.GetNumPages
                if not $SourcePDF.InsertPages($intSourcePgs + $intInsertPgs -1, $TargetPDF2, 0, $intInsertPgs2, False) = -1  then
                    $TargetPDF2.Close
                    $TargetPDF2=""
                    $intInsertPgs += 1
                EndIf
            EndIf
            $TargetPDF.Close
            $TargetPDF=""
        endif

        $intSourcePgs += $intInsertPgs


    next
    $b = $SourcePDF.Save(1, $DestinationPath)
    ProgressSet(100, $filelist[$filelist[0]])
    sleep(800)
    ProgressOff()
    endif

Endfunc




func getfiles($dir, $filter) ; search files in dir
Global $filelist[1]

    $n=0
    $search= FileFindFirstFile($dir & $filter)
; Check if the search was successful
    If $search = -1 Then
        MsgBox(0, "Error", "No files/directories matched the search pattern")
        Exit
    EndIf

    While 1
        $n=$n+1
        $file = FileFindNextFile($search)
        If @error Then ExitLoop
        redim $filelist[$n+1]
        $filelist[$n]= $file
        $filelist [0] = $n
    WEnd
; Close the search handle
    FileClose($search)
EndFunc

#cs
func PDFMerge($File1, $File2, $Fileout)
; ---------------------------------------
; File1 first  file
; File2 second file (inserted after)
; Fileout is the saving name
;
; returns  1 on success
; returns -1 Error insert Pages
; returns -2 Error Object Create
;----------------------------------------

    $SourcePDF = ObjCreate("AcroExch.PDDoc")
    if not IsObj($SourcePDF) then
        return -2
    endif

    $b = $SourcePDF.Open($sourcepath & $filelist[$n-1])

    $TargetPDF = ObjCreate("AcroExch.PDDoc")
    $b = $TargetPDF.Open($sourcepath & $filelist[$n])

    $intSourcePgs = $SourcePDF.GetNumPages
    $intInsertPgs = $TargetPDF.GetNumPages
    if not $SourcePDF.InsertPages($intSourcePgs-1, $TargetPDF, 0, $intInsertPgs, False) = -1  then
        $SourcePDF.Close
        $TargetPDF.Close
        $SourcePDF=""
        $TargetPDF=""
        return -1
    endif
    $b = $SourcePDF.Save(1, $DestinationPath)
    $SourcePDF.Close
    $TargetPDF.Close
    $SourcePDF=""
    $TargetPDF=""
    return 1
endfunc
#ce


func GetPagesCount($target); count pages
    $AcroPDDoc = ObjCreate("AcroExch.PDDoc")
    if @error then return -1
    $bPDF = $AcroPDDoc.Open($target)
    if @error then return -2
    $Pages= $AcroPDDoc.GetNumPages
    $bPDF = $AcroPDDoc.Close
    return $pages
endfunc




; Feel free to improve the code...

; Greetings Mozat90

[llewxam]

Have you checked $b2 to make sure that it is able to open $TargetPDF2?   Is that a full-page blank sheet or an empty file?

Ian

[kaotkbliss]

It's returning "True" as expected (able to open file) and it's a full blank page.

[kaotkbliss]

What additional information is needed to help solve this? It shouldn't be hard to adapt for testing as it's set up for you to choose your own folder of PDFs. The only thing that would need changed is the location of the blank PDF.

[SmOke_N]

What does:

$intInsertPgs2 = $TargetPDF2.GetNumPages

return?

[kylomas]

and what if you add 1 to it?

[kaotkbliss]

I hadn't thought of checking that. I would assume it returns a 1 as that's how many pages are in the PDF, but I will check it to make sure and be back with the result.

*edit*

Just as suspected, it returns a 1. I tried kylomis' suggestion and added 1 to that, but that didn't merge all the PDFs (our test folder has 300 PDFs of 7 pages so I should get 2400 pages. I only ended up with 930 some) and there was still no blank page added to the ones that did merge

Edited November 9, 2014 by kaotkbliss

[SmOke_N]

You could always contact the original author of the code you're using, only looks like you've changed a couple of things that mozart90 wrote, maybe they could help.

I wrote a pdf library some time ago, I may still have it on a backup flash drive somewhere, I'll have a look tomorrow.

In the meantime, this guy seems to have written a pretty extensive library that may come in better use for you:

'?do=embed' frameborder='0' data-embedContent>>

He documented the code pretty well, and has examples provided in the zip as well.

[mLipok]

Thanks @SmOke_N

@kaotkbliss

Merge is in Lite version of DebenuLibrary, so you can use it for free.
_QPDF_Example_MergeFiles_Lite()

In QuickPDF_Examples.au3
There is _QPDF_Example_MergeFiles() but this is for commercial version DebenuLibrary.

 

But no worry look in my UDF thread for new post.

If you encounter any problems then ask in topic mentioned by @SmOke_N

[kaotkbliss]

I managed to get this to work

it opens the first pdf and counts the pages, if it's an odd number, inserts the blank page.

Then starts merging the rest of the pdfs and if the total number of merged pages each loop is odd, it adds another blank page.

One of the problems were the insertpages lines, that function returns a true or false and it was checking for -1 (just removed it completely)

I also renamed the pdf variables so it made more sense to me (source = pdf you're reading from, target = pdf you want to add to) which also helped me rewrite the code.

Using the function as copied from the forums here, it took about a half hour to merge around 700 pdfs.

Using the rewrite, it takes just around a minute for that same 700 (plus adding in blank pages)

Just replace the variable $blank at the top of the script to the path of whatever you want to insert if the number of pages are odd and that's it

expandcollapse popup

#include <Math.au3>
Dim $filelist[1]
$blank = "H:\Client\BRVO\Daily\Print\Blank.pdf"

If Not FileExists(@ScriptDir & "\PDFmerge.ini") Then
    IniWrite(@ScriptDir & "\PDFmerge.ini","LastFolder",1,"")
EndIf



$sourcepath = IniRead(@ScriptDir & "\PDFmerge.ini","LastFolder",1,"")

; example  merging files
$var= FileSelectFolder("Select folder", "","",$sourcepath) & "\"
if @error Then
    Exit
EndIf
IniWrite(@ScriptDir & "\PDFmerge.ini","LastFolder",1,$var)
$var2 = FileSaveDialog( "Select Filename", $var, "PDF Files (*.pdf)", 2)
If @error Then
    Exit
EndIf
MergeFiles($var,$var2)
; example end

func MergeFiles($SourcePath , $DestinationPath)

    if StringRight($DestinationPath,4) <> ".pdf" Then
        $DestinationPath = $DestinationPath&".pdf"
    EndIf

    if fileexists($DestinationPath) then
        FileDelete($DestinationPath)
    endif


    getfiles($sourcepath, "*.pdf")                                      ; Search Files in Dir
    if $filelist[0] < 2 then
        Msgbox(32,"Info", "Ther are less than two files in folder")
        exit
    endif

    ProgressOn("PDF Merge","Processing ...")

    $SourcePDF = ObjCreate("AcroExch.PDDoc")
    if IsObj($SourcePDF) then
        $b = $SourcePDF.Open($sourcepath & $filelist[1])
        $intSourcePgs = $SourcePDF.GetNumPages
        $mathcheck = _MathCheckDiv($intSourcePgs/2)
        if $mathcheck <> 2 Then
            $SourcePDF.Close
            $SourcePDF=""
            $TargetPDF = ObjCreate("AcroExch.PDDoc")
            $b = $TargetPDF.Open($sourcepath & $filelist[1])
            $intTargetPgs = $TargetPDF.GetNumPages
            $SourcePDF = ObjCreate("AcroExch.PDDoc")
            $b2 = $SourcePDF.Open($blank)
            $intSourcePgs = $SourcePDF.GetNumPages
            $c = $TargetPDF.InsertPages($intTargetPgs-1, $SourcePDF, 0, $intSourcePgs, False)
            $b = $TargetPDF.Save(1, $DestinationPath)
            $TargetPDF.Close
            $TargetPDF=""
            $SourcePDF.Close
            $SourcePDF=""
        Else
            $SourcePDF.Close
            $SourcePDF=""
            $TargetPDF = ObjCreate("AcroExch.PDDoc")
            $b = $TargetPDF.Open($sourcepath & $filelist[1])
            $intTargetPgs = $TargetPDF.GetNumPages
            $SourcePDF = ObjCreate("AcroExch.PDDoc")
            $b2 = $SourcePDF.Open($sourcepath & $filelist[1])
            $intSourcePgs = $SourcePDF.GetNumPages
            $c = $TargetPDF.InsertPages($intTargetPgs-1, $SourcePDF, 0, $intSourcePgs, False)
            $b = $TargetPDF.Save(1, $DestinationPath)
            $TargetPDF.Close
            $TargetPDF=""
            $SourcePDF.Close
            $SourcePDF=""
        EndIf

        $TargetPDF = ObjCreate("AcroExch.PDDoc")
        $b = $TargetPDF.Open($DestinationPath)
        $intTargetPgs = $TargetPDF.GetNumPages

        for $n=2 to UBound($filelist)-1

            ProgressSet((($n-1)/$filelist[0]) * 100, $filelist[$n-1])

            $SourcePDF = ObjCreate("AcroExch.PDDoc")
            $b = $SourcePDF.Open($sourcepath & $filelist[$n])
            $intSourcePgs = $SourcePDF.GetNumPages

            $c = $TargetPDF.InsertPages($intTargetPgs-1, $SourcePDF, 0, $intSourcePgs, False)
            $intTargetPgs += $intSourcePgs
            $SourcePDF.Close
            $SourcePDF=""
            if _MathCheckDiv($intTargetPgs/2) <> 2 Then
                $SourcePDF = ObjCreate("AcroExch.PDDoc")
                $b2 = $SourcePDF.Open($blank)
                $intSourcePgs = $SourcePDF.GetNumPages
                $c = $TargetPDF.InsertPages($intTargetPgs-1, $SourcePDF, 0, $intSourcePgs, False)
                $intTargetPgs += $intSourcePgs
                $SourcePDF.Close
                $SourcePDF=""
            EndIf
        next
        $b = $TargetPDF.Save(1, $DestinationPath)
        ProgressSet(100, $filelist[$filelist[0]])
        sleep(800)
        ProgressOff()
    endif
Endfunc

func getfiles($dir, $filter) ; search files in dir
Global $filelist[1]

    $n=0
    $search= FileFindFirstFile($dir & $filter)
; Check if the search was successful
    If $search = -1 Then
        MsgBox(0, "Error", "No files/directories matched the search pattern")
        Exit
    EndIf

    While 1
        $n=$n+1
        $file = FileFindNextFile($search)
        If @error Then ExitLoop
        redim $filelist[$n+1]
        $filelist[$n]= $file
        $filelist [0] = $n
    WEnd
; Close the search handle
    FileClose($search)
EndFunc

func GetPagesCount($target); count pages
    $AcroPDDoc = ObjCreate("AcroExch.PDDoc")
    if @error then return -1
    $bPDF = $AcroPDDoc.Open($target)
    if @error then return -2
    $Pages= $AcroPDDoc.GetNumPages
    $bPDF = $AcroPDDoc.Close
    return $pages
endfunc




; Feel free to improve the code...

; Greetings Mozat90