Extract date from string by using StringRegExpReplace

[lsakizada]

Hi,

I need help with regexp to extract the date from a file name, because I do not much about regexp  .

The file name has the following naming template:

VIAS1_2015_02_15_part_02.log

The file name can be any like this (where XX and YY can be changed):

VIASXX_2015_02_15_part_YY.log

I needs the following values to be extracted:

$Year=2015
$Month = 02
$Day = 15

Best Regards,

[kylomas]

one way...

#include <array.au3>

local $str = 'VIAS1_2015_02_15_12_02.log'

local $a10 = stringregexp($str,'_(\d+)_(\d+)_(\d+)',3)

_arraydisplay($a10)

local $year = $a10[0]
local $mnth = $a10[1]
local $day  = $a10[2]

ConsoleWrite(stringformat('%4s/%2s/%2s',$year,$mnth,$day) & @CRLF)

[kylomas]

another way...

local $str = '123_2015_02_15_12_02.log'

local $year = stringregexpreplace($str,'.*_(\d{4})_\d?\d_\d?\d+.*','$1')
local $mnth = stringregexpreplace($str,'.*_\d{4}_(\d?\d)_\d?\d+.*','$1')
local $day = stringregexpreplace($str,'.*_\d{4}_\d?\d_(\d?\d+).*','$1')

ConsoleWrite(stringformat('%4s/%2s/%2s',$year,$mnth,$day) & @CRLF)

[SadBunny]

If you do it like this:

local $str = '123_2015_02_15_12_02.log'
local $date = stringregexpreplace($str,'.*_(\d{4})_(\d?\d)_(\d?\d+)_(\d?\d+)_(\d?\d+).*','$1/$2/$3 $4:$5')

... you get a date and time you can parse through Date.au3's _DateTimeFormat.

[lsakizada]

Hi

SadBunny and kylomas

 

Thanks, I will check it later and let you know which one is appropriate.

best regards

[mikell]

Tss Tss

Don't forget the basics 

$str = "VIASXX_2015_02_15_part_YY.log"

$s = StringSplit($str, "_")
Msgbox(0,"", $s[2] & "/" & $s[3] & "/" & $s[4])

[lsakizada]

Hi Mikell,

That's exactly what I have done , but because I have many calls during single call I thought it will be faster to use regex

correction:

$s = StringSplit($StrFN, "_")
Msgbox(0,"", $s[3] & "/" & $s[4] & "/" & $s[5])

Regards

Edited February 22, 2015 by lsakizada

[mikell]

Then a strict replace is the best

Local $str = 'something_123_2015_02_15_12_else_02.log'

Msgbox(0,"", stringregexpreplace($str, '.*(\d{4})_(\d{2})_(\d{2}).*', "$1/$2/$3") )

[kylomas]

It looks like the OP wants date parts seperated, hence my solutions...

[mikell]

Oh you are right

A fragmented solution like the one in your post #3 then

Local $str = 'something_123_2015_02_15_12_else_02.log'

Msgbox(0,"year", stringregexpreplace($str, '.*(\d{4})_\d{2}_\d{2}.*', "$1") )
Msgbox(0,"month", stringregexpreplace($str, '.*\d{4}_(\d{2})_\d{2}.*', "$1") )
Msgbox(0,"day", stringregexpreplace($str, '.*\d{4}_\d{2}_(\d{2}).*', "$1") )

[SmOke_N]

#8 + StringSplit would probably be faster

But then again, if StringSplit was working, then it's going to be much faster than regex calls.