[SOLVED] _GUIImageList_Create _GUIImageList_AddIcon resolution

[rootx]

I would like to know how to increase the resolution of the icons in the grid.

$iColor = 5 is 32 bit DIB section.. but if I try with

$Image = _GUIImageList_Create(48,48,5,1)

the upscaling is very bad and pixelate, I have 32bit icon resolution with hight detail, how can I control or force the resolution of the icons ?

Thanks

Edited May 14, 2015 by rootx

[UEZ]

Can you please post a reproducer script?

 

Thx.

[rootx]

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idListview, $hImage
    Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    GUICreate("ImageList Create", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
    GUISetState(@SW_SHOW)

    ; Load images
    $hImage = _GUIImageList_Create(48, 48,5,1)
   _GUIImageList_Add($hImage, _GUIImageList_AddIcon($hImage,@ScriptDir&"\ico.ico"))
 _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Items", 120)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)
   
    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

 

[UEZ]

What about ico.ico? What is the dimension?

[rootx]

This icon for example.

Thanks for your attention

empty.ico

[UEZ]

You have to upscale the icon manually and add it afterwards to the _GUIImageList_Create.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiListView.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>

Example()

Func Example()
    _GDIPlus_Startup()
    Local $idListview, $hImage
    Local $iStylesEx = BitOR($LVS_EX_GRIDLINES, $LVS_EX_FULLROWSELECT, $LVS_EX_SUBITEMIMAGES)

    GUICreate("ImageList Create", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_NOSORTHEADER, $LVS_REPORT))
    _GUICtrlListView_SetExtendedListViewStyle($idListview, $iStylesEx)
    GUISetState(@SW_SHOW)

    ; Load images
    $hImage = _GUIImageList_Create(48, 48, 5, 1)

    ;load icon and upscale the icon to 48x48 pixels
    Local $hBitmap = _GDIPlus_BitmapCreateFromFile(@ScriptDir & "\empty.ico")
    Local $hBitmap_scaled = _GDIPlus_ImageResize($hBitmap, 48,  48)
    Local $hBitmap_GDI = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap_scaled)
    _GDIPlus_BitmapDispose($hBitmap_scaled)
    _GDIPlus_BitmapDispose($hBitmap)

    _GUIImageList_Add($hImage, $hBitmap_GDI)
    _GUICtrlListView_SetImageList($idListview, $hImage, 1)

    ; Add columns
    _GUICtrlListView_AddColumn($idListview, "Items", 120)

    ; Add items
    _GUICtrlListView_AddItem($idListview, "Item 1", 0)

    ; Loop until the user exits.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
    _WinAPI_DeleteObject($hBitmap_GDI)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example

 

Edited May 14, 2015 by UEZ

[rootx]

Perfect example

Thanks, I was really confused