Create array from GUICtrlCreateEdit data

[iamthetboz]

I'm trying to find a way to easily create an array from user input through a GUI edit box.  The user would copy a range of cells from an excel file into the edit box.

Any ideas???

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

#include <EditConstants.au3>

 

Local $edit, $msg

 

GUICreate("Get excel data") ; will create a dialog box that when displayed is centered

 

$edit = GUICtrlCreateEdit("", 75, 25, 300, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)

Local $idButton1 = GUICtrlCreateButton("OK", 5, 25, 50, 30)

GUISetState()

 

GUICtrlSetData($edit,"")

 

; Run the GUI until the dialog is closed

While 1

    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then

  Exit

    ElseIf $msg = $idButton1 Then

  ConsoleWrite("What did i get? " & @CR & GUICtrlRead($edit) & @CR)

  ExitLoop

    EndIf

WEnd

 

_ArrayDisplay($edit)

Edited February 25, 2015 by iamthetboz

[mLipok]

Please use code tags when you post your code (this small A button )

EDIT:

and use TIDY before you post your code.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

Local $edit, $msg

GUICreate("Get excel data") ; will create a dialog box that when displayed is centered

$edit = GUICtrlCreateEdit("", 75, 25, 300, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
Local $idButton1 = GUICtrlCreateButton("OK", 5, 25, 50, 30)
GUISetState()

GUICtrlSetData($edit, "")

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
        Exit
    ElseIf $msg = $idButton1 Then
        ConsoleWrite("What did i get? " & @CR & GUICtrlRead($edit) & @CR)
        ExitLoop
    EndIf
WEnd

_ArrayDisplay($edit)

Edited February 25, 2015 by mlipok

[mLipok]

Here you have working example with hints:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <array.au3>
#include "CSVSplit.au3"

Local $edit, $msg

GUICreate("Get excel data") ; will create a dialog box that when displayed is centered

$edit = GUICtrlCreateEdit("", 75, 25, 300, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
Local $idButton1 = GUICtrlCreateButton("OK", 5, 25, 50, 30)
GUISetState()

GUICtrlSetData($edit, "")

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
        Exit
    ElseIf $msg = $idButton1 Then

        ; GUICtrlRead($edit) Return the text
        ; you need to put it to Variable
        $sText = GUICtrlRead($edit)

        ; and now you can use this variable
        ConsoleWrite("What did i get? " & @CR & $sText & @CR)

        ExitLoop
    EndIf
WEnd
; so now you can split this text to Array variable
;~  http://www.autoitscript.com/forum/topic/155748-csvsplit
$aTable = _CSVSplit($sText, @TAB)

; and show what you get

; btw you forget to use #include <array.au3> - I do not
_ArrayDisplay($aTable)

[iamthetboz]

Sorry mlipok about the code tag... I was trying to figure out how to post it like that but I gave up to time!  Also what is "TIDY" referencing?

This works perfect mlipok!  Thank you very much!

I added in the two functions that were needed by copying functions _CSVSplit and __GetSubstitute off of the link '?do=embed' frameborder='0' data-embedContent>>

Thanks to czardas as well!

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <Array.au3> ;only for _ArrayDisplay()

Local $edit, $msg

GUICreate("Get excel data") ; will create a dialog box that when displayed is centered

$edit = GUICtrlCreateEdit("", 75, 25, 300, 200, $ES_AUTOVSCROLL + $WS_VSCROLL)
Local $idButton1 = GUICtrlCreateButton("Go", 5, 25, 50, 30)
GUISetState()

GUICtrlSetData($edit,"")

; Run the GUI until the dialog is closed
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then
       Exit
    ElseIf $msg = $idButton1 Then
       ConsoleWrite("What did i get? " & @CR & GUICtrlRead($edit) & @CR)
       $sText = GUICtrlRead($edit)
       ExitLoop
    EndIf
WEnd

$aTable = _CSVSplit($sText, @TAB)
_ArrayDisplay($aTable)



; #FUNCTION# ====================================================================================================================
; Name...........: _CSVSplit
; Description ...: Converts a string in CSV format to a two dimensional array (see comments)
; Syntax.........: CSVSplit ( $aArray [, $sDelim ] )
; Parameters ....: $aArray  - The array to convert
;                  $sDelim  - Optional - Delimiter set to comma by default (see 2nd comment)
; Return values .: Success  - Returns a two dimensional array or a one dimensional array (see 1st comment)
;                  Failure  - Sets @error to:
;                 |@error = 1 - First parameter is not a valid string
;                 |@error = 2 - Second parameter is not a valid string
;                 |@error = 3 - Could not find suitable delimiter replacements
; Author ........: czardas
; Comments ......; Returns a one dimensional array if the input string does not contain the delimiter string
;                ; Some CSV formats use semicolon as a delimiter instead of a comma
;                ; Set the second parameter to @TAB To convert to TSV
; ===============================================================================================================================

Func _CSVSplit($string, $sDelim = ",") ; Parses csv string input and returns a one or two dimensional array
    If Not IsString($string) Or $string = "" Then Return SetError(1, 0, 0) ; Invalid string
    If Not IsString($sDelim) Or $sDelim = "" Then Return SetError(2, 0, 0) ; Invalid string

    $string = StringRegExpReplace($string, "[\r\n]+\z", "") ; [Line Added] Remove training breaks
    Local $iOverride = 63743, $asDelim[3] ; $asDelim => replacements for comma, new line and double quote
    For $i = 0 To 2
        $asDelim[$i] = __GetSubstitute($string, $iOverride) ; Choose a suitable substitution character
        If @error Then Return SetError(3, 0, 0) ; String contains too many unsuitable characters
    Next
    $iOverride = 0

    Local $aArray = StringRegExp($string, '\A[^"]+|("+[^"]+)|"+\z', 3) ; Split string using double quotes delim - largest match
    $string = ""

    Local $iBound = UBound($aArray)
    For $i = 0 To $iBound -1
        $iOverride += StringInStr($aArray[$i], '"', 0, -1) ; Increment by the number of adjacent double quotes per element
        If Mod ($iOverride +2, 2) = 0 Then ; Acts as an on/off switch
            $aArray[$i] = StringReplace($aArray[$i], $sDelim, $asDelim[0]) ; Replace comma delimeters
            $aArray[$i] = StringRegExpReplace($aArray[$i], "(\r\n)|[\r\n]", $asDelim[1]) ; Replace new line delimeters
        EndIf
        $aArray[$i] = StringReplace($aArray[$i], '""', $asDelim[2]) ; Replace double quote pairs
        $aArray[$i] = StringReplace($aArray[$i], '"', '') ; Delete enclosing double quotes - not paired
        $aArray[$i] = StringReplace($aArray[$i], $asDelim[2], '"') ; Reintroduce double quote pairs as single characters
        $string &= $aArray[$i] ; Rebuild the string, which includes two different delimiters
    Next
    $iOverride = 0

    $aArray = StringSplit($string, $asDelim[1], 2) ; Split to get rows
    $iBound = UBound($aArray)
    Local $aCSV[$iBound][2], $aTemp
    For $i = 0 To $iBound -1
        $aTemp = StringSplit($aArray[$i], $asDelim[0]) ; Split to get row items
        If Not @error Then
            If $aTemp[0] > $iOverride Then
                $iOverride = $aTemp[0]
                ReDim $aCSV[$iBound][$iOverride] ; Add columns to accomodate more items
            EndIf
        EndIf
        For $j = 1 To $aTemp[0]
            If StringLen($aTemp[$j]) Then
                If Not StringRegExp($aTemp[$j], '[^"]') Then ; Field only contains double quotes
                    $aTemp[$j] = StringTrimLeft($aTemp[$j], 1) ; Delete enclosing double quote single char
                EndIf
                $aCSV[$i][$j -1] = $aTemp[$j] ; Populate each row
            EndIf
        Next
    Next

    If $iOverride > 1 Then
        Return $aCSV ; Multiple Columns
    Else
        For $i = 0 To $iBound -1
            If StringLen($aArray[$i]) And (Not StringRegExp($aArray[$i], '[^"]')) Then ; Only contains double quotes
                $aArray[$i] = StringTrimLeft($aArray[$i], 1) ; Delete enclosing double quote single char
            EndIf
        Next
        Return $aArray ; Single column
    EndIf
 EndFunc ;==> _CSVSplit



 ; #INTERNAL_USE_ONLY# ===========================================================================================================
; Name...........: __GetSubstitute
; Description ...: Searches for a character to be used for substitution, ie one not contained within the input string
; Syntax.........: __GetSubstitute($string, ByRef $iCountdown)
; Parameters ....: $string   - The string of characters to avoid
;                  $iCountdown - The first code point to begin checking
; Return values .: Success   - Returns a suitable substitution character not found within the first parameter
;                  Failure   - Sets @error to 1 => No substitution character available
; Author ........: czardas
; Comments ......; This function is connected to the function _CSVSplit and was not intended for general use
;                  $iCountdown is returned ByRef to avoid selecting the same character on subsequent calls to this function
;                  Initially $iCountown should be passed with a value = 63743
; ===============================================================================================================================

Func __GetSubstitute($string, ByRef $iCountdown)
    If $iCountdown < 57344 Then Return SetError(1, 0, "") ; Out of options
    Local $sTestChar
    For $i = $iCountdown To 57344 Step -1
        $sTestChar = ChrW($i)
        $iCountdown -= 1
        If Not StringInStr($string, $sTestChar) Then
            Return $sTestChar
        EndIf
    Next
    Return SetError(1, 0, "") ; Out of options
EndFunc ;==> __GetSubstitute

[mLipok]

I'm glad I could help.