ToolTips showing on wrong tab.. Bug?

[corz]

expandcollapse popup

#include <GuiTab.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

AutoItSetOption("GUIOnEventMode", 1)


global $tabspace, $tabspace_opt, $old_tab, $tabs[3] = [2], $opt_tabs[6] = [5]
global $width = 400, $height = 300, $x = -1, $y = -1


$ExampleGUI = GUICreate("example", $width, $height, $x, $y, BitOr($WS_CAPTION, $WS_SYSMENU, $WS_MINIMIZEBOX, $WS_SIZEBOX))
GUISetOnEvent($GUI_EVENT_CLOSE, "DoExit", $ExampleGUI)


$opt_gui = GUICreate("opt_child", $width, $height-50, 3, 5, BitOR($WS_CHILD, $WS_TABSTOP), -1, $ExampleGUI)
$tabspace_opt = GUICtrlCreateTab(3, 2, $width-20, $height-20, BitOr($TCS_BUTTONS, $TCS_FLATBUTTONS, $TCS_TOOLTIPS, $TCS_HOTTRACK, $WS_CHILD, $WS_TABSTOP))

$opt_tabs[1] = GUICtrlCreateTabItem(" Option 1 ")
$opt_tabs[2] = GUICtrlCreateTabItem(" Option 2 ")
$opt_tabs[3] = GUICtrlCreateTabItem(" Option 3 ")
$opt_tabs[4] = GUICtrlCreateTabItem(" Option 4 ")
$opt_tabs[5] = GUICtrlCreateTabItem(" Option 5 ")

GUICtrlCreateTabItem("")

GUISwitch($ExampleGUI)

$tabspace = GUICtrlCreateTab(3, 2, $width, $height-5, BitOr($TCS_BOTTOM, $TCS_BUTTONS, $TCS_TOOLTIPS, $TCS_HOTTRACK, $WS_TABSTOP))
GUICtrlSetResizing(-1, $GUI_DOCKLEFT+$GUI_DOCKRIGHT+$GUI_DOCKTOP+$GUI_DOCKBOTTOM)

$tabs[1] = GUICtrlCreateTabItem(" Main Tab.. ")

$tabs[2] = GUICtrlCreateTabItem(" Options.. ")

GUICtrlCreateTabItem("")


GUICtrlSetTip($tabs[1], " Tip for the main tab.. ")
GUICtrlSetTip($tabs[2], " Tip for the options tab.. ")

GUICtrlSetTip($opt_tabs[1], " Tip for options tab 1.. ")
GUICtrlSetTip($opt_tabs[2], " Tip for options tab 2.. ")
GUICtrlSetTip($opt_tabs[3], " Tip for options tab 3.. ")
GUICtrlSetTip($opt_tabs[4], " Tip for options tab 4.. ")
GUICtrlSetTip($opt_tabs[5], " Tip for options tab 5.. ")


GUISetState(@SW_SHOW, $ExampleGUI)


while true
    local $new_tab =  GUICtrlSendMsg($tabspace, $TCM_GETCURSEL, 0, 0)
    if $new_tab <> $old_tab then
        if $new_tab = 1 then
            GUISetState(@SW_SHOW, $opt_gui)
        else
            GUISetState(@SW_HIDE, $opt_gui)
            GUISetState(@SW_SHOW, $ExampleGUI)
        endif
        $old_tab = $new_tab
    endif
    Sleep(100)
wend


func DoExit()
    exit
endfunc

 

As you can see, the tooltip for the options tabs 1 & 2 appear when hovering your pointer over the main two tabs.

Am I doing something wrong? Or is this a bug?

 

;o) Cor

[Melba23]

corz,

This does not happen in Beta 3.3.15.0, but does in release 3.3.14.0. So it seems that is already fixed.

M23

 

Edit: https://www.autoitscript.com/trac/autoit/ticket/2869

Edited July 23, 2015 by Melba23

[corz]

Excellent. Any idea when this will make into a proper release?

;o) Cor

[Melba23]

corz,

No - but as we have only just had a full release I would not expect another in the very near future. However, I often wonder why people have such a dislike of using the Betas - most of the changes are bug fixes and improvements so they are not that different.

M23