How to Get FileCopy to Work?

[Radish]

I'm trying to create a simple script to create folders and copy files from one location to another. I have the following script so far:

expandcollapse popup

#include <Array.au3> ; Only required to display the arrays
#include <File.au3> ;Required by _FileListToArray

Local $sSourceRootPath = "W:\Test\"
Local $aSource
Local $sDestRootPath = "G:\Download\"
Local $aDest
GetList()
_ArrayDisplay($aSource, "Sorted tree $aSource")
$aDest = $aSource
CopyFoldersAndFiles()


Func GetList()
    $aSource = _FileListToArrayRec($sSourceRootPath, "*", $FLTAR_FILESFOLDERS, $FLTAR_RECUR, $FLTAR_SORT)
EndFunc   ;==>GetList


Func CopyFoldersAndFiles()
    For $i = 1 To $aSource[0]

        If StringRight($aSource[$i], 1) = "\" Then ;This is a folder - this 'folders' part seems to be working okay.
            $aDest[$i] = $sDestRootPath & $aSource[$i]
            MsgBox(0, "Folder to Create", $aDest[$i])
            DirCreate($aDest[$i])
        Else ;This is a file
            $aDest[$i] = $sDestRootPath & $aSource[$i]

            $SlashPostion = StringInStr($aDest[$i], "\", 0, -1)
            $aDest[$i] = StringLeft($aDest[$i], $SlashPostion)
            MsgBox(0, "File to Copy", "Source: " & $aSource[$i] & @CRLF & @CRLF & "Dest: " & $aDest[$i])

            FileCopy($aSource[$i], $aDest[$i], $FC_NOOVERWRITE + $FC_CREATEPATH)
        EndIf

    Next
EndFunc   ;==>CopyFoldersAndFiles

The part that creates folders seems to work. However, the part that is meant to copy files isn't working at all. I've spent hours trying to get this to work. Can someone please explain what I am getting wrong so that I can fix it?

[BrewManNH]

Change your FIleCopy line to this:

FileCopy($sSourceRootPath & $aSource[$i], $aDest[$i], $FC_NOOVERWRITE + $FC_CREATEPATH)

You need the source path name before the name of the files you're trying to copy.

[Radish]

(Mmm... Strange, I thought I had already replied to this.)

Thanks very much BrewMan, much appreciated.

Works like a treat now.

[BrewManNH]

The forum was rolled back at one point recently, so some posts disappeared.