FileOpenDialog and SQLite Error

[lNoVal]

Hi Guys,

first of all i wanna thank you for this greate forum. I am a autoit newbie and leaned allready a lot (i belive) by reading this forum.

Now i got to a strange problem. 

If i open a FileOpenDialoge befor using my sqlite connection. SQL will not find the DB table. (See first script)

But if i comment the FileDialog it works fine and i get the result of my DB Table.

Where is the mistake?

Thx for your help.

#include <Array.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>
local $sMessage
local $sFileOpenDialog = FileOpenDialog($sMessage, @WindowsDir & "\" , "All (*.*)")

global $sSQliteDll = _SQLite_Startup("SQLite3.dll")
If @error Then
MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite3.dll Can't be Loaded!" & @CRLF & @CRLF & _
"Not FOUND in @SystemDir, @WindowsDir, @ScriptDir, @WorkingDir or from www.autoitscript.com")
Exit -1
 EndIf

local $DB_Main_MainDB = _SQLite_Open("Main_DB.db3")
Local $hQuery,$aRow
local $sql = "SELECT * FROM testscript"
 _SQLite_Query($DB_Main_MainDB, $sql,$hQuery)

dim $test
While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK
    $test = $arow[0]
wEnd
msgbox (0,0,$test)

#include <Array.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>
local $sMessage
;--------------------------------------------------------------------------------------------
;local $sFileOpenDialog = FileOpenDialog($sMessage, @WindowsDir & "\" , "All (*.*)")
;-----------------------------------------------------------------------------------------
global $sSQliteDll = _SQLite_Startup("SQLite3.dll")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite3.dll Can't be Loaded!" & @CRLF & @CRLF & _
            "Not FOUND in @SystemDir, @WindowsDir, @ScriptDir, @WorkingDir or from www.autoitscript.com")
    Exit -1
 EndIf

local $DB_Main_MainDB = _SQLite_Open("Main_DB.db3")
Local $hQuery,$aRow
local $sql = "SELECT * FROM testscript"
 _SQLite_Query($DB_Main_MainDB, $sql,$hQuery)

dim $test
While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK
    $test = $arow[0]
wEnd
msgbox (0,0,$test)

Edited April 2, 2015 by lNoVal

[Melba23]

lNoVal,

A successful return from FileOpenDialog resets the @WorkingDir to the path of the returned file. I imagine that the _SQLite_Open cannot then find the database file as it is looking in the wrong place. >

Try passing the full path, or reset the path with FileChangeDir.

M23

Edit: And welcome to the AutoIt forums.

Edited April 2, 2015 by Melba23

[lNoVal]

Melba23 your the best

Here is the working code if someone has the same Problem..

#include <Array.au3>
#include <SQLite.au3>
#include <SQLite.dll.au3>


Global $glb_MAIN_DBname = @WorkingDir&"\Main_DB.db3"
local $sMessage
local $sFileOpenDialog = FileOpenDialog($sMessage, @WindowsDir & "\" , "All (*.*)")


 FileChangeDir(@WorkingDir)
global $sSQliteDll = _SQLite_Startup("SQLite3.dll")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite3.dll Can't be Loaded!" & @CRLF & @CRLF & _
            "Not FOUND in @SystemDir, @WindowsDir, @ScriptDir, @WorkingDir or from www.autoitscript.com")
    Exit -1
 EndIf

;msgbox(0,0,$glb_MAIN_DBname)
local $DB_Main_MainDB = _SQLite_Open($glb_MAIN_DBname)

Local $hQuery,$aRow
local $sql = "SELECT * FROM amis_testcasescript"
 _SQLite_Query($DB_Main_MainDB, $sql,$hQuery)

dim $test
While _SQLite_FetchData($hQuery, $aRow) = $SQLITE_OK
    $test = $arow[0]
wEnd
msgbox (0,0,$test)

[Melba23]

lNoVal,

This line merely sets the @WorkingDir to its current content and so is completely superfluous: >

FileChangeDir(@WorkingDir)

What you need to do is something like this:

Local $sWorkingDir = @WorkingDir ; Save current WorkingDir in a variable
Global $glb_MAIN_DBname = $sWorkingDir & "\Main_DB.db3"
local $sMessage
local $sFileOpenDialog = FileOpenDialog($sMessage, @WindowsDir & "\" , "All (*.*)")
; WorkingDir will now be changed
FileChangeDir($sWorkingDir) ; So reset WorkingDir to the original saved path

All clear?

M23