How to stop SAPI.SpVoice in function

[drquochoai]

HotKeySet('^t', '_Translate')

$oSp = ObjCreate("SAPI.SpVoice")
While 1
Sleep(200)
WEnd
Func _Translate()
$oldClip = ClipGet(); get the data that is currently in the clipboard
Send('^c'); copy the selected text to the clipboard
$phrase = ClipGet(); get the data from the clipboard (which is now the selected word)
ClipPut($oldClip); put the old data back in the clipboard
ToolTip($phrase, 0, 0)
; now phrase is the word or phrase you want to translate
$oSp.Speak($phrase)
EndFunc

I started to use SAPI.VOICE.

My code mean, when i select anytext in anyApplication and press Ctrl+T he will speak my selected text.

My problem is: when i selected a long text and press Ctrl+T he speak a long sentencese, when he's speaking, i continue to select other text, and press Ctrl+T again, but he not stop the speaking sentence. He must finish the speaking sentence then speak my second sentence.

I don't know how to stop the speaking sentence and start to speak my new sentence.

Please help me, hope to see your godlike answer!

[BrewManNH]

Try this:

HotKeySet('^t', '_Translate')

$oSp = ObjCreate("SAPI.SpVoice")
While 1
    Sleep(200)
WEnd
Func _Translate()
    $oldClip = ClipGet(); get the data that is currently in the clipboard
    Send('^c'); copy the selected text to the clipboard
    $phrase = ClipGet(); get the data from the clipboard (which is now the selected word)
    ClipPut($oldClip); put the old data back in the clipboard
    ToolTip($phrase, 0, 0)
    ; now phrase is the word or phrase you want to translate
    $oSp.Speak($phrase, 3) ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
EndFunc   ;==>_Translate

 

[mLipok]

https://msdn.microsoft.com/en-us/library/ms723609(v=vs.85).aspx

https://msdn.microsoft.com/en-us/library/ms720892(v=vs.85).aspx

 

HotKeySet('^t', '_Translate')

$oSp = ObjCreate("SAPI.SpVoice")
While 1
    Sleep(200)
WEnd
Func _Translate()
    $oldClip = ClipGet(); get the data that is currently in the clipboard
    Send('^c'); copy the selected text to the clipboard
    $phrase = ClipGet(); get the data from the clipboard (which is now the selected word)
    ClipPut($oldClip); put the old data back in the clipboard
    ToolTip($phrase, 0, 0)
    ; now phrase is the word or phrase you want to translate
    $oSp.Speak($phrase,1)
    MsgBox(0, 'Testing', 111)
EndFunc   ;==>_Translate

 

[BrewManNH]

mLipok, that doesn't stop the script's speaking when I run it. It keeps speaking the first text, then afterwards plays the next queued text.

Using 3 instead of 1 will cause it to be asynchronous, meaning it will return immediately after the text is queued, and it will purge any data in the buffer. You can't use just 2 or 1 by itself because even though it might return immediately using 1, the buffer will still be speaking. Also, if you use just 2 by itself, then it will empty the buffer before the next message gets queued, but because it doesn't return immediately the function will keep talking until the buffer is empty, and then it returns so 2 wouldn't help at that point because the buffer is already empty.

[drquochoai]

thanks BrewManNH so much, the code is running extremly fantastis, exactly as i need. You are my idol.

My english is not good, i've tried to read the .speak() function in MS document before, but i don't understand much, so i don't know after Speak($phrase,..) we can add more arguments.

Thanks mLipok too, your code is so good. I promise that i have to read document clearly before i trying to post a question.

Thanks all, your answers are very very friendly. I love you so much.

 

Edited July 2, 2015 by drquochoai
repaire grammar

[mLipok]

Thanks @BrewManNH for clarification.