Convert first letter to small letter

[tmsandeep]

How I can convert first letter in string to small letter

Like I got string from

Local $str = ClipGet();

Now how I can convert first letter alone to small letter.

[kylomas]

one way to do it...

local $s = 'What'

$s = stringlower(stringleft($s,1)) & stringright($s,stringlen($s)-1)

ConsoleWrite($s & @CRLF)

kylomas

[Malkey]

A similar way to do it.

Local $str = ClipGet()
$str = StringLower(StringLeft($str, 1)) & StringMid($str, 2)
ConsoleWrite($str & @LF)

[kylomas]

yes, better way...I forgot that StringMid defaults to the rest of the string for the 3RD parm... 

[tmsandeep]

Thank you folks, it is working great.

[SmOke_N]

Another way:

StringLower(StringLeft($sString, 1)) & StringTrimLeft($sString, 1)

And another:

StringRegExpReplace($sString, "(.)(.*?)$", StringLower(StringLeft($sString, 1)) & "$2")

And another:

StringLower(StringSplit($sString, "", 2)[0]) & StringTrimLeft($sString, 1)

I could probably do this all day.

[jguinch]

StringRegExpReplace($string, "^.", StringLower( StringLeft($string, 1) ) )

StringReplace($string, StringLeft($string, 1) , StringLower( StringLeft($string, 1) ), 1 )

.... all day

[kylomas]

Ha!  Bet you guys can't come up with a bitwise way of doing it...?

[SmOke_N]

StringLower(StringRegExp($sString, "^.",1)[0]) & StringTrimLeft($sString, 1)

[kylomas]

@SmOke_N - I hope that is not in response to me...

edit: Was thinking more of a way to use a bitwise operator to add 32 ( or whatever the offset is) to the 1ST byte. 

Edited January 20, 2015 by kylomas

[SmOke_N]

@kylomas

Global $gsOut = ((StringIsLower(StringLeft($sString, 1))) ? $sString : Chr(BitXOR(Asc(StringLeft($sString, 1)), 32)) & StringTrimLeft($sString, 1))

Edit:

Or:

Global $gsOut = ((StringIsLower(StringLeft($sString, 1))) ? $sString : Chr(BitXOR(StringToASCIIArray($sString)[0], 32)) & StringTrimLeft($sString, 1))

Edited January 20, 2015 by SmOke_N

[kylomas]

@SmOke_N - WOW, not going to mention that I've been fruitlessly jag'in around with this, on and off, since the thread started.

Thanks...

[kaesereibe]

or with MSDN CharLowerBuff function with cchLength = 1

[Malkey]

This is using the regular expression unicode character property for lower case, "p{Ll}",  to check if the first character is lower case.  Ref. from here.

Local $sString = "Local $sString"
Global $gsOut = StringRegExp($sString, "^\p{Ll}") ? $sString : (Chr(Asc(StringLeft($sString, 1)) + 32) & StringMid($sString, 2))
ConsoleWrite($gsOut & @LF)

Edited January 21, 2015 by Malkey

[kaesereibe]

Here is an example with CharLowerBuff

$string = "UPPER_TO_LOWER"
$length = 1

Func _CharLowerBuff($string, $length)
    $ret = DllCall("user32.dll", "DWORD", "CharLowerBuff", "str", $string, "DWORD", $length)
    Return $ret[1]
EndFunc    ;==> _CharLowerBuff

MsgBox(0, "_CharLowerBuff()", _CharLowerBuff($string, $length))    ; ==> uPPER_TO_LOWER

or

$string = "UPPER_TO_LOWER"
$length = 1

$ret = DllCall("user32.dll", "DWORD", "CharLowerBuff", "str", $string, "DWORD", $length)

MsgBox(0, "CharLowerBuff()", $ret[1])    ; ==> uPPER_TO_LOWER

Edited January 21, 2015 by kaesereibe

[SmOke_N]

Or

MsgBox(0, "CharLowerBuff()", DllCall("user32.dll", "DWORD", "CharLowerBuff", "str", "UPPER_TO_LOWER", "DWORD", 1)[1])    ; ==> uPPER_TO_LOWER

[BrewManNH]

A DLL call seems a LITTLE bit over the top just to make a letter lower cased.

[kaesereibe]

Thx for hint SmOke_N

Why not?

Isn't AutoIt Function StringLower the same like MSDN CharLower function?

Edited January 21, 2015 by kaesereibe

[SmOke_N]

@BrewManNH... everyone is just playing around after the first few working examples in the post.  But I'd prefer to use the DLL call myself to be honest (if it were wrapped).

[BrewManNH]

Yeah, but it's one command built into the language, and we let AutoIt worry about the implementation of it. I personally don't care HOW it's done I just want to get it done.

I want a quarter inch hole, not a quarter inch drill.