Regular express to array

[lsakizada]

Hi,

Anyone please help me getting some data from text line into an array by using regexp?

I have a line that looks like:

11:05:40.839855 T2708 DBG Feat stats, sensor 78: BG, p=2000: c=10: 100%.

I need a one dimension array that has that elements values:

$aArray[0] = 6

$aArray[1] = '11:05:40.839855'

$aArray[2] = '78'

$aArray[3] = 'BG'

$aArray[4] = '2000'

$aArray[5] = '10'

$aArray[6] = '100'

[libreau3]

You could do something like this

#include <Array.au3>
$str = '11:05:40.839855 T2708 DBG Feat stats, sensor 78: BG, p=2000: c=10: 100%.'
$array = StringSplit($str," ", 2)

Then the remove the unnecessary characters individually and remove the extra elements with _ArrayDelete(). 

Edited March 12, 2015 by libreau3

[lsakizada]

You could do something like this

#include <Array.au3>
$str = '11:05:40.839855 T2708 DBG Feat stats, sensor 78: BG, p=2000: c=10: 100%." 
$array = StringSplit($str," ", 2)

Then the remove the unnecessary characters individually and remove the extra elements with _ArrayDelete(). 

 

Thanks for the reply,

Indeed that's how I did, but the performance of parsing thousands of lines with that method took very long time.

I must use regexp to reduce the time.

For $i = 1 To $aData[0]
            If StringInStr($aData[$i], "Feat stats, sensor ") <> 0 Then
                $aSplit = StringSplit($aData[$i], " ")
                ;_ArrayDisplay($aSplit)
                If $aSplit[0] = 12 Then
                    $aFeatureHolder[0][0] = $aFeatureHolder[0][0] + 1
                    ReDim $aFeatureHolder[UBound($aFeatureHolder) + 1][11]
                    ;_ArrayDisplay($aFeatureHolder,"11")
                    $aSplit1 = StringSplit($aSplit[2], ".")
                    ;_ArrayDisplay($aSplit1,"$aSplit1")
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][0] = $aSplit[2] ; raw time
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][1] = StringTrimRight($aSplit[8], 1) ; sensor id
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][2] = StringTrimRight($aSplit[9], 1) ; feat type. e.g. MC, Fg, BG..
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][3] = StringTrimLeft(StringTrimRight(StringStripWS($aSplit[10], 8), 1), 2) ; feat sub type. e.g. p=333, p=332, p=100, etc
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][4] = StringTrimRight(StringStripWS($aSplit[12], 8), 2); performance value
                    $aFeatureHolder[UBound($aFeatureHolder) - 1][5] = $sFN & " " & $aSplit1[1] ; full date/time without miliseconds
                EndIf
                ;   10:41:59.256697 T33252 DBG Feat stats, sensor 85: FG, p=100: c=191: 95%.
            EndIf
        Next

[jchd]

Try this:

#include <Array.au3>

Local $str = " 11:05:40.839855 T2708 DBG Feat stats, sensor 78: BG, p=2000: c=10: 100%."
Local $res = StringRegExp($str, "(?i)(\d+:\d+:\d+\.\d+).*?sensor\s+(\d+):\s+([^,]+),\s+p=(\d+):\s+c=(\d+):\s+(\d+)%", 1)
_ArrayDisplay($res)

[mikell]

If necessary you can use an empty group at the beginning of the pattern to 'reserve' the first row

Local $res = StringRegExp($str, "(?i)()(\d+:\d+:\d+\.\d+).... etc
$res[0] = 6

[Melba23]

mikell,

Useful tip that - thanks.

M23

[jguinch]

Great, Mikell ! (i recently used this to : )'>)

Edited March 12, 2015 by jguinch

[jchd]

Yes, I forgot to point that out. Anyway I question the usefullness of storing dimension in this case: the number of entries is fixed at 6 by design, so what purpose does it have to store this value?

And yes, volontary empty captures can help shifting the resulting array entries when it's actually useful. Not here, because 6 = 6.

Edited March 12, 2015 by jchd

[lsakizada]

 

Try this:

#include <Array.au3>

Local $str = " 11:05:40.839855 T2708 DBG Feat stats, sensor 78: BG, p=2000: c=10: 100%."
Local $res = StringRegExp($str, "(?i)(\d+:\d+:\d+\.\d+).*?sensor\s+(\d+):\s+([^,]+),\s+p=(\d+):\s+c=(\d+):\s+(\d+)%", 1)
_ArrayDisplay($res)

 

Hi JCHD,

That's working very well in my procedure.

Now I will go and test it how faster it will be.

BTW: I am using some of your other code that was posted on the forums. Thanks for all and have a good one !!!

[lsakizada]

 

If necessary you can use an empty group at the beginning of the pattern to 'reserve' the first row

Local $res = StringRegExp($str, "(?i)()(\d+:\d+:\d+\.\d+).... etc
$res[0] = 6

Thanks mikell, I will have that in the pattern too!