parsing out data

[gcue]

i am trying to get the list that corresponds to a list name from a string.  i am having trouble getting just the names that correspond to the list in question.

ie: when querying for Test 2 list I only want jack,jill,tim

expandcollapse popup

#include <Array.au3>
$msg_normal = 262144


local $lists_array[3]


$lists_array[0] = "Test"
$lists_array[1] = "Test 2"
$lists_array[2] = "Test_3"


$string = "Test: mike,peter,bob|Test 2: jack,jill,tim|Test_3: fabio,mark,jed"


for $x = 0 to ubound($lists_array)-1
$current_list = $lists_array[$x]


$names = stringregexpreplace($string, "(?s)(?i)" & $current_list & ":(|*?)", "$1")


debug($current_list, $names)
next




Func Debug($variable1 = "", $variable2 = "", $variable3 = "")


;~  #include <array.au3>
;~  $msg_normal = 0


If IsArray($variable1) Then
_ArrayDisplay($variable1)
Else
If $variable2 <> "" Then
$variable1 &= @CRLF & $variable2
EndIf


If $variable3 <> "" Then
$variable1 &= @CRLF & $variable3
EndIf


ClipPut($variable1)
MsgBox($msg_normal, "Debug", $variable1)
EndIf


EndFunc   ;==>Debug

Thanks in advance!

 

 

[jguinch]

local $lists_array[3] = ["Test", "Test 2", "Test_3"]

$string = "Test: mike,peter,bob|Test 2: jack,jill,tim|Test_3: fabio,mark,jed"

For $x = 0 to ubound($lists_array)-1
    $current_list = $lists_array[$x]
    $names = StringRegExpReplace($string, "(?is).*\Q" & $current_list & "\E:\h*([^|]+).*", "$1" )
    ConsoleWrite($names & @CRLF)
Next

[gcue]

works perfectly!

thank you very much

[mikell]

Another one 

#include <Array.au3>

Local $lists_array[3] = ["Test", "Test 2", "Test_3"]
$string = "Test: mike,peter,bob|Test 2: jack,jill,tim|Test_3: fabio,mark,jed"

For $x = 0 to ubound($lists_array)-1
  $names = StringRegExp(StringSplit($string, "|", 2)[$x], '\w+(?=,|$)', 3)
  _ArrayDisplay($names)
Next

[Melba23]

gcue,

 

$names = StringRegExpReplace($string, "(?U)^.*\|?" & $current_list & ":\s(.*)(\|.*)?$", "$1")

SRER decode:

(?U)           - Not greedy
^              - Start at the beginning
.*\|?          - There might be some characters ending in "|"
$current_list  - followed by the title...
:\s            - ...a colon and a space
(.*)           - Capture the text
(\|.*)?        - but not after another "|"
$              - and so we get to the end

That works for me.

M23

Edit: It always takes me too long to develop RegEx patterns.

Edited December 22, 2014 by Melba23

[kylomas]

How quickly you develop SRE's is inversely proportional to how human you are (as opposed to machine).

[Melba23]

kylomas,

A nice thought - thanks!

M23

[mikell]

Hmmm... couldn't output an array using a single regex 

#include <Array.au3>

Local $lists_array[3] = ["Test", "Test 2", "Test_3"]
$string = "Test: mike,peter,bob|Test 2: jack,jill,tim|Test_3: fabio,mark,jed"

For $x = 0 to ubound($lists_array)-1
  $names = StringSplit(StringRegExp($string, $lists_array[$x] & ':\h*([^|]+)', 3)[0], ",", 2)
  _ArrayDisplay($names)
Next