How to disable right click

[GoravG]

Global Const $GUI_EVENT_CLOSE = -3

_Main()
Func _Main()
    Local $OCSE2, $GUIActiveX, $gui_button_Exit, $Msg

    $OCSE2 = ObjCreate("Shell.Explorer.2")

    GUICreate("Google", 800, 400, (@DesktopWidth - 400) / 2, (@DesktopHeight - 400) / 2)
    GUISetBkColor(0x000000)

    $GUIActiveX = GUICtrlCreateObj($OCSE2, 10, 45, 780, 350)

    $gui_button_Exit = GUICtrlCreateButton("Exit", 710, 5, 80, 30)
    GUICtrlSetBkColor(-1, 0xFFFFFF)

    $OCSE2.navigate("http:\\www.google.com")
    GUISetState()

    While 1
        $Msg = GUIGetMsg()
        Select
            Case $Msg = $GUI_EVENT_CLOSE
                ExitLoop

            Case $Msg = $gui_button_Exit = $GUI_EVENT_CLOSE
                ExitLoop

        EndSelect
    WEnd
    GUIDelete()
EndFunc

i am new no idea to disable right click in GUICtrlCreateObj

[MikahS]

Have a look at this topic, it seems you will need to insert some javascript to stop the context menu from coming up with _IEHeadInsertEventScript:

.

Edited May 13, 2015 by MikahS
function name

[GoravG]

MikahS

thanks to reply it's work....

[MikahS]

Glad to help. 

[jguinch]

Also, for a single web page, you can use _IEHeadInsertEventScript (see example #2) :

#Include <IE.au3>
#Include <GUIConstantsEx.au3>

$oIE = _IECreateEmbedded()

GUICreate("Google", 800, 400, (@DesktopWidth - 400) / 2, (@DesktopHeight - 400) / 2)
GUISetBkColor(0x000000)

$GUIActiveX = GUICtrlCreateObj($oIE, 10, 45, 780, 350)

$gui_button_Exit = GUICtrlCreateButton("Exit", 710, 5, 80, 30)
GUICtrlSetBkColor(-1, 0xFFFFFF)

_IENavigate($oIE, "http://www.google.com")
GUISetState()

_IEHeadInsertEventScript($oIE, "document", "oncontextmenu", "return false;")

While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE , $gui_button_Exit
            ExitLoop
    EndSwitch
WEnd

 

[GoravG]

jguinch

Thanks to reply, im create already this script

My Work

#Include <IE.au3>
#Include <GUIConstantsEx.au3>

$oIE = _IECreateEmbedded()

$gui = GUICreate("Google", 800, 400, (@DesktopWidth - 400) / 2, (@DesktopHeight - 400) / 2)
GUISetBkColor(0x000000)

$GUIActiveX = GUICtrlCreateObj($oIE, 10, 45, 780, 350)

$gui_button_Exit = GUICtrlCreateButton("Exit", 710, 5, 80, 30)
GUICtrlSetBkColor(-1, 0xFFFFFF)

GUISetState()

GUISetState(@SW_DISABLE, $gui)
_IENavigate($oIE, "http://www.google.com")
_IEHeadInsertEventScript($oIE, "document", "oncontextmenu", "return false;")
GUISetState(@SW_ENABLE, $gui)
While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE , $gui_button_Exit
            ExitLoop
    EndSwitch
WEnd

 

[spudw2k]

I noticed after navigating to a new page the eventscript no longer applies and Right-Click functionality resumes.  One way I found this can be addressed is to register objevent and listen for NavigateComplete events.

#include <IE.au3>
#include <GUIConstantsEx.au3>

$oIE = _IECreateEmbedded()

GUICreate("Google", 800, 400, (@DesktopWidth - 400) / 2, (@DesktopHeight - 400) / 2)
GUISetBkColor(0x000000)

$GUIActiveX = GUICtrlCreateObj($oIE, 10, 45, 780, 350)

$gui_button_Exit = GUICtrlCreateButton("Exit", 710, 5, 80, 30)
GUICtrlSetBkColor(-1, 0xFFFFFF)

Local $oIEEvents = ObjEvent($oIE, "_IEEvent_", "DWebBrowserEvents2")
_IENavigate($oIE, "http://www.google.com")


GUISetState()


While 1
    $Msg = GUIGetMsg()
    Switch $Msg
        Case $GUI_EVENT_CLOSE, $gui_button_Exit
            ExitLoop
    EndSwitch
WEnd

;https://www.autoitscript.com/autoit3/docs/functions/ObjEvent.htm
Func _IEEvent_NavigateComplete2($oIEpDisp, $sIEURL, $iIEFlags, $sIETargetFrameName, $sIEPostData, $iIEHeaders, $bIECancel)
    _DisableRightClick()
EndFunc   ;==>_IEEvent_NavigateComplete2

Func _DisableRightClick()
    _IEHeadInsertEventScript($oIE, "document", "oncontextmenu", "return false;")
EndFunc   ;==>_DisableRightClick

edit: code tags

Edited May 18, 2015 by spudw2k