Global declared twice, is it suppose to keep the previous value?

[nitekram]

I thought that when you declared a variable as Global, and then declared it again as Global - it would overwrite the previous value. But I think it is working more like a Static Variable. And I could be completly wrong too?

Here is the code, it runs ever min ie 59 seconds, and it keeps appending EST over and over - I know how to fix it, but really thought that if one was to declare a variable with the same name and scope, that it would set it back to NULL, or at least not keep the current value

#include <Date.au3>

While 1
    If @SEC = 59 Then
        ; Show current time zone information
        Global $aOld = _Date_Time_GetTimeZoneInformation()
        Global $sTimeZone
        Global $aTimeZone = StringSplit($aOld[2], ' ')
        Global $iHour = ''
        Global $sUIP = ''

        If @HOUR = 0 Then
            $iHour = 12 & 'AM'
        ElseIf @HOUR >= 13 Then
            $iHour = @HOUR - 12 & 'PM'
        Else
            $iHour = @HOUR & 'AM'
        EndIf

        For $x = 1 To UBound($aTimeZone) - 1
            $sTimeZone &= StringLeft($aTimeZone[$x], 1)
        Next
        ;_ArrayDisplay($aTimeZone)
        $sUIP = ' ' & @MON & '.' & @MDAY & '.' & @YEAR & ' | ' & $iHour & ' ' & $sTimeZone
        MsgBox($MB_OK, 'DATE | HOUR ZONE', 'Send it, clipboarded subject line' & @CRLF & @CRLF _
                 & $sUIP)
        ClipPut($sUIP)
    EndIf

WEnd

.

[JohnOne]

It does set it back to uninitiated in your case above.

The problem there is you do not test it.//I assume it's $sTimeZone as it's the only one declared twice.

And as you know declaring variables in a loop is daft.

EDIT:

Totally misread the code.

Edited February 9, 2015 by JohnOne

[water]

A short test will show you how it works:

Global $Test = "Test"
ConsoleWrite($Test & @CRLF)
Global $Test
ConsoleWrite($Test & @CRLF)

returns "Test" two times.

[nitekram]

So no bug, but I would think that it would delete whatever value it was - again, I find that I am wrong. Thanks

[jdelaney]

Create a function for the internal If statement, and use LOCAL variables...then they will clear out after each return from the function.

Else, specifically set each variable ="" athe the start of the if statement.

Edited February 9, 2015 by jdelaney

[TheSaint]

From what I understand about Global declaration, is that you should only do it once.

In fact, you should get an error at compile time if you declare more than once.

If you need to reset/destroy a variable, use the Local scope, as suggested.

Really though, once you do a Global declaration for a variable, why would you ever need to do so again, when you can set the value to anything, including nothing. If it needs to be destroyed, either use it with Local instead or avoid using a variable altogether ... though I'm sure there is a way to null.

[TheDcoder]

Thanks for starting this thread

[water]

So no bug, but I would think that it would delete whatever value it was - again, I find that I am wrong. Thanks

The value of an already declared variable is only changed when you assign a new value to it. Either in the second "Global" statement or in an assignment.

[nitekram]

Okay, I now see my mistake. Besides declaring the variable as global each time, I thought it was similar to removing the data from an array by redeclaring it with the global key word. I have learned a lot about variables in the last couple of posts, or I am just getting too old to remember, what I already learned.

The reason for using the global key word, is that I wanted to keep all the code in one place for testing, and then move it to its own file.

Thanks again, for every ones time and help.

Edited February 10, 2015 by nitekram

[SmOke_N]

There are times when a Global/Dim does change the scope/initializer... actually, only one comes to mind at the moment:

#include <Array.au3>
Global $gaArr; I'm going to use this in the future, but might not be an array if condition doesn't meet
ConsoleWrite(VarGetType($gaArr) & @CRLF) ; not an array
_some_func()
ConsoleWrite(VarGetType($gaArr) & @CRLF) ; now is an array
_ArrayDisplay($gaArr)

Func _some_func()
    If 1 = 1 Then
        ; condition is met, initialize array
        Global $gaArr[2] = ["Hello", "There"]; I actually use Dim here as a personal preference so I can track my code and what I'm doing
    EndIf
EndFunc

Edit:

I use this method when I need to clear/delete an array too, even though it is still probably declared as an array type.

Edited February 10, 2015 by SmOke_N

[nitekram]

I was reading a thread, where they did not want to remove the array elements, but only the data, so in your example, you could declare Global $gaArr[2], would remove only that data? Sorry, doing this from my phone.

Edited February 10, 2015 by nitekram

[water]

Yes, it does.

#include <array.au3>
Global $gaArr[2] = [1, 2]
_ArrayDisplay($gaArr)
Global $gaArr[2]
_ArrayDisplay($gaArr)

returns an empty array the second time.

[nitekram]

So I think that is where my confusion came in, I thought it would be the same, and remove the value of the data. But I now know better.

Edited February 10, 2015 by nitekram

[JohnOne]

May I ask, what variable is declared twice in your original code?

Either I'm badly blind or none of them are.

[czardas]

All the globals (in the first post) are declared over again each time the loop repeats. The declarations really ought to be placed before the loop.

Edited February 10, 2015 by czardas

[water]

They get declared multiple times because the Global statements are within the loop.

[JohnOne]

I see, thought OP meant variable was redeclared each time in loop.

[czardas]

Declartation occuring in a loop that repeats is always redeclaring after the first run. That's what the 're' part of the word implies. ^^

[JohnOne]

Semantics, I mean it's declared only once in each loop.

[czardas]

Ah okay! Each loop? Perhaps using Static is acceptable inside a loop - strange idea though. I believe I would ever do that personally. NOPE ==> Returns an error.

Edited February 10, 2015 by czardas