How to get nth line text from a given text with Regexp

[kcvinu]

Hi all,

How to get nth line text from a given text with Regexp. For example, i have a text from a window which contains 15 lines.

And i need to get the text from 5th line (it may vary). How to do it. I have tried some patters like "(^ &)5" and "[^ $]{5}". But didn't work.

[Realm]

Does it have to be RegExp?

I'd personally use _FileReadToArray(), and then use RegExp to extract the needed data from the line I need.

[guinness]

I agree with Realm, regular expressions are generally for pattern matching, so it would be far simpler not to use a regular expression for this.

[kcvinu]

Actually, this text is from an edit control. And i need to process as fast as possible. My first method was to split the string and put it in an array and get my desired line with line number. In that case, i need to verify that there is no error while putting it to array and gettng from array. My assumption is that fileread and write are slower than array functions. Correct me if i am wrong.

[guinness]

Test it and don't make assumptions.

[SadBunny]

Are you sure the text consists of lines? Meaning, does it actually contain @CR and/or @LF characters? If so, then this should work:

$text = "hello1" & @CRLF & "hello2" & @CRLF & "hello3" & @CRLF & "hello4" & @CRLF & "hello5"
$array_of_lines = StringRegExp($text, "(?m)^.*$", 3)
MsgBox(0, 0, "Third line: " & $array_of_lines[2])

(Note that the third line is array element 2, as the array result of that StringRegExp call is 0-based.)

Of course, if speed is paramount you should benchmark all possible approaches.

[kcvinu]

Hi 

SadBunny, Thanks . Let me try this .

[kcvinu]

@

SadBunny, It's working. What i understood from that regular expression is;

1. " ^.*$  "

^ = start point of the line

.* = any text can come after start point

$ = end point point of the line. 

Thant means this regex will catch a complete line.

But i don't know what is meant by (?m) 

[kcvinu]

@

SadBunny, Instead of making an array, does regexp can catch the exact line text only. ?

[mpower]

It's possible without making an array of all the lines:

$text = "this is some text on line 1" & @CRLF & "text on line 2" & @CRLF & "another line of text (line 3)" & @CRLF & "line 4" & @CRLF & "this is the final line (5)"

For $linenum = 1 to 5
    $pattern = "^(?:[^\n]*\n){" & $linenum - 1 & "}([^\n]*)"
    $test = StringRegExp($text, $pattern, 1)
    ConsoleWrite('Text on line ' & $linenum & ' is: "' & StringStripCR($test[0]) & '"' & @CRLF)
Next

[kcvinu]

@mpower, If we know the line number (say 4) then do we need a loop ?

[jchd]

Of course no:

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & "line 4" & @LF & "this is the final line (5)"
Local $sLine4 = StringRegExpReplace($sText, "(?m)((?:.*\R){3})(.*)(?s)(.*)", "$2")
ConsoleWrite($sLine4 & @LF)

Just make sure that the line number is < 65535 else you need something slightly more complex.

Also, using R copes with line breaks being CR or LF or CRLF as shwon here.

Edited March 16, 2015 by jchd

[mpower]

Obviously not....it was just an example. You don't need a loop I was just showing that I can get any number line.

$text = "this is some text on line 1" & @CRLF & "text on line 2" & @CRLF & "another line of text (line 3)" & @CRLF & "line 4" & @CRLF & "this is the final line (5)"
$linenum = 4
$pattern = "^(?:[^\n]*\n){" & $linenum - 1 & "}([^\n]*)"
$test = StringRegExp($text, $pattern, 1)
ConsoleWrite('Text on line ' & $linenum & ' is: "' & StringStripCR($test[0]) & '"' & @CRLF)

EDIT: jchd beat me to it by milliseconds

Edited March 16, 2015 by mpower

[kcvinu]

@jchd Thanks a lot.

@mpower thanks a lot. 

Let me try these ideas.

[mikell]

Because of the dot default feature "doesn't match newline"  jchd's expression can be done a bit simpler

StringRegExpReplace($sText, "(?:.*\R){3}(.*)(?s).*", "$1")

[kcvinu]

@

mikell, you mean, this regexp will delete all other lines from a text and give the  text from nth line ?

[mikell]

Yes that is what this kind of StringRegExpReplace does, replace the whole string by something - in this case the backreference is used

[kcvinu]

@

mikell, But yoour code is giving an empty string. 

[mikell]

I used jchd's example to test it

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
msgbox(0,"", $sText)
Local $sLine4 = StringRegExpReplace($sText, "(?:.*\R){3}(.*)(?s).*", "$1")
msgbox(0,"", $sLine4)

But if the 4th line is empty it will return nothing

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"
msgbox(0,"", $sText)
Local $sLine4 = StringRegExpReplace($sText, "(?:.*\R){3}(.*)(?s).*", "$1")
msgbox(0,"", $sLine4)

[iamtheky]

Local $sText = "this is some text on line 1" & @CRLF & "text on line 2" & @LF & "another line of text (line 3)" & @CRLF & "this is line 4" & @LF & "this is the line (5)" & @CRLF & "text on line 6"


$line = 4


msgbox(0, '' , stringsplit($sText , @LF)[$line])

Edited March 16, 2015 by boththose