Using a stop button to interrupt a function

[InunoTaishou]

I've been racking my brain around this one all morning. Trying to make a script stop if a button is pressed. I don't want to use a hotkey because I'm trying to keep this completely GUI based.

 

Thought about some AdLibRegister but I don't think it would work properly.

Tried doing a GUIGetMsg in the start loop with a flag but it doesn't read the GUIGetMsg. Thought it was because it was in the onevent function so I moved it to a loop function, but no go.

Func main()
   $hGui = GUICreate("Test", 105, 40)
   GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")

   $btnStart = GUICtrlCreateButton("Start", 10, 10, 40, 20)
   GUICtrlSetOnEvent(-1, "start")

   $btnStop = GUICtrlCreateButton("Stop", 55, 10, 40, 20)
   GUICtrlSetOnEvent(-1, "stop")

   GUISetState(@SW_SHOW)

   While 1
      Sleep(250)
   WEnd
EndFunc

Func start()
   Msgbox("", "", "Started")
   $startFlag = True
   loop()
   Return
EndFunc

Func loop()
   while $startFlag
      if GUIGetMsg() = $btnStop then stop()
      Sleep(250)
   WEnd
EndFunc

Func stop()
   MsgBox("","","Stopped")
   $startFlag = False
   Return
EndFunc

Is there any way to make it stop doing the function that was called using a button?

[BrewManNH]

https://www.autoitscript.com/wiki/Interrupting_a_running_function

[Melba23]

InunoTaishou,

The Interrupting a running function tutorial in the Wiki should give you the answer.

M23

[TheSaint]

Another method, that is handy if you want to have your program minimized etc, is a floating STOP button (separate EXE), that can write to a Registry or INI file entry, that your program regularly checks.

[InunoTaishou]

InunoTaishou,

The Interrupting a running function tutorial in the Wiki should give you the answer.

M23

 

I read that thing 2-3 times last night and this morning, couldn't figure it out... Posted this topic, played some Dying Light, came back to the topic and saw that. Read it again and finally figured it out.

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>

AutoitSetOption("GuiOnEventMode", 1)

Global $hGui, $btnStart, $btnStop, $startFlag

main()

Func main()
   $hGui = GUICreate("Test", 105, 40)
   GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")

   $btnStart = GUICtrlCreateButton("Start", 10, 10, 40, 20)
   GUICtrlSetOnEvent(-1, "start")

   $btnStop = GUICtrlCreateButton("Stop", 55, 10, 40, 20)
   GUICtrlSetOnEvent(-1, "stop")

   $dmyInterrupt = GUICtrlCreateDummy()
   GUICtrlSetOnEvent($dmyInterrupt, "interrupt")
   GUIRegisterMsg($WM_COMMAND, "interrupt")

   GUISetState(@SW_SHOW)

   While 1
      Sleep(250)
   WEnd
EndFunc

Func start()
   $startFlag = True

   ToolTip("start()", 0, 0)

   while $startFlag
      Sleep(250)
   WEnd

   Return
EndFunc

Func stop()
   ToolTip("stop()", 0, 0)
   sleep(500)
   ToolTip("")

   $startFlag = False

   Return
EndFunc

 Func interrupt($hWnd, $Msg, $wParam, $lParam)
     If BitAND($wParam, 0x0000FFFF) =  $btnStop Then $startFlag = False
     Return $GUI_RUNDEFMSG
 EndFunc

Func _exit()
   Exit
EndFunc