Loop, FilePattern (Transitioning from AutoHotkey)

[Imbecility]

Hello, I am transitioning from AutoHotkey to AutoIt and am looking for a nudge in the right direction with regard to looping through files and folders.  What I would like to do is create a delimited list of certain attributes (filename, path, extension, size, last modified) about all files in network drives.  In AutoHotkey I can use "Loop, FilePattern" to go through every file and folder and pull all the information I need.  How can I go about doing this efficiently in AutoIt?

From what I've learned so far, it appears I'll need to use "FileListToArray" to create an array of filepaths, then loop through the entire array, using "FileGet . . ." for each element.  Is there a better way or am I on the right track?

Please be kind as this is my first post.   Thank you!

[water]

Welcome to AutoIt and the forum!

I would start with _FileListToArrayRec to recursively list files and/or folders. Then use FileGetAttrib to retrieve the attributes.

[Imbecility]

Thank you water.  My intent is to make a database of all network files, with "Filename", "Extension", "Filepath", "Mod. Date", and "Size (kb)" headings.  My code for doing just my desktop is below, but I'm a bit disappointed in how much time it takes to complete (~25 seconds).  FYI, I have 5,208 files on my desktop and in subfolders.  Is there anything I can do/change to make it run more quickly?

#include <Array.au3>
#include <File.au3>

$aFileList = _FileListToArrayRec(@DesktopDir,"*",0,1,0,2)
Local $aDBList[0][5]
Local $sDrive = "", $sDir = "", $sFilename = "", $sExtension = ""
_ArrayAdd($aDBList,$aFileList[0])
For $nCt = 1 To $aFileList[0]
   $sFileSize = Ceiling(FileGetSize($aFileList[$nCt])/1024)
   $sFileModDate = FileGetTime($aFileList[$nCt],0,1)
   _PathSplit($aFileList[$nCt], $sDrive, $sDir, $sFilename, $sExtension)
   $sDBListRow = $sFilename & $sExtension & "|" & $sExtension & "|" & $sDrive & $sDir & "|" & $sFileModDate & "|" & $sFileSize
   _ArrayAdd($aDBList,$sDBListRow)
Next
_ArrayDisplay($aDBList)

The output doesn't necessarily need to be an array; a delimited text file would suffice as well.

Thank you!

[mikell]

This is a bit faster

#include <Array.au3>
#include <File.au3>

$aFileList = _FileListToArrayRec(@DesktopDir,"*",0,1,0,2)
Local $aDBList[100000][5]
Local $sDrive = "", $sDir = "", $sFilename = "", $sExtension = ""
$aDBList[0][0] = $aFileList[0]
For $nCt = 1 To $aFileList[0]
   $sFileSize = Ceiling(FileGetSize($aFileList[$nCt])/1024)
   $sFileModDate = FileGetTime($aFileList[$nCt],0,1)
   _PathSplit($aFileList[$nCt], $sDrive, $sDir, $sFilename, $sExtension)
   $aDBList[$nCt][0] = $sFilename & $sExtension
   $aDBList[$nCt][1] = $sExtension
   $aDBList[$nCt][2] = $sDrive & $sDir
   $aDBList[$nCt][3] = $sFileModDate
   $aDBList[$nCt][4] = $sFileSize
Next
Redim $aDBList[$nCt][5]
_ArrayDisplay($aDBList)

[Imbecility]

 

This is a bit faster

 

Wow, that is much faster (~2 sec. compared to ~25 sec).  Thank you very kindly!

[mikell]

You're welcome 

FYI the _Array* funcs are slow and should be avoided in case of large number of entries

e.g.  _ArrayAdd() does StringSplit and Redim at each pass, while the code above Redims only once  

[Melba23]

Imbecility,

The Recursion tutorial in the Wiki shows in the final example how best to fill an array whose final size is not known. Basically you keep doubling it in size when you fill it.

M23

[mikell]

Redimming only once is still better 

[Melba23]

mikell,

If you initially create the array with an enormous number of elements that may well be possible, but then you could run into memory problems if it was truly gigantic and you had a lot of other data to store. Personally I prefer a reasonable initial size followed by doubling when necessary.

M23

[jguinch]

@mikell : I don't understand why you did not use Local $aDBList[$aFileList[0]][5] ???

[mikell]

Should be Local $aDBList[$aFileList[0]+1][5]  but of course you are right

This is a too-quickly-done-script  oversight 

Edit

Funny, nobody but you saw this

Edited March 26, 2015 by mikell

[Imbecility]

Should be Local $aDBList[$aFileList[0]+1][5]  but of course you are right

This is a too-quickly-done-script  oversight 

Edit

Funny, nobody but you saw this

I had actually already editted my code to be like this, as my next test was my entire C-drive and the 100,000 amount wasn't high enough.

I am extremely pleased with the results!  I had been using Autohotkey (an still am until I convert the code over) to create local and network databases.  It took ~1h:20m to process just under 200,000 files in Autohotkey, but just under 30s for just over 200,000 files in AutoIt - that's 160x faster... I'm sure my Autohotkey code could have been optimized for efficiency, but it appears there will be no need to pursue that!

Needless to say, I'm now a believer!

[jguinch]

@Imbecility : with Melba's suggestion in #7, you could make your own function, faster (2 times faster, if it is not more)