Reading multiple sections from ini-file to array

[bendover]

I have dialogue that reads city selection from ini-file. There are three sections in ini-file. Example:

[CITY]

City1=Chicago

City2=Stockholm

City3=New York

[PREFIX]

Prefix1=CHI

Prefix2=STC

Prefix3=NYC

[OU]

Ou1="LDAP://dc1.corp.domain.com/OU=Chicago,OU=Computers,DC=corp,DC=domain,DC=com

Ou2="LDAP://dc1.corp.domain.com/OU=Stockholm,OU=Computers,DC=corp,DC=domain,DC=com

Ou3="LDAP://dc1.corp.domain.com/OU=New York,OU=Computers,DC=corp,DC=domain,DC=com

All sections have connection to each others (City1=Prefix1=Ou1 etc). I read city section to array but the question is: how to read all sections to multidimensional array and keep the connection described earlier? I'm not very familiar with multidimensional arrays.

Thanks in advance.

[water]

Welcome to AutoIt and the forum!

If the entries in every section always have the same order (means: The 2nd entry in [CITY] is City2 and the 2nd entry in [PREFIX] is Prefix2 etc.) then you could usse INIRead to read the sections into 3 arrays and access the content by index.

[mikell]

Because you're not very familiar with multidimensional arrays... 

#include <Array.au3>

$ini = @ScriptDir & "\ini.ini"

$city = IniReadSection($ini, "CITY")
$prefix = IniReadSection($ini, "prefix")
$ou = IniReadSection($ini, "ou")

$nb = $city[0][0]
Local $res[$nb+1][3]
$res[0][0] = $nb
For $i = 1 to $nb
   $res[$i][0] = $city[$i][1]
   $res[$i][1] = $prefix[$i][1]
   $res[$i][2] = $ou[$i][1]
Next
_ArrayDisplay($res)

[TheSaint]

Or a simpler approach, using some of the same calls, if you only want one city at a time. No array.
 

Global $cities, $city, $details, $inifle, $num, $ou, $prefix, $total

$inifle = @ScriptDir & "\Citydetail.ini"

$cities = IniReadSection($inifle, "CITY")

$total = $cities[0][0]

For $num = 1 To $total
    $city = IniRead($inifle, "CITY", "City" & $num, "")
    $prefix = IniRead($inifle, "PREFIX", "Prefix" & $num, "")
    $ou = IniRead($inifle, "OU", "Ou" & $num, "")
    $details = "City = " & $city & @LF & "Prefix = " & $prefix & @LF & "Ou = " & $ou
    MsgBox(0, "City Details", $details)
Next

Edited November 9, 2014 by TheSaint

[bendover]

Thanks....works perfectly. Now I can search the values I want to use from array.