Please explain code used in Help file for several File functions

[timmy2]

Here's the Help file example for the FileOpen function.

expandcollapse popup

#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Create a constant variable in Local scope of the filepath that will be read/written to.
    Local Const $sFilePath = @TempDir & "\FileOpen.txt"

    ; Create a temporary file to read data from.
    If Not FileCreate($sFilePath, "This is an example of using FileOpen.") Then Return MsgBox($MB_SYSTEMMODAL, "", "An error occurred whilst writing the temporary file.")

    ; Open the file for reading and store the handle to a variable.
    Local $hFileOpen = FileOpen($sFilePath, $FO_READ)
    If $hFileOpen = -1 Then
        MsgBox($MB_SYSTEMMODAL, "", "An error occurred when reading the file.")
        Return False
    EndIf

    ; Read the contents of the file using the handle returned by FileOpen.
    Local $sFileRead = FileRead($hFileOpen)

    ; Close the handle returned by FileOpen.
    FileClose($hFileOpen)

    ; Display the contents of the file.
    MsgBox($MB_SYSTEMMODAL, "", "Contents of the file:" & @CRLF & $sFileRead)

    ; Delete the temporary file.
    FileDelete($sFilePath)
EndFunc   ;==>Example

; Create a file.
Func FileCreate($sFilePath, $sString)
    Local $bReturn = True ; Create a variable to store a boolean value.
    If FileExists($sFilePath) = 0 Then $bReturn = FileWrite($sFilePath, $sString) = 1 ; If FileWrite returned 1 this will be True otherwise False.
    Return $bReturn ; Return the boolean value of either True of False, depending on the return value of FileWrite.
EndFunc   ;==>FileCreate

 

In line 5 of the Func Example() there's a Return before MsgBox.  Is the Return meant to exit the function? How is MsgBox executed with a Return before it?  I haven't noticed this technique before, although I can see what you'd want to provide a way to abort if the temp file can't be created.

If Not FileCreate($sFilePath, "This is an example of using FileOpen.") Then Return MsgBox($MB_SYSTEMMODAL, "", "An error occurred whilst writing the temporary file.")

 

Also, what is the reasoning and purpose behind the design of FileCreate function? 

; Create a file.
Func FileCreate($sFilePath, $sString)
    Local $bReturn = True ; Create a variable to store a boolean value.
    If FileExists($sFilePath) = 0 Then $bReturn = FileWrite($sFilePath, $sString) = 1 ; If FileWrite returned 1 this will be True otherwise False.
    Return $bReturn ; Return the boolean value of either True of False, depending on the return value of FileWrite.
EndFunc   ;==>FileCreate

I assume that the goal of the first line is to declare the local variable, $bReturn, and setting it to True is a bet that the file will be created successfully.

The second line starts out understandable: "if the file does not already exist then create and write the string to it. But what's the " = 1" hanging off the end? I can't say I've ever seen a statement like "variable = function = value" before (even though this same FileCreate function is used in several Help file examples -- I just never noticed these details before). I'm going to need some hand holding through that one.

Why was the FileCreate function even employed when the following seems adequate for creating and writing text to the target file in the Example function?

; Create a temporary file to read data from.
    If Not FileWrite ($sFilePath,"This is an example of using FileOpen.") then MsgBox($MB_SYSTEMMODAL, "", "An error occurred whilst writing the temporary file.")

I realize this leaves out checking to see if the file already exists but what will happen if FileWrite opens and writes text to an existing file?

[kaisies]

 

 

File create is setup that way to return if the file write worked.  File write returns 1 if succeed, 0 if fail. So return file write = 1 will return 1 = 1 (true)  if succeed,  return 0 = 1 (false) if fail. 

Edited July 15, 2015 by kaisies

[kaisies]

And yes, return msgbox is intended to exit the function 

[guinness]

I explained here

[timmy2]

 

 

File create is setup that way to return if the file write worked.  File write returns 1 if succeed, 0 if fail. So return file write = 1 will return 1 = 1 (true)  if succeed,  return 0 = 1 (false) if fail. 

Gosh I feel stupid but "return 1 = 1 (True)" and "return 0 =1 (false)" are new concepts -- new statements -- to me. Have you ever seen a clear explanation of this?

I've only ever heard of 1 = true and 0 = false.  Thank you for replying.

 

[timmy2]

I explained here

Indeed you did, and thank you, Guinness.  I have no idea how my question got posted twice. I drafted my question and submitted it.   No funny stuff - refresh, backward, forward, etc. -- with the browser.

[guinness]

Me neither, but it's not my job to know =)

Here have a look at this, the results might shock you!

#include <MsgBoxConstants.au3>

MsgBox($MB_SYSTEMMODAL, '', '1. ' & (True = 1) & @CRLF & _ ; Implicit
        '2. ' & (False = 0) & @CRLF & _ ; Implicit
        '3. ' & (True = 0) & @CRLF & _ ; Of course not!
        '4. ' & (False = 1) & @CRLF & _ ; Of course not!
        '5. ' & (True = 99) & @CRLF & _ ; True is basically anything that isn't zero
        '6. ' & (False = 99) & @CRLF & _ ; False is only zero
        '7. ' & (True == 1) & @CRLF & _ ; Explicit, so it checks the type and value
        '8. ' & (False == 0) & @CRLF) ; Explicit, so it checks the type and value

 

[timmy2]

Me neither, but it's not my job to know =)

Here have a look at this, the results might shock you!

#include <MsgBoxConstants.au3>

MsgBox($MB_SYSTEMMODAL, '', '1. ' & (True = 1) & @CRLF & _ ; Implicit
        '2. ' & (False = 0) & @CRLF & _ ; Implicit
        '3. ' & (True = 0) & @CRLF & _ ; Of course not!
        '4. ' & (False = 1) & @CRLF & _ ; Of course not!
        '5. ' & (True = 99) & @CRLF & _ ; True is basically anything that isn't zero
        '6. ' & (False = 99) & @CRLF & _ ; False is only zero
        '7. ' & (True == 1) & @CRLF & _ ; Explicit, so it checks the type and value
        '8. ' & (False == 0) & @CRLF) ; Explicit, so it checks the type and value

 

(thank you)

Edited July 15, 2015 by timmy2

[guinness]

You're welcome