Sorting a listview

[tommeke228]

Hi there

Here's a picture of my listview loaded in with FileFindFirstFile

 

and here with _FileListToArray

 

How can i make that it sorts perfectly from 1 till 12 ?

Putting numbers in the filename doesnt work, it doesn't work without it... pff

is there an easy solution ?

grtz

Tom

[Melba23]

tommeke228,

 

is there an easy solution ?

In short - no. As this recent thread showed. >

M23

[tommeke228]

pff thanks

gona search a solution because it needs to be fixed ;p (will post it then)

grtz

tom

[Melba23]

tommeke228,

If these filenames are created by you, then forcing the leading number into a fixed format with leading zeroes will work.

M23

[jdelaney]

You can re-dim the array to add a second dimention...use a regexp to grab the leading numbers, and convert them to integers...then sort by that new column...edit: repopulate back to the 1d array.

#include <Array.au3>
Local $a[3]=["1 something", "11 something2", "2 something3"]
_ArrayDisplay($a)

; since the redim doesn't work when changing dimentions, create a new one...quicker
Local $a2[UBound($a)][2]
For $i = 0 To UBound($a2)-1
    $a2[$i][0] = $a[$i]
    $a2[$i][1] = Number(StringRegExpReplace($a[$i],"(\d+)(.*)","\1"))
Next

_ArraySort($a2,0,0,0,1)
For $i = 0 To UBound($a)-1
    $a[$i] = $a2[$i][0]
Next
$a2 = ""

_ArrayDisplay($a)

Edited January 9, 2015 by jdelaney

[SmOke_N]

As Melba said, leading zeros with StringFormat (I usually use 6) solves the issue nicely for future issues.

This situation is easily fixed though, just using converting to int().

IMO, this is not a cure all though, doesn't take care of numbers throughout the string.

expandcollapse popup

#include <Array.au3>

Global $gaOrignal[] = [ _
    "1 Monday 5 January 2015_6u_7u", "10 Tuesday 6 January 2015_4-5", _
    "11 Tuesday 6 January 2015_17u15-18u15", "12 Wednesday 7 January 2015_6u15-7u15", _
    "2 Monday 5 January 2015_7u15-9u15", "3 Monday 5 January 2015_9u30-12u00", _
    "4 Monday 5 January 2015_12u30-16u00", "5 Monday 5 January 2015_16u-17u", _
    "6 Tuesday 6 January 2015_6u15-7u15", "7 Tuesday 6 January 2015_7u15-9u15", _
    "8 Tuesday 6 January 2015_9u30-12", "9 Tuesday 6 January 2015_12u30-17u15"]

_ArrayDisplay($gaOrignal)
_mySimple1DArrSortSolution($gaOrignal)
_ArrayDisplay($gaOrignal)


Func _mySimple1DArrSortSolution(ByRef $aArr, $iDesc = 0, $iStart = 0, $iEnd = 0)

    If Not IsArray($aArr) Then Return SetError(1, 0, 0)
    If UBound($aArr, 2) Then Return SetError(2, 0, 0)

    Local $iUB = UBound($aArr)
    If $iEnd < $iStart Or $iEnd > ($iUB - 1) Then Return SetError(3, 0, 0)
    $iEnd = (IsKeyword($iEnd) Or $iEnd < 1) ? $iUB - 1 : $iEnd

    Local $aTmp[$iUB][2]
    For $i = $iStart To $iEnd
        $aTmp[$i][0] = $aArr[$i]
        $aTmp[$i][1] = Int($aArr[$i])
    Next

    _ArraySort($aTmp, $iDesc, $iStart, $iEnd, 1)

    For $i = $iStart To $iEnd
        $aArr[$i] = $aTmp[$i][0]
    Next

EndFunc

Edit:

Oops, didn't see jdelaney posted.

Edited January 9, 2015 by SmOke_N

[jdelaney]

Almost exactly the same technique...I just used a regexp to grab the first digits, instead of grabbing all of them.

[tommeke228]

thankyou so much guys !!!! :thumbsup:

Edited January 10, 2015 by tommeke228