Multiple listviews/tabs and Listview_CreateArray

[Jewtus]

I have been trying to make this GUI do some of the stuff I need but it is getting quickly more complicated and I'm not even sure how to proceed with debugging my next step.
 
I'm using >guinness's Listview_CreateArray script and it works like a charm in other places, but when I try to use it on my tabbed GUI, It just kicks back a few 0s.

Here is my code

expandcollapse popup

#include <GUITab.au3>
#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Array.au3>
#include <GUIListView.au3>


;Begin Main Gui
Global $Home = GUICreate("Welcome", 635, 477, 192, 114, $WS_MAXIMIZEBOX)

;Menus
$MenuFile = GUICtrlCreateMenu("File")
$Start = GUICtrlCreateMenuItem("Start", $MenuFile)
GUICtrlCreateMenuItem("", $MenuFile) ; Create a separator line
$ExitMenu = GUICtrlCreateMenuItem("Exit", $MenuFile)
GUISetState(@SW_SHOW)
WinSetState($Home, '', @SW_MAXIMIZE)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE, $ExitMenu
            Exit
        Case $Start
            Example()
    EndSwitch
WEnd

Func Example()
    $MainForm = GUICreate("Test", 925, 327, 192, 114, -1, $WS_EX_MDICHILD, $Home)
    $TypeLabel = GUICtrlCreateLabel("Search Type", 8, 8, 65, 17)
    $SearchInput = GUICtrlCreateCombo("", 16, 26, 257, 25)
    GUICtrlSetData(-1, "Name|ID")
    $InputValLabel = GUICtrlCreateLabel("Input Value", 8, 56, 58, 17)
    $InputVal = GUICtrlCreateInput("", 16, 80, 257, 21)
    $StartSearch = GUICtrlCreateButton("Search", 8, 284, 75, 25)
    $aLabel = GUICtrlCreateLabel("Date", 8, 112, 84, 17)
    $aInput = GUICtrlCreateDate("", 19, 132, 259, 21, (0x00))
    $aReportBox = GUICtrlCreateCheckbox("Generate report", 11, 168, 169, 17)
    GUICtrlSetState(-1, $GUI_HIDE)
    $MarkDead = GUICtrlCreateCheckbox("Mark Dead", 11, 192, 169, 17)
    GUICtrlSetState(-1, $GUI_HIDE)
    $UserOutput = GUICtrlCreateButton("Output", 188, 284, 75, 25)
    GUICtrlSetState($UserOutput, $GUI_HIDE)
    $bEnterDummy = GUICtrlCreateDummy()
    Local $bAccelKeys[1][2] = [["{ENTER}", $bEnterDummy]]
    GUISetAccelerators($bAccelKeys)

    GUICtrlCreateTabItem("")
    GUISetState(@SW_SHOW)

    While 1
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE, $ExitMenu
                GUIDelete($MainForm)
                ExitLoop
            Case $StartSearch, $bEnterDummy
                If GUICtrlRead($InputVal) = "" Then
                    MsgBox(0, "ERROR", "You must input a parameter")
                Else
                    SplashTextOn("Processing...", "Processing" & @CRLF & @CRLF & "Please wait", 200, 150, Default, Default, 1, Default, 25)
                    $type = GUICtrlRead($SearchInput)
                    $Parameter = GUICtrlRead($InputVal)
                    GUICtrlSetData($InputVal, "")
                    Local $IDs[2][2] = [["1", "A"], ["2", "B"]]
                    SplashOff()
                    If UBound($IDs) > 0 Then
                        SplashTextOn("Processing...", "Processing" & @CRLF & @CRLF & "Please wait", 200, 150, Default, Default, 1, Default, 25)
                        Local $ResultList[UBound($IDs)]
                        Local $Tab[UBound($IDs)]
                        $AcctResults = GUICreate("", 620, 344, 294, 0, $WS_CHILD, -1, $MainForm)
                        $Tabs = GUICtrlCreateTab(0, 10, 609, 300)
                        ;Loop for each Result
                        For $p = 0 To UBound($IDs) - 1
                            Local $Fullresult[3][7] = [[Random(1, 10), "Tester", "123456", GUICtrlRead($aInput), '', '', ''], ["Hello", "There", "My", "Fine", "Friend", "", ""], ["GoodBye", "There", "My", "Hated", "Enemy", "", ""]]
                            $Tab[$p] = GUICtrlCreateTabItem($Fullresult[0][0])
                            $ResultList[$p] = GUICtrlCreateListView("", 7, 128, 594, 174,$LVS_EDITLABELS)
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col0')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col1')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col2')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col3')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col4')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col5')
                                _GUICtrlListView_AddColumn($ResultList[$p], 'Col6')
                            Local $aWriter = $Fullresult
                            _ArrayDelete($aWriter, 0)
                            _GUICtrlListView_AddArray($ResultList[$p], $aWriter)
                            GUICtrlCreateTabItem("")
                        Next
                        Hide(1, $aLabel, $aInput, $UserOutput, $aReportBox, $MarkDead)
                        SplashOff()
                        GUISetState(@SW_SHOW)
                        While 2
                            ExitLoop
                        WEnd
                    EndIf
                EndIf
            Case $UserOutput
                If _GUICtrlTab_GetItemState($Tabs, 0) = 1 Then; First tab
                    $test = _GUICtrlListView_CreateArray($Tab[0])
                    _ArrayDisplay($test)
                EndIf
        EndSwitch
    WEnd
EndFunc   ;==>Example

Func Hide($toggle, $aLabel, $aInput, $UserOutput, $aReportBox, $MarkDead)
    GUICtrlSetState($aLabel, $toggle = 1 ? $GUI_SHOW : $GUI_HIDE)
    GUICtrlSetState($aInput, $toggle = 1 ? $GUI_SHOW : $GUI_HIDE)
    GUICtrlSetState($UserOutput, $toggle = 1 ? $GUI_SHOW : $GUI_HIDE)
    GUICtrlSetState($aReportBox, $toggle = 1 ? $GUI_SHOW : $GUI_HIDE)
    GUICtrlSetState($MarkDead, $toggle = 1 ? $GUI_SHOW : $GUI_HIDE)
EndFunc   ;==>Hide

; #FUNCTION# ====================================================================================================================
; Name ..........: _GUICtrlListView_CreateArray
; Description ...: Creates a 2-dimensional array from a listview.
; Syntax ........: _GUICtrlListView_CreateArray($hListView[, $sDelimeter = '|'])
; Parameters ....: $hListView           - Control ID/Handle to the control
;                  $sDelimeter          - [optional] One or more characters to use as delimiters (case sensitive). Default is '|'.
; Return values .: Success - The array returned is two-dimensional and is made up of the following:
;                                $aArray[0][0] = Number of rows
;                                $aArray[0][1] = Number of columns
;                                $aArray[0][2] = Delimited string of the column name(s) e.g. Column 1|Column 2|Column 3|Column nth

;                                $aArray[1][0] = 1st row, 1st column
;                                $aArray[1][1] = 1st row, 2nd column
;                                $aArray[1][2] = 1st row, 3rd column
;                                $aArray[n][0] = nth row, 1st column
;                                $aArray[n][1] = nth row, 2nd column
;                                $aArray[n][2] = nth row, 3rd column
; Author ........: guinness
; Remarks .......: GUICtrlListView.au3 should be included.
; Example .......: Yes
; ===============================================================================================================================
Func _GUICtrlListView_CreateArray($hListView, $sDelimeter = '|')
    Local $iColumnCount = _GUICtrlListView_GetColumnCount($hListView), $iDim = 0, $iItemCount = _GUICtrlListView_GetItemCount($hListView)
    If $iColumnCount < 3 Then
        $iDim = 3 - $iColumnCount
    EndIf
    If $sDelimeter = Default Then
        $sDelimeter = '|'
    EndIf

    Local $aColumns = 0, $aReturn[$iItemCount + 1][$iColumnCount + $iDim] = [[$iItemCount, $iColumnCount, '']]
    For $i = 0 To $iColumnCount - 1
        $aColumns = _GUICtrlListView_GetColumn($hListView, $i)
        $aReturn[0][2] &= $aColumns[5] & $sDelimeter
    Next
    $aReturn[0][2] = StringTrimRight($aReturn[0][2], StringLen($sDelimeter))

    For $i = 0 To $iItemCount - 1
        For $j = 0 To $iColumnCount - 1
            $aReturn[$i + 1][$j] = _GUICtrlListView_GetItemText($hListView, $i, $j)
        Next
    Next
    Return SetError(Number($aReturn[0][0] = 0), 0, $aReturn)
EndFunc   ;==>_GUICtrlListView_CreateArray

Anyone have suggestions on what I'm doing wrong? I tried to put in a If _GUICtrlTab_GetItemState($Tabs, 0) = 1 to make sure it was binding to the tabs and that I could control the index's, but I'm not sure where I'm going wrong.

[mLipok]

I'am not sure what you want to achieve.
 
but here are some question:
 
Why you use TabItem as a parameter to function 

$test = _GUICtrlListView_CreateArray($Tab[0])

when expected is:
 

; Parameters ....: $hListView           - Control ID/Handle to the control

 
Cheers.
mLipok
 
btw.
please read Best coding practices

[Jewtus]

That would be it... used the wrong param... I'll study the coding practices... I often cant figure out what to name variables so this will be helpful.