_IEDocWriteHTML - ExtractedHTML

[mLipok]

I'am using such script:

#include <IE.au3>
#include <FileConstants.au3>

Local $hFileOpen = FileOpen('test.html', $FO_READ + $FO_UTF8)
Local $sHTML = FileRead($hFileOpen)
FileClose($hFileOpen)

Local $oIE = _IECreate()
_IEDocWriteHTML($oIE, $sHTML)

But in results I do not see image in IE .

What to do to properly display this image inside IE.

All files are here ExtractedHTML.zip

[SmOke_N]

So... test.html opens correctly in the browser, and the test.html is written in utf-8?

Edit:

I answered this for someone else not to long ago.

src="images/jigbbabf.png"

Is not going to work when adding the code dynamically.  Remember, you're not a server.

You need the direct path... eg:

src="file://C:/MyPath/images/jigbbabf.png"

Edited February 17, 2015 by SmOke_N

[mLipok]

hmm...

I just check by using FileGetEncoding and I get 0 = ANSI

so I used:

#include <IE.au3>
#include <FileConstants.au3>

Local $hFileOpen = FileOpen('test.html', $FO_READ)
Local $sHTML = FileRead($hFileOpen)
FileClose($hFileOpen)

Local $oIE = _IECreate()
_IEDocWriteHTML($oIE, $sHTML)

But I still do not see images inside IE.

Why ?

[SmOke_N]

I explained why with the file:///[drive letter]:/Fullpath/etc

Here's a fix if you don't want to hard code the files, you'd have to code pretty consistent with your html though:

#include <IE.au3>
#include <FileConstants.au3>

Local $hFileOpen = FileOpen('test.html', $FO_READ + $FO_UTF8)
Local $sHTML = FileRead($hFileOpen)
_html_imgSrcToLocalPath($sHTML)
FileClose($hFileOpen)

Local $oIE = _IECreate()
_IEDocWriteHTML($oIE, $sHTML)

Func _html_imgSrcToLocalPath(ByRef $sHTML, $sPath = @ScriptDir)

    Local $aImgFiles = StringRegExp($sHTML, "(?is)(<\s*img\s+src=[""'](.+?)[""'])", 3)
    If @error Then ; no img files
        Return SetError(1, 0, 0)
    EndIf

    $sPath = StringReplace(StringRegExpReplace($sPath, "[\\/]+$", ""), "\", "/", 0, 1)
    Local $sRepl
    For $i = 0 To UBound($aImgFiles) -1 Step 2
        If StringRegExp($aImgFiles[$i + 1], "^(?i)\s*(http|s?ftp|file:///)") Then ContinueLoop
        $sRepl = StringReplace($aImgFiles[$i], $aImgFiles[$i + 1], _
            "file:///" & $sPath & "/" & $aImgFiles[$i + 1])
        $sHTML = StringReplace($sHTML, $aImgFiles[$i], $sRepl, 1, 0)
    Next

    Return 1
EndFunc

Edited February 17, 2015 by SmOke_N

[mLipok]

 

Edit:

I answered this for someone else not to long ago.

src="images/jigbbabf.png"

Is not going to work when adding the code dynamically.  Remember, you're not a server.

You need the direct path... eg:

src="file://C:/MyPath/images/jigbbabf.png"

 

I do not see your edit when I post my previous post.

Thanks it works.

But ultimately I wanted to do something like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <IE.au3>
#include <FileConstants.au3>

Local $hFileOpen = FileOpen('test.html', $FO_READ)
Local $sHTML = FileRead($hFileOpen)
FileClose($hFileOpen)

;~ $oIE = _IECreate()
;~ _IEDocWriteHTML($oIE, $sHTML)

$oIE = _IECreateEmbedded()
GUICreate("Embedded Web control Test", 640, 580, _
        (@DesktopWidth - 640) / 2, (@DesktopHeight - 580) / 2, _
        $WS_OVERLAPPEDWINDOW + $WS_CLIPSIBLINGS + $WS_CLIPCHILDREN)
GUICtrlCreateObj($oIE, 10, 40, 600, 360)
GUISetState(@SW_SHOW) ;Show GUI

;~ _IENavigate($oIE, "http://google.com")

_IEDocWriteHTML($oIE, $sHTML)
_IEAction($oIE, "refresh")

; Waiting for user to close the window
While 1
    Local $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
    EndSelect
WEnd

GUIDelete()

But it puts errors in console:

 

--> IE.au3 T3.0-1 Error from function _IELoadWait, $_IEStatus_InvalidDataType

--> IE.au3 T3.0-1 Error from function _IEAction(refresh), $_IEStatus_COMError (4)

 

unless I uncomment:

_IENavigate($oIE, "http://google.com")

Why this not working properly without initial _IENavigate(... ?

[mLipok]

hmm.....

HelpFile is my friend:

 

You must therefore use _IENavigate() to navigate this browser to 'about:blank' after it has been embedded into the parent application and before you attempt any operations that rely on having a document loaded (e.g. _IEBodyWriteHTML()
 ).