Read Array from file and laterz seprate them

[Faran]

Hello,

i m totaly newbie to Autoit i need some help with this

i have a array in text file users.txt something like this

profile[1]=user1|password1
profile[2]=user2|password2
profile[3]=user3|password3
profile[4]=user4|password4
profile[5]=user5|password5

i want to import this array to multi select listbox
 and laterz seprate them and login to a site by them

thanks

[water]

Welcome to AutoIt and the forum!

Function FileReadToArray would be a good start.

To split strings try function StringSplit.

[Melba23]

Faran,

Why do you want to log into "a site" using many different username/password combinations and why are you storing these combinations in a simple text file?

M23

[Faran]

something like this

#include <file.au3>

Dim $aArray
If _FileReadToArray("users.txt",$aArray) then
   MsgBox(0,"Array Output records",$aArray[0])
Else
   MsgBox(0,"Error","Error from Function")
EndIf
Exit

but isnt only for counting this telling me "7" a nummber of array only

[Faran]

good question

i have many email account thats why i want to save them all to a text file

and wiv autoit i want to login to selected Email account which will be display in Listbox i guess but i m not so familar to autoit

[Melba23]

Faran,

Fine.

M23

[Faran]

so far i have i have got my text file 2d array in Listbox

but 2nd issue how will i get text from colum1 and colum2 of selected items

#include <File.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 615, 438, 192, 124)
$button = GUICtrlCreateButton("Selected item", 10, 325)
$List1 =  GUICtrlCreateListView("List|List1", 2, 40, 394, 268, BitOR($LBS_MULTIPLESEL,$LBS_MULTICOLUMN,$LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
$file = "users.txt"
FileOpen($file, 0)
For $i = 1 to _FileCountLines($file)
      $line = FileReadLine($file, $i)
GUICtrlCreateListViewItem($line,$List1)

Next
FileClose($file)
 _GUICtrlListView_SetItemSelected($List1, 1)
    _GUICtrlListView_SetItemSelected($List1, 2)
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
         case $button
       MsgBox (0,"Selected","Item are" & _GUICtrlListView_GetSelectedIndices($List1,1))
    EndSwitch
WEnd

thanks in advance

[Melba23]

Faran,

This should give you an idea of how you might proceed:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListView.au3>

$file = "users.txt"

$Form1 = GUICreate("Form1", 615, 438, 192, 124)

$button = GUICtrlCreateButton("Selected item", 10, 325)
$List1 =  GUICtrlCreateListView("List|List1", 2, 40, 394, 268)

GUISetState(@SW_SHOW)

; Read the file into an array
$aLines = FileReadToArray($file)
; Loop through the array
For $i = 0 To @extended - 1
    ; Extract the data
    $sUser = StringRegExpReplace($aLines[$i], "^.*=(.*)\|.*$", "$1")
    $sPass = StringRegExpReplace($aLines[$i], "^.*\|(.*)$" , "$1")
    ; And fill the ListView
    GUICtrlCreateListViewItem($sUser & "|" & $sPass, $List1)
Next

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            ; Get the selected item
            $sSelection = Number(_GUICtrlListView_GetSelectedIndices($List1, False))
            ; Extract the data from the original array
            $sUser = StringRegExpReplace($aLines[$sSelection], "^.*=(.*)\|.*$", "$1")
            $sPass = StringRegExpReplace($aLines[$sSelection], "^.*\|(.*)$" , "$1")
            ; And here it is
            MsgBox($MB_SYSTEMMODAL, "Selection", "UserName:" & @TAB & $sUser & @CRLF & "Password: " & @TAB & $sPass)
    EndSwitch
WEnd

M23

[Faran]

thanks m23 but its not filling the listbox at all

[Melba23]

Faran,

I used the same file format as you showed in the OP:

profile[1]=user1|password1
profile[2]=user2|password2
profile[3]=user3|password3
profile[4]=user4|password4
profile[5]=user5|password5

Is that not how the file reads? If not then what does it look like?

M23

[Faran]

M23

its same file but see i have screen shoot there is nothing inside listbox

[Melba23]

Faran,

A thought - re-reading the OP makes me think the actual file content looks like this:

user1|password1
user2|password2
user3|password3
user4|password4
user5|password5

If this is the case then this code should work:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListView.au3>

$file = "users.txt"

$Form1 = GUICreate("Form1", 615, 438, 192, 124)

$button = GUICtrlCreateButton("Selected item", 10, 325)
$List1 =  GUICtrlCreateListView("Username|Password", 2, 40, 394, 268)

GUISetState(@SW_SHOW)

$aLines = FileReadToArray($file)
For $i = 0 To @extended - 1
    ; Add the already formatted data
    GUICtrlCreateListViewItem($aLines[$i], $List1)
Next


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $iSelection = Number(_GUICtrlListView_GetSelectedIndices($List1, False))
            ; Split the array line on the "|"
            $aSplit = StringSplit($aLines[$iSelection], "|")
            MsgBox($MB_SYSTEMMODAL, "Selection", "UserName:" & @TAB & $aSplit[1] & @CRLF & "Password: " & @TAB & $asplit[2])
    EndSwitch
WEnd

If that still does not work, please post a copy of the file with which you want to work.

M23

[Faran]

M23

still same issue

used this

user1|password1
user2|password2
user3|password3
user4|password4
user5|password5

in file and putted ur new given codes but nothing comes in listbox

and when press button its show

[Melba23]

Faran,

Is the file in the same folder as the script? If not, use the full path when you declare the $file variable.

M23

[Faran]

yes its in same Folder where the script is

[Melba23]

Faran,

Then I am at a complete loss - the code works for me or I would not have posted it. >

Let us see if we can pin down which part of the script is failing. Try running this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <GuiListView.au3>

; Prefill the array
Global $aLines[5] = ["user1|password1", "user2|password2", "user3|password3", "user4|password4", "user5|password5"]

$Form1 = GUICreate("Form1", 615, 438, 192, 124)

$button = GUICtrlCreateButton("Selected item", 10, 325)
$List1 =  GUICtrlCreateListView("Username|Password", 2, 40, 394, 268)

GUISetState(@SW_SHOW)

For $i = 0 To 4
    ; Add the already formatted data
    GUICtrlCreateListViewItem($aLines[$i], $List1)
Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $iSelection = Number(_GUICtrlListView_GetSelectedIndices($List1, False))
            ; Split the array line on the "|"
            $aSplit = StringSplit($aLines[$iSelection], "|")
            MsgBox($MB_SYSTEMMODAL, "Selection", "UserName:" & @TAB & $aSplit[1] & @CRLF & "Password: " & @TAB & $asplit[2])
    EndSwitch
WEnd

Does it work now?

M23

[Faran]

hello m23

I used "For $i = 0 To Ubound($aLines)  -1" instead of "For $i = 0 To @extended - 1" and its worked now

thanks you so much for ur time

faran

[Melba23]

Faran,

My fault for using the latest beta where @extended holds the number of lines read. Glad you got it working.

M23