FTP Upload won't work?

[Azureus]

#include <FTP.au3>

$server = "BLANK"
$username = "BLANK"
$pass = "BLANK"

$Open = _FTPOpen("ftpupload")
consolewrite( "Open: " & $Open & @crlf )
$Conn = _FTPConnect($Open, $server, $username, $pass)
consolewrite( "Connect: " & $Conn & @crlf )
$Ftpp = _FtpPutFile($Conn, @ScriptDir&"\test.txt", "/htdocs/pinner")
consolewrite( "Put Result: " & $Ftpp & @crlf )
$Ftpc = _FTPClose($Open)

It won't work? Open: [RANDOMNUMBERS], Connect: [SAME RANDOM NUMBERS], and finally Put Result, which equals zero. (Put Result = 0) < consolewrite.

 

Why won't it work? Please.

[AutoBert]

Why using the old FTP.au3. Use the FTPEx.au3, here the example for _FTP_FilePut:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <FTPEx.au3>

Opt('MustDeclareVars', 1)

_example()

Func _example()
    Local $s_ServerName = '127.0.1' ;dieser Server existiert nicht
    Local $s_Username = "Bert"
    Local $s_Password = "Test"

    Local $s_LocalFile = @ScriptDir & "\_FTP_FilePut.au3"
    Local $s_RemoteFile = "/AutoIt3.My/_FTP_FilePut.au3"
    Local $i_Passive = 0
    Local $l_InternetSession, $l_FTPSession, $errOpen, $errFTP

    $l_InternetSession = _FTP_Open('AuoItZilla') ;Öffnet eine FTP Sitzung
    $errOpen = @error
    If Not @error Then
        $l_FTPSession = _FTP_Connect($l_InternetSession, $s_ServerName, $s_Username, $s_Password, $i_Passive) ;Verbindet zu einem FTP Server
        $errFTP = @error
        If Not @error Then
            If _FTP_FilePut($l_FTPSession, $s_LocalFile, $s_RemoteFile) Then
                ConsoleWrite("Upload: erfolgreich"  & @CRLF)
            Else
                ConsoleWrite("Upload: fehlgeschlagen " & " " & @error & @CRLF)
            EndIf
        Else
            MsgBox(0, "Connect", "fehlgeschlagen")
            ConsoleWrite("Connect: " & " " & $errFTP & @CRLF)
        EndIf
    Else
        MsgBox(0, "Open", "fehlgeschlagen")
        ConsoleWrite("Open " & " " & $errOpen & @CRLF)
    EndIf
    _FTP_Close($l_FTPSession)        ;schliesst die FTP-Sitzung
    _FTP_Close($l_InternetSession)   ;schliesst die Internet-Sitzung
EndFunc   ;==>_example

i wrote this example for the german helpfile long (AutoIt 3.3.6.3) time ago and it works still today with AutoIt 3.3.12.0 

 

 

Edited July 14, 2015 by AutoBert
removed attached files (bug in board)

[Azureus]

FTPEx.au

 Where do I download that?

[BrewManNH]

It comes with AutoIt3 download, FTPEx is a standard UDF include.

[Azureus]

I tried the script, and I get an error that says "Upload: fehlgeschlagen  -1".The servername, username and password is a hundred

percent correct.

 

Local $s_LocalFile = @ScriptDir & "\test.txt"
 Local $s_RemoteFile = "/htdocs/pinner/test.txt"

It doesn't work? I don't understand. I've also tried RemoteFile as just /htdocs/pinner/ and so on. Please help!

[BrewManNH]

Is the FTP server a secure FTP server (SFTP)? If it is, then the FTP functions in AutoIt won't work.

[Azureus]

Is the FTP server a secure FTP server (SFTP)? If it is, then the FTP functions in AutoIt won't work.

No, I don't think so.

What should I put in the remotefile place<?

[AutoBert]

No, I don't think so.

What should I put in the remotefile place<?

The whole Path to the file. All folders in the Path must exist. I have expanded my example:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <FTPEx.au3>

Opt('MustDeclareVars', 1)

_example()

Func _example()
    Local $s_ServerName = '127.0.0.1' ;dieser Server existiert nicht
    Local $s_Username = "Bert"
    Local $s_Password = "Test"

    Local $s_LocalFile = @ScriptDir & "\FTP_FilePut.au3"
    Local $s_RemoteFile = "/AutoIt3.My/FTP_FilePut.au3"
    Local $i_Passive = 0
    Local $l_InternetSession, $l_FTPSession, $errOpen, $errFTP
    If Not FileExists($s_LocalFile) Then
        ConsoleWrite('Local File not found' & @CRLF)
        Exit
    EndIf
    $l_InternetSession = _FTP_Open('AuoItZilla') ;Öffnet eine FTP Sitzung
    $errOpen = @error
    If Not @error Then
        ConsoleWrite("Internet-Session opened" & @CRLF)
        $l_FTPSession = _FTP_Connect($l_InternetSession, $s_ServerName, $s_Username, $s_Password, $i_Passive) ;Verbindet zu einem FTP Server
        $errFTP = @error
        If Not @error Then
            ConsoleWrite("connected to " & $s_ServerName & @CRLF)
            If _FTP_FilePut($l_FTPSession, $s_LocalFile, $s_RemoteFile) Then
                ConsoleWrite("Upload: erfolgreich" & @CRLF)
            Else
                ConsoleWrite("Upload: fehlgeschlagen " & " " & @error & @CRLF)
                ConsoleWrite("Check all Folders in Remotepath, they must exist before uploading!" & @CRLF)
            EndIf
        Else
            MsgBox(0, "Connect", "fehlgeschlagen")
            ConsoleWrite("Connect: " & " " & $errFTP & @CRLF)
        EndIf
    Else
        MsgBox(0, "Open", "fehlgeschlagen")
        ConsoleWrite("Open " & " " & $errOpen & @CRLF)
    EndIf
    _FTP_Close($l_FTPSession) ;schliesst die FTP-Sitzung
    _FTP_Close($l_InternetSession) ;schliesst die Internet-Sitzung
EndFunc   ;==>_example

So you can see that session is opened (only when local file exists), the session is connected and if FilePut false the message that all Folders must exists.