_ArrayDisplay and FileGetTime

[gius]

Hello everyone,
I apologize for my English.

I am developing a small application
with _ArrayAdd

Local $aFileList = _FileListToArray (@DesktopCommonDir)
Local $aFileList1 = _FileListToArray (@DocumentsCommonDir)
Local $aFileList2 = _ArrayAdd ($aFileList, $aFileList1)
_ArrayDisplay ($aFileList2)

but is not nothing in _ArrayDisplay,
  why?

Then, how I can see the file, the date of modification?

FileGetTime ($aFileList, $ FT_MODIFIED, 1)
and
FileGetTime ($aFileList1, $ FT_MODIFIED, 1)

Where I can add?

Thanks for your help

[jchd]

Read again help file over _ArrayDisplay _ArrayAdd, and you'll discover that it uses a ByRef first parameter and returns something distinct from what you expect it to.

Yet my answer isn't quite right as Melba rightly stressed just now. I badly need a second coffee for the other eye...

Edited January 4, 2015 by jchd

[Melba23]

gius,

Welcome to the AutoIt forums.

You need to concatenate the arrays. Here is an example which shows you how to do what you want:

#include <Array.au3>
#include <File.au3>

Local $aFileList = _FileListToArray (@DesktopCommonDir)
; Add a column
_ArrayColInsert($aFileList, 1)
; And loop through the elements to get the time stamp
For $i = 1 To $aFileList[0][0]
    $aFileList[$i][1] = FileGetTime(@DesktopCommonDir & "\" & $aFileList[$i][0], $FT_MODIFIED, 1)
Next
; Here is the result
_ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8)

; Now do the same for the other list
Local $aFileList1 = _FileListToArray (@DocumentsCommonDir)
; Add a column
_ArrayColInsert($aFileList1, 1)
; And loop through the elements to get the time stamp
For $i = 1 To $aFileList1[0][0]
    $aFileList1[$i][1] = FileGetTime(@DocumentsCommonDir & "\" & $aFileList1[$i][0], $FT_MODIFIED, 1)
Next
; Here is the result
_ArrayDisplay($aFileList1, "@DocumentsCommonDir", Default, 8)

; Use concatenate to join arrays - note we do not concatenate the count from the second array
_ArrayConcatenate ($aFileList, $aFileList1, 1)
; But we add it here
$aFileList[0][0] += $aFileList1[0][0]

;And here you have the result
_ArrayDisplay($aFileList, "Concatenated", Default, 8)

Please ask if you have any questions.

M23

[gius]

Thank You Melba23,

your commented code, it is really clear and very well explained.

I have a small problem:
if I insert address as a folder on the Desktop,
example folder "Test"
I have an error

is no longer visible the last modification

Local $aFileList = _FileListToArray (@DesktopDir "Test")
$aFileList [$i] [1] = FileGetTime (@DesktopDir "Test" & $aFileList [$i] [0], $FT_MODIFIED, 1)

where I am wrong?

thanks again

 

I apologize, I realized that I had not entered "" after the address of the folder "Test"

Local $aFileList = _FileListToArray (@DesktopDir "Test")
$aFileList [$i] [1] = FileGetTime (@DesktopDir "Test"  & "" & $aFileList [$i] [0], $FT_MODIFIED, 1)

Sorry and thanks again

Edited January 4, 2015 by gius

[mikell]

$aFileList [$i] [1] = FileGetTime (@DesktopDir "Test" & "" & $aFileList [$i] [0], $FT_MODIFIED, 1)

[gius]

It is possible to change the date format

of FileGetTime "YYYYMMDDHHMMSS"
in "YYYY/MM/DD[HH:MM:SS]" of DateTimeFormat with $Type = 0

_DateTimeFormat(_NowCalc(), 0) ?

thanks to all

[water]

Sure. Please have a look at StringRegExpReplace or search the forum for "date formatting" or something similar.

[jguinch]

; Method 1, with an array
$aTime = FileGetTime (@ScriptFullPath)
$sRes = $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"
ConsoleWrite($sRes & @CRLF)

; Method 2, with string manipulation
$sTime = FileGetTime (@ScriptFullPath, 0, 1)
$sRes = StringRegExpReplace($sTime, "^(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})(\d{2})", "$1/$2/$3[$4:$5:$6]")
ConsoleWrite($sRes & @CRLF)

[gius]

Thank You jguinch and water

for your help,
but in this code 

#include <Array.au3>
#include <File.au3>

Local $aFileList = _FileListToArray (@DesktopCommonDir)
; Add a column
_ArrayColInsert($aFileList, 1)
; And loop through the elements to get the time stamp
For $i = 1 To $aFileList[0][0]
    $aFileList[$i][1] = FileGetTime(@DesktopCommonDir & "\Test" & "\" & $aFileList[$i][0], $FT_MODIFIED, 1)
Next
; Here is the result
_ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8)

I can not understand where to insert

$sRes = $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"

You can still help me?
thank you

[Melba23]

gius,

You need to do something like this:

For $i = 1 To $aFileList[0][0]
    ; Get file timestamp as an array
    $aTime = FileGetTime(@DesktopCommonDir & "\Test\" & $aFileList[$i][0], $FT_MODIFIED)
    ; Format the array elements as required
    $aFileList[$i][1] = $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"
Next

M23

[gius]

Thank You Melba23,

I put your help

#include <Array.au3>
#include <File.au3>
Local $aFileList = _FileListToArray (@DesktopCommonDir & "\Test\") ; Add a column
_ArrayColInsert($aFileList, 1) ; And loop through the elements to get the time stamp
For $i = 1 To $aFileList[0][0]     ; Get file timestamp as an array
$aTime = FileGetTime(@DesktopCommonDir & "\Test\" & $aFileList[$i][0], $FT_MODIFIED)
; Format the array elements as required
 $aFileList[$i][1] = $aTime[0] & "\" & $aTime[1] & "\" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"
Next

_ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8)

but I returns this error:

Subscript used on non-accessible variable.:
For $i = 1 To $aFileList[0][0]
For $i = 1 To $aFileList^ ERROR

I have done something wrong?

thank you

[Melba23]

gius,

That would mean that the function has not found any files in the folder. So you need to add some errorchecking, perhaps like this:

#include <Array.au3>
#include <File.au3>

Local $aFileList = _FileListToArray (@DesktopCommonDir & "\Test")
If Not @error Then
    ; Add a column
    _ArrayColInsert($aFileList, 1)
    ; And loop through the elements to get the time stamp
    For $i = 1 To $aFileList[0][0]
        $aTime = FileGetTime(@DesktopCommonDir & "\Test" & "\" & $aFileList[$i][0], $FT_MODIFIED)
        $aFileList[$i][1] = $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"
    Next
    ; Here is the result
    _ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8)
Else
    MsgBox($MB_SYSTEMMODAL, "Error", "No files found")
EndIf

M23

[gius]

Thank You Melba23,
Your code works fine.

I have tried to add a second column, $ FT_CREATED,

#include <Array.au3> 
#include <File.au3> 
Local $aFileList = _FileListToArray (@DesktopCommonDir & "\Test") 
If Not @error Then     
; Add a column     
   _ArrayColInsert($aFileList, 2)     
; And loop through the elements to get the time stamp     
   For $i = 1 To $aFileList[0][0]         
      $aTime = FileGetTime(@DesktopCommonDir & "\Test" & "\" & $aFileList[$i][0], $FT_MODIFIED,$FT_CREATED)        
      $aFileList[$i][2] = $aTime[0] & "/" & $aTime[1] & "/" & $aTime[2] & "[" & $aTime[3] & ":" & $aTime[4] & ":" & $aTime[5] & "]"    
   Next     ; Here is the result    
   _ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8) 
Else     
MsgBox($MB_SYSTEMMODAL, "Error", "No files found") 
EndIf

but I'm wrong in something,

where?

thank you

[Melba23]

gius,

You need to read the Help file when you try to change function parameters - what you did made no sense at all when you look how the functions work.

If you want another column with the created time you need to do something like this:

#include <Array.au3>
#include <File.au3>

Local $sPath = @DesktopCommonDir & "\Test"
Local $aFileList = _FileListToArray($sPath)
If Not @error Then
    ; Add 2 columns <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    _ArrayColInsert($aFileList, 1)
    _ArrayColInsert($aFileList, 2)
    ; And loop through the elements to get the different time stamps
    For $i = 1 To $aFileList[0][0]
        $sFile = $sPath & "\" & $aFileList[$i][0]
        $aTime_Mod = FileGetTime($sFile, $FT_MODIFIED)    ; Modified time
        $aTime_Created = FileGetTime($sFile, $FT_CREATED) ; Created time
        ; Now add these values to the array
        $aFileList[$i][1] = $aTime_Mod[0] & "/" & $aTime_Mod[1] & "/" & $aTime_Mod[2] & "[" & $aTime_Mod[3] & ":" & $aTime_Mod[4] & ":" & $aTime_Mod[5] & "]"
        $aFileList[$i][2] = $aTime_Created[0] & "/" & $aTime_Created[1] & "/" & $aTime_Created[2] & "[" & $aTime_Created[3] & ":" & $aTime_Created[4] & ":" & $aTime_Created[5] & "]"
    Next ; Here is the result
    _ArrayDisplay($aFileList, "@DesktopCommonDir", Default, 8)
Else
    MsgBox($MB_SYSTEMMODAL, "Error", "No files found")
EndIf

M23