Changing Var from Input after Button Press

[AutoScrub]

I'm loosing my mind, hopefully someone can help me out. Basically I have a tab open with an input box where you can type a name in and then it goes ahead and checks that name against a library for info. I have the input box set with a name when it launches, so it queries that info and that single instance works. What does not work is me being able to query any other instance.

 

$Tab_Tracker = GUICtrlCreateTabItem("Tracker")

        Global $I_SN = GUICtrlCreateInput("TestName", 16, 48, 169, 21)
        $Label11 = GUICtrlCreateLabel("Name: ", 16, 80, 186, 25)
        $Label12 = GUICtrlCreateLabel("Level: ", 16, 112, 186, 25)
        $Label13 = GUICtrlCreateLabel("Id: ", 16, 144, 186, 25)
        $Label14 = GUICtrlCreateLabel("Elo: ", 16, 176, 186, 25)
        $Label15 = GUICtrlCreateLabel("Label15", 16, 208, 186, 25)
        $B_S_LU = GUICtrlCreateButton("Query", 200, 48, 75, 25)
        $UserName = GUICtrlRead($I_SN)

Func Query()

        $I_SN = GUICtrlCreateInput
        $UserName = GUICtrlRead($I_SN)

EndFunc

I can't figure out how I can get the input variable to change in the code once I press the button and have all my labels (WHICH ARE BASED OF OFF THE VAR) to change. Please help Obi-Wan Kenobi.

[SmOke_N]

You keep recreating the Input (in the Query() func), using GUICtrlRead right after before anything can be typed in it.

Remove the Query() $I_SN = GUICtrlCreateInput

[AutoScrub]

So I would have GUICtrlRead($I_SN, 0), which would read it but you said to add it in the querry and then you said to remove querry, which is it, cause neither seems to work.

[AutoScrub]

right after before 

I feel like your trolling me so hard.

[Melba23]

AutoScrub,

Moderators here are not in the habit of trolling newcomers.

We prefer welcoming them to the forum - so consider yourself welcome.

SmOke_N's comment was absolutely correct - in the Query() function you are reassigning the $I_SN by (incorrectly and with bad syntax) reusing GUICtrlCreateInput so that the original ControlID set when creating the "TestName" input is lost. That means that your GUICtrlRead does not use the correct value for the original input and so fails to read its content. Take a look at this example script:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

Global $I_SN = GUICtrlCreateInput("TestName", 16, 48, 169, 21)

$Label11 = GUICtrlCreateLabel("Name: ", 16, 80, 186, 25)
$Label12 = GUICtrlCreateLabel("Level: ", 16, 112, 186, 25)
$Label13 = GUICtrlCreateLabel("Id: ", 16, 144, 186, 25)
$Label14 = GUICtrlCreateLabel("Elo: ", 16, 176, 186, 25)
$Label15 = GUICtrlCreateLabel("Label15", 16, 208, 186, 25)

$B_S_LU = GUICtrlCreateButton("Query", 200, 48, 75, 25)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $B_S_LU
            _Query()
    EndSwitch
WEnd

Func _Query()
    ; Read username
    $UserName = GUICtrlRead($I_SN)
    If $UserName Then
        ; Change label
        GUICtrlSetData($Label11, "Name: " & $UserName)
    EndIf
EndFunc   ;==>_Query

Please ask if yo have any questions.

M23

[AutoScrub]

Thank's alot! That helped understand it much better and I was able to resolve the issue using the While and Func example you gave.

[Melba23]

AutoScrub,

Glad I could help.

M23

[SmOke_N]

Guess I forgot a comma separating the two.  I'm not in the habit of recreating code that doesn't run out of the box to demonstrate the issue.  Certainly not looking to "troll" anyone, regardless of their status on the forum.  Glad things worked out for you, as it seems, the original code you posted (able to be ran on our side or not) did not really demonstrate the extent of the issue based on your reply to Melba23.