How this code work?

[Guest]

Helo,

I have this function that I wrote some time ago:

expandcollapse popup

Func _RetrieveRunningServices2($Sort = 0)
    Local $Output[1][2], $iPid
    $Output[0][0] = 0
    $iPid = Run(@ComSpec & " /c sc query", @SystemDir, @SW_HIDE, 2)
    If $iPid > 0 Then
        ProcessWaitClose($iPid)
        ; from here the Process $iPid Should be closed
        Sleep(10000) ; just to be sure that the process is really closeed..
        If ProcessExists($iPid) Then ConsoleWrite(1 &" (Line "&@ScriptLineNumber&")"&@CRLF) ; And this line confirms that the process really close
        Local $StdoutRead = StdoutRead($iPid) ; So how this line works if $iPid is closed ?? ther is not @error
        If Not @error Then
            Local $add = 0, $n = 1, $aStdoutRead, $tmp
            $aStdoutRead = StringSplit($StdoutRead, @CRLF, 1)
            For $a = 1 To $aStdoutRead[0]
                $tmp = StringLeft($aStdoutRead[$a], 1)
                If $tmp <> " " And $tmp <> "" Then
                    $tmp = StringSplit($aStdoutRead[$a], ": ", 1)
                    If $tmp[0] = 2 Then
                        If $add = 0 Then
                            ReDim $Output[$n + 1][2]
                            $Output[$n][0] = $tmp[$tmp[0]]
                            $add = 1
                        Else
                            $Output[$n][1] = $tmp[$tmp[0]]
                            $Output[0][0] = $n
                            $n += 1
                            $add = 0
                        EndIf
                    EndIf
                EndIf
            Next
            If $Sort = 1 And $Output[0][0] > 0 Then _ArraySort($Output, 0, 1, 0, 1) ; Sort by DisplayName
        EndIf
    EndIf
    ;$Output[0][0]
    Return $Output
EndFunc   ;==>_RetrieveRunningServices2

My question is in the code:

ProcessWaitClose($iPid)
; from here the Process $iPid Should be closed
Sleep(10000) ; just to be sure that the process is really closeed..
If ProcessExists($iPid) Then ConsoleWrite(1 &" (Line "&@ScriptLineNumber&")"&@CRLF) ; And this line confirms that the process really close
Local $StdoutRead = StdoutRead($iPid) ; So how this line works if $iPid is closed ?? ther is not @error
If Not @error Then

Thanks for helpers!

Edited January 6, 2015 by Guest

[guinness]

Search about flushing the standard input stream.

[Gianni]

I had the same perplexity as exposed in >this post and also >here time ago.
in any case it seems that the way to read the StdOut stream from an already death process

is also used in the official help of AutoIt, as from the example of the StdOutRead command... 

[Guest]

I had the same perplexity as exposed in >this post and also ?do=embed' frameborder='0' data-embedContent>>here time ago.

in any case it seems that the way to read the StdOut stream from an already death process

is also used in the official help of AutoIt, as from the example of the StdOutRead command... 

 

Thanks for the information.

I had a feeling that it could cause problems and you gave evidence.

I will use this ?do=embed' frameborder='0' data-embedContent>>piece of code instead ProcessWaitClose($iPid)

 

I Still did not understand how it can read information from dead process.

 

EDIT:

New function with the fix for this potential bug/problem:

Func _RetrieveRunningServices2($Sort = 0)
    Local $Output[1][2], $iPid
    $Output[0][0] = 0
    $iPid = Run(@ComSpec & " /c sc query", @SystemDir, @SW_HIDE, 2)
    If $iPid <= 0 Then Return $Output
    Local $StdoutRead,$tmp = TimerInit()
    Do
        If TimerDiff($tmp) > 15000 Then Return $Output ; just a fix for another potential bug/problem that the loop will never ends ..
        $StdoutRead &= StdoutRead($iPid)
    Until @error
    Local $add = 0, $n = 1, _
    $aStdoutRead = StringSplit($StdoutRead, @CRLF, 1)
    For $a = 1 To $aStdoutRead[0]
        $tmp = StringLeft($aStdoutRead[$a], 1)
        If StringStripWS($tmp,3) = '' Then ContinueLoop
        $tmp = StringSplit($aStdoutRead[$a], ": ", 1)
        If $tmp[0] <> 2 Then ContinueLoop
        If $add = 0 Then
            ReDim $Output[$n + 1][2]
            $Output[$n][0] = $tmp[$tmp[0]]
            $add = 1
        Else
            $Output[$n][1] = $tmp[$tmp[0]]
            $Output[0][0] = $n
            $n += 1
            $add = 0
        EndIf
    Next
    If $Sort And $Output[0][0] > 1 Then _ArraySort($Output, 0, 1, 0, 1) ; Sort by DisplayName
    Return $Output
EndFunc   ;==>_RetrieveRunningServices2

EDIT: The code has been updated with a fix for another potential bug/problem that the loop will never ends ..

Edited January 6, 2015 by Guest