My problem with _FileWriteToLine

[galan2015]

Case $Combo4; Stany
            $ReadCombo = GUICtrlRead($Combo4)
            if $ReadCombo = "California" then
            $ReadFile = FileRead(@ScriptDir&'\Dzielnice\California.txt')
            GUICtrlSetData($Combo5,$ReadFile)
            _FileWriteToLine(@ScriptDir&'\cfg\ostatniedane.txt',1,'5')

I want overwrite the First line of file ostatniedane.txt but it's only adds another one :/ Anyone Could help me?

[Melba23]

galan2015,

Re-read the help file for _FileWriteToLine and pay particular attention to the $bOverWrite parameter.

M23

[galan2015]

Thank you!

 

[galan2015]

 

$Combo5 = GUICtrlCreateCombo("http://craigslist.org|http://reddit.com|http://google.com|http://gmail.com", 184, 98, 145, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))

Func ZapisywanieMiejscaProgramu()
            $1ReadCombo = GUICtrlRead($Combo5)
        If $1ReadCombo = 'http://craigslist.org' then
            _FileWriteToLine(@ScriptDir&'\cfg\ostatniedane.txt',2,'1',1)
            Msgbox(1,1,$1ReadCombo)
            ElseIf $combo5 = 'http://reddit.com' then
            _FileWriteToLine(@ScriptDir&'\cfg\ostatniedane.txt',2,'2',1)
            Msgbox(1,1,$Combo5)
            ElseIf $1ReadCombo = 'http://google.com' then
            _FileWriteToLine(@ScriptDir&'\cfg\ostatniedane.txt',2,'3',1)
EndIf
EndFunc

 

_FileWriteToLine works only for first example.

Edited May 6, 2015 by galan2015

[BrewManNH]

What error if any is returned by _FileWriteToLine when you use it and it doesn't work?

[galan2015]

What error if any is returned by _FileWriteToLine when you use it and it doesn't work?

​Nothing showing up. :S

[Melba23]

galan2015,

You have discovered a bug in _FileWriteToLine - when it was rewritten the check for an error in the $bOverWrite parameter was badly formatted and so it fails regardless of the setting. I will fix it for the next release but you can use this modified function in the meantime:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <ComboConstants.au3>
#include <File.au3>

$sFilePath = @ScriptDir & '\ostatniedane.txt'

; Simulate creation of the file
FileDelete($sFilePath)
FileWrite($sFilePath, "Fixed" & @CRLF & "Replaceable")
$sCheck = FileRead($sFilePath)
MsgBox($MB_SYSTEMMODAL, "Content", $sCheck)

$hGUI = GUICreate("Test", 500, 500)
$Combo5 = GUICtrlCreateCombo("", 184, 98, 145, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
GUICtrlSetData($Combo5, "http://craigslist.org|http://reddit.com|http://google.com|http://gmail.com")

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Combo5
            ZapisywanieMiejscaProgramu()
    EndSwitch



WEnd



Func ZapisywanieMiejscaProgramu()
    Switch GUICtrlRead($Combo5)
        Case 'http://craigslist.org'
            _FileWriteToLine_Mod($sFilePath, 2, '1', True)
        Case 'http://reddit.com'
            _FileWriteToLine_Mod($sFilePath, 2, '2', True)
        Case 'http://google.com'
            _FileWriteToLine_Mod($sFilePath, 2, '3', True)
    EndSwitch



    $sCheck = FileRead($sFilePath)
    MsgBox($MB_SYSTEMMODAL, "Content", $sCheck)

EndFunc   ;==>ZapisywanieMiejscaProgramu



Func _FileWriteToLine_Mod($sFilePath, $iLine, $sText, $bOverWrite = False)
    If $iLine <= 0 Then Return SetError(4, 0, 0)
    If Not IsString($sText) Then
        $sText = String($sText)
        If $sText = "" Then Return SetError(6, 0, 0)
    EndIf

    If $bOverWrite = Default Then $bOverWrite = False
    If Not (IsBool($bOverWrite) Or $bOverWrite = 0 Or $bOverWrite = 1) Then Return SetError(5, 0, 0) ; For old versions.
    If Not FileExists($sFilePath) Then Return SetError(2, 0, 0)

    Local $aArray = FileReadToArray($sFilePath)
    Local $iUBound = UBound($aArray) - 1
    If ($iUBound + 1) < $iLine Then Return SetError(1, 0, 0)

    Local $hFileOpen = FileOpen($sFilePath, FileGetEncoding($sFilePath) + $FO_OVERWRITE)
    If $hFileOpen = -1 Then Return SetError(3, 0, 0)

    Local $sData = ""
    $iLine -= 1 ; Now the array is 0-based, so reduce the line number by 1.
    For $i = 0 To $iUBound
        If $i = $iLine Then
            If $bOverWrite Then
                If $sText Then $sData &= $sText & @CRLF
            Else
                $sData &= $sText & @CRLF & $aArray[$i] & @CRLF
            EndIf
        ElseIf $i < $iUBound Then
            $sData &= $aArray[$i] & @CRLF
        ElseIf $i = $iUBound Then
            $sData &= $aArray[$i]
        EndIf
    Next

    FileWrite($hFileOpen, $sData)
    FileClose($hFileOpen)
    Return 1
EndFunc   ;==>_FileWriteToLine

That works for me.

M23

Edit: Fixed.

Edited May 6, 2015 by Melba23

[galan2015]

oh nice, thanks!