_Word_DocFindReplace with character

[Floppy]

Hello,

I'm trying to replace "%s1%" with a checkbox in a Word document. I thought I could use the font Wingdings2 to do this. (you can see here the character I would like to use: http://it.tinypic.com/r/10wqvx0/8)

The problem is if I copy and paste the character from the Character Map, SciTe displays a little square instead of the character. What should I put instead?

_Word_DocFindReplace($oDoc, "%s1%", "WHAT SHOULD I PUT HERE???")

Edited December 3, 2014 by Floppy

[water]

After replacing %s1% you need to set the font for the replacing character to WingDings2.

[Floppy]

water, your solution is smart. But how can I change the font of all chackeboxes at once?

[MikahS]

Use a for loop to loop through each one and change the font?

[water]

Exactly.

Use _Word_DocFind in  a loop to find all occurrences of "%s1%" and change the font. Then replace all "%s1%" with the checkbox character.

[Floppy]

I tried with the following script from _Word_DocFind help file, but it underlines only the first occurance. Why?

Global $oRangeFound
$oRangeFound = _Word_DocFind($oDoc, "%s1%", 0)
MsgBox(0,@error,$oRangeFound)
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFind Example", "Error locating the specified text in the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
$oRangeFound.Underline = True
While 1
    $oRangeFound = _Word_DocFind($oDoc, "%s1%", -1, $oRangeFound)
MsgBox(0,@error,$oRangeFound)
    If @error <> 0 Then ExitLoop
    $oRangeFound.Underline = True
WEnd

[water]

Because you spcified -1 (Selection) as the range to be searched. Selection is the part of the document you have marked.

Try 0 instead.

[Floppy]

I tried but it's the same: only the first occurrence gets underlined.

[water]

Which version of Office do you run?

[Floppy]

Office 2013 x64 (os Windows 8.1 x64)

[water]

This works fine for me and underlines all occurrences of "%s1%" in the document:

#include <Word.au3>
#include <MsgBoxConstants.au3>
Global $oRangeFound
Global $oWord = _Word_Create()
Global $oDoc = _Word_DocOpen($oWord, "C:\temp\test.docx")
$oRangeFound = _Word_DocFind($oDoc, "%s1%", 0)
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFind Example", "Error locating the specified text in the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
$oRangeFound.Underline = True
While 1
    $oRangeFound = _Word_DocFind($oDoc, "%s1%", 0, $oRangeFound)
    If @error <> 0 Then ExitLoop
    $oRangeFound.Underline = True
WEnd

Edited December 6, 2014 by water

[water]

A played a little bit with Word and recorded a macro to insert the Wingdings2 symbols.

This script works fine on Windows 7, Office 2010:

#include <Word.au3>
#include <MsgBoxConstants.au3>
Global $oRangeFound
Global $oWord = _Word_Create()
Global $oDoc = _Word_DocOpen($oWord, "C:\temp\test.docx")
$oRangeFound = _Word_DocFind($oDoc, "%s1%", 0)
If @error <> 0 Then Exit MsgBox($MB_SYSTEMMODAL, "Word UDF: _Word_DocFind Example", "Error locating the specified text in the document." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
$oRangeFound.InsertSymbol(-4012, "Wingdings 2", True)
While 1
    ConsoleWrite("**" & @CRLF)
    $oRangeFound = _Word_DocFind($oDoc, "%s1%", 0, $oRangeFound)
    If @error <> 0 Then ExitLoop
    $oRangeFound.InsertSymbol(-4012, "Wingdings 2", True)
WEnd