Jump to content

about dialog (modle)


Recommended Posts

Just use GUICreate parameters. in witch you can set a parent window and a style :

For example :

#Include <WindowsConstants.au3>

$hMain = GUICreate("My GUI")
$about = GUICtrlCreateButton("About", 10, 10, 150, 20)

GUISetState()

While 1
    $msg = GUIGetMsg()
    If $msg = -3 Then Exit
    
    If $msg = $about Then _About()
WEnd


Func _About()
    GUISetState(@SW_DISABLE, $hMain)

    Local $hAbout = GUICreate("About", 200, 200, -1, -1, $WS_SYSMENU, -1, $hMain )
    Local $iMsg
    GUISetState()
    While 1
        $iMsg = GUIGetMsg()
        If $iMsg = -3 Then ExitLoop
    WEnd
    GUISetState(@SW_ENABLE, $hMain)
    GUIDelete($hAbout)
EndFunc
Link to comment
Share on other sites

  • 1 month later...

thanks! Jguinch,Johnone

but the about dialog have a icon  and rightclick title bar  contextmenu are "restor","move","size","minimize","maximize","close"

I want there have no icon and  contextmenu only have "move" and "close" , not have above all  but the two is enable.

in a word, like   about  SciTe  dialog.

 

 

Link to comment
Share on other sites

  • Moderators

macran,

Something like this perhaps?

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GUIMenu.au3>

$hGUI = GUICreate("Test", 500, 500)

$mMenu = GUICtrlCreateMenu("File")
$mAbout = GUICtrlCreateMenuItem("About", $mMenu)
$mExit = GUICtrlCreateMenuItem("Exit", $mMenu)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExit

            Exit
        Case $mAbout

            _About()
    EndSwitch



WEnd



Func _About()

    ; Disable main GUI
    GUISetState(@SW_DISABLE, $hGUI)

    ; Create About GUI
    Local $hGUI_About = GUICreate("About", 280, 280, 0, 0, $WS_SYSMENU, $WS_EX_MDICHILD, $hGUI)

    ; Grey out unwanted system menu items
    _GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hGUI_About), $SC_MINIMIZE, $MF_GRAYED, False)
    _GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hGUI_About), $SC_MAXIMIZE, $MF_GRAYED, False)
    _GUICtrlMenu_EnableMenuItem(_GUICtrlMenu_GetSystemMenu($hGUI_About), $SC_SIZE, $MF_GRAYED, False)

    Local $cEdit = GUICtrlCreateEdit("", 10, 30, 260, 160)

    Local $cButton_Cancel = GUICtrlCreateButton("Cancel", 110, 200, 80, 30)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $cButton_Cancel
                ExitLoop

        EndSwitch

    WEnd



    GUISetState(@SW_ENABLE, $hGUI)
    GUIDelete($hGUI_About)
    WinActivate($hGUI)

EndFunc

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...