Excel _ExcelReadCell

[Happy82]

I am trying to read a specific cell value in Excel. In my Excel.au3 I don't have the function _ExcelReadCell. Is there any other way to read a specific cell or is there any download available for Excel.au3

Edited May 6, 2015 by Happy82

[BrewManNH]

Use _Excel_RangeRead instead. And please pick a smaller font.

[JLogan3o13]

Please tone down your font size, making my eyes bleed.

What version of AutoIt are you running? The current version would use _Excel_RangeWrite

[Happy82]

sure... i have reduced the font size..... I will use  _Excel_RangeRead. I using Autoit V3.3.12

[water]

The Excel UDF has been rewritten. Please check the AutoIt history for Script Breaking Changes to see what has changed. 

[Happy82]

 

#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>

; Create application object and open a workbook
Local $oAppl = _Excel_Open()
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
Local $oWorkbook = _Excel_BookOpen($oAppl, @ScriptDir & "\Unassigned Credit Card Transactions (MAIN REPORT).xlsx")
If @error Then
    MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example", "Error opening workbook '" & @ScriptDir & "\Unassigned Credit Card Transactions (MAIN REPORT).xlsx'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _Excel_Close($oAppl)
    Exit
EndIf

; *****************************************************************************
; Display a list of all worksheets for a specific Workbook
; *****************************************************************************
Local $aWorkSheets = _Excel_SheetList($oWorkbook)
If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example 1", "Error listing Worksheets." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
;_ArrayDisplay($aWorkSheets, "Excel UDF: _Excel_SheetList Example 1")
For Local $nNames In $aWorkSheets
            Local $worksheetname = $nNames
            MsgBox(64,"Res", "The Name of worksheet :" & $worksheetname )
Next

 

This code does not go into for-loop.

All i am trying to do "Format the Range of cells in mutliple worksheet in a  workbook. My workbook has multiple worksheets.

I took this script form the Examples. Instead of displaying using _ArrayDisplay i am trying to use a For Next loop. Once I loop i will know the worksheet I am on to modify the cell ranges.

I am not sure I am doing the right way. Since the variable is 2-d array it does not work in the for loop?

Edited May 6, 2015 by Happy82

[water]

Use

For $nNames In $aWorkSheets

 

[Happy82]

I tried using the mentioned way, still it did not work. It did not do anything.

Edited May 6, 2015 by Happy82

[JLogan3o13]

The function returns a 2D array. Try this. It works for me on a 25-sheet workbook.

#include <Array.au3>
#include <Excel.au3>
#include <MsgBoxConstants.au3>

Local $oAppl = _Excel_Open()
    If @error Then Exit ConsoleWrite("Error creating application object" & @CRLF)

Local $oWorkbook = _Excel_BookOpen($oAppl, @ScriptDir & "\Unassigned Credit Card Transactions (MAIN REPORT).xlsx")
    If @error Then Exit ConsoleWrite("Error creating workbook object" & @CRLF)


Local $aWorkSheets = _Excel_SheetList($oWorkbook)
    If @error Then Exit ConsoleWrite("Error enumerating worksheets" & @CRLF)


For $i = 0 To UBound($aWorkSheets) - 1
    MsgBox(64,"Res", "The Name of worksheet :" & $aWorkSheets[$i][0])
Next

 

[Happy82]

Thanks..... It works.

Edited May 6, 2015 by Happy82

[JLogan3o13]

Glad to hear it. Again, very important to read the notes on each function to determine what it returns. In this case, big difference between 1D and 2D array, and how you handle them