Count function calls....

[vladedoty]

Is there an already made script or an easy function to create to be able to give me the counts of all my calls to functions

like something like...

Local $windowCallCount ; number of total calls for the WindowName function
Local $windowHandleCount ; number of total calls for the WindowHandle function

Func TotalWinCount()
       ; Add code here to add all calls and list them individually for each function called
EndFunc

ConsoleWrite("Function WindowName() calls = " & $windowCallCount & @LF)
ConsoleWrite("Function WindowHandle() calls = " & $windowHandleCount & @LF)

any help would be much appreciated

thx...

Edited December 16, 2014 by vladedoty

[Geir1983]

Like this?

Global $windowCallCount ; number of total calls for the WindowName function

Func WindowName()
        $windowCallCount += 1
        ConsoleWrite("Function WindowName() calls = " & $windowCallCount & @LF)
       ; Add the real function here
EndFunc

[mLipok]

or this:

_myFunc1()
_myFunc2()
_myFunc3()
ConsoleWrite("_FuncCounter = " & _FuncCounter() & @LF)

Func _FuncCounter()
    Static Local $iFuncCounter = 0
    $iFuncCounter += 1
    Return $iFuncCounter
EndFunc   ;==>_FuncCounter

Func _myFunc1()
    _FuncCounter()
EndFunc   ;==>_myFunc1

Func _myFunc2()
    _FuncCounter()
EndFunc   ;==>_myFunc2

Func _myFunc3()
    _FuncCounter()
EndFunc   ;==>_myFunc3

EDIT:

@vladedoty

please read this: How to post code on the forum

Edited December 16, 2014 by mLipok

[jguinch]

for the fun :

For $i = 1 To Random(1, 10, 1)
    _FirstFunc()
Next

For $i = 1 To Random(1, 10, 1)
    _SecondFunc()
Next

ConsoleWrite("#######################" & @CRLF)
ConsoleWrite("_FirstFunc was called " & _FuncCount("_FirstFunc", 0) & " times" & @CRLF)
ConsoleWrite("_SecondFunc was called " & _FuncCount("_SecondFunc", 0) & " times" & @CRLF)

Func _FirstFunc()
    _FuncCount("_FirstFunc")
    ConsoleWrite("_FirstFunc call" & @CRLF)
EndFunc


Func _SecondFunc()
    _FuncCount("_SecondFunc")
    ConsoleWrite("_SecondFunc call" & @CRLF)
EndFunc

; $iFlag = 0 : returns the total calls for the specified function name
;          1 : adds 1 to the total of calls for the specified function name
Func _FuncCount($sFuncName, $iFlag = 1)
    Local Static $sFuncCounter = ""
    If $iFlag = 0 Then Return UBound ( StringRegExp($sFuncCounter, "(?im)^\Q" & $sFuncName & "\E$", 3) )
    
    $sFuncCounter &= @CRLF & $sFuncName
EndFunc